dnl Process this file with autoconf to produce a configure script.

AC_INIT(configure.in)

AM_INIT_AUTOMAKE(lxdream, 0.8.1)

AM_MAINTAINER_MODE

AM_CONFIG_HEADER(config.h)

AC_ISC_POSIX

AC_PROG_CC

AM_PROG_CC_STDC

AM_PROG_AS

AC_CHECK_SIZEOF([void *])

AC_HEADER_STDC

AC_CANONICAL_BUILD

AC_CANONICAL_HOST

AC_PATH_PROG(POD2MAN, [pod2man])

AC_PATH_PROG(POD2HTML, [pod2html])

dnl ---------------- enable/with flags ------------------

AC_ARG_ENABLE( trace, 

   AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),

   [if test "$enableval" == "yes"; then

     AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])

    fi] )

AC_ARG_ENABLE( watch,

   AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),

   [if test "$enableval" == "yes"; then

     AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])

   fi] )

AC_ARG_ENABLE( sh4stats,

   AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),

   [if test "$enableval" == "yes"; then

     AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])

    fi] )

AC_ARG_WITH( osmesa,

   AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),

   [], [with_osmesa=no])

AC_ARG_WITH( gtk,

   AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )

AC_ARG_WITH( esd,

   AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )

AC_ARG_WITH( pulse,

   AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )

dnl ------------ Check if we're building on Darwin --------------

dnl For starters, do we have a working objective-c compiler?

lxdream_save_cppflags="$CPPFLAGS"

CPPFLAGS="$CPPFLAGS -x objective-c"

AC_TRY_COMPILE([@interface Foo @end],, [

   AC_CHECK_HEADER([Cocoa/Cocoa.h], [

      HAVE_COCOA='yes'

      APPLE_BUILD='yes'

      LIBS="$LIBS -framework AppKit"

      LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"

      AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])

      AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])

      if test "x$with_gtk" = "xx11"; then

        with_gtk=no

      fi

   ])

], [CPPFLAGS="$lxdream_save_cppflags"] )

AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])

dnl ----------- Check for mandatory dependencies --------------

dnl Check for libpng (required)

PKG_CHECK_MODULES(LIBPNG, [libpng] )

dnl Implied by libpng, but check explicitly just in case

AC_CHECK_LIB(z, uncompress, [], [

    echo "Zlib (libz.so) could not be found, but is required."

    exit 1])

if test "x$with_gtk" = "xno"; then

   dnl Check for GLIB only

   PKG_CHECK_MODULES(GLIB, glib-2.0)

else

   dnl Check for GTK

   PKG_CHECK_MODULES(GTK, gtk+-2.0, [

       HAVE_GTK='yes'

       AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])

   ])

   dnl Which GTK port do we have?

   LIBS="$LIBS $GTK_LIBS"

   AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 

      HAVE_GTK_X11='yes'

      AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])

   AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 

      HAVE_GTK_OSX='yes'

      AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])

fi

AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])

dnl ------------------ Video driver support -------------------

AS_IF([test "x$with_osmesa" != xno], [ 

dnl User requested OSMesa (ie pure software rendering)

  AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],

    [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])

  AC_CHECK_HEADER([GL/osmesa.h], [],

    [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])

  HAVE_OSMESA='yes'

  VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"

  AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [

dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already

dnl taken care of above).

   if test "x$APPLE_BUILD" != 'xyes'; then

      AC_CHECK_LIB(GL, glVertex3f, [], [

          AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])

      AC_CHECK_HEADER([GL/gl.h], [], [

          AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])

   else

      AC_CHECK_FUNC(NSOpenGLGetVersion, [

         HAVE_NSGL='yes'

         VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"

         AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )

   fi

dnl Now work out how to get from the UI to GL - this is usually the painful part.

   if test "x$HAVE_GTK_X11" = "xyes"; then

      if test "x$APPLE_BUILD" = "xyes"; then

         LIBS="$LIBS -L/usr/X11/lib -lGL"

      fi

      AC_CHECK_FUNC(glXQueryVersion, [

         HAVE_GLX='yes'

         VIDEO_DRIVERS="$VIDEO_DRIVERS glx"

         AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )

   fi

])

AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])

AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])

AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])

dnl Check for optional (but highly desireable) OpenGL features

AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])

AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])

AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])

AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])

dnl Check for a supported cpu target for translation purposes

case $host_cpu in

    i386|i486|i586|i686|x86_64)

	SH4_TRANSLATOR="x86"

        AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;

esac

AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])

AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])

dnl ------------------ Optional driver support -------------------

dnl Check for Apple CoreAudio

AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [

     HAVE_CORE_AUDIO=yes

     LIBS="$LIBS -framework CoreAudio"

     AUDIO_DRIVERS="$AUDIO_DRIVERS osx"

     AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])

AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )

dnl Check for pulseaudio

if test "x$with_pulse" != "xno"; then

   PKG_CHECK_MODULES(PULSE, [libpulse-simple], [

       HAVE_PULSE='yes'

       AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"

       AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 

   ], [

       if test "x$with_pulse" = "xyes"; then

          AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )

       fi

   ])

fi

AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )

dnl Check for esound

if test "x$with_esd" != "xno"; then

   PKG_CHECK_MODULES(ESOUND, [esound], [ 

       HAVE_ESOUND='yes'

       AUDIO_DRIVERS="$AUDIO_DRIVERS esd"

       AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 

   ], [

       if test "x$with_esd" = "xyes"; then

          AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )

       fi

   ])

fi

AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )

dnl Check for alsa support

PKG_CHECK_MODULES(ALSA, [alsa], [ 

     HAVE_ALSA='yes'

     AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"

     AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])

AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )

dnl Check for native cdrom support. There can be only one.

AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])

AC_CHECK_HEADER([IOKit/IOKitLib.h], [

     CDROM_DRIVER=osx

     LIBS="$LIBS -framework IOKit"],[true])

AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])

AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])

AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])

AC_CHECK_HEADER([linux/joystick.h], [

    HAVE_LINUX_JOYSTICK_H=yes

    AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 

  [ echo "Linux Joystick support not found, building without it."] )

AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])

dnl Check for cross-compiler availability - needed for system tests

AC_PATH_PROG(SHCC, [sh-elf-gcc])

AC_PATH_PROG(SHLD, [sh-elf-ld])

AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])

AC_PATH_PROG(ARMCC, [arm-elf-gcc])

AC_PATH_PROG(ARMLD, [arm-elf-ld])

AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])

if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then

  BUILD_SH="no"

  echo "Warning: SH4 cross-compiler not found, system tests will be disabled."

else

  BUILD_SH="yes"

fi

if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then

  BUILD_ARM="no"

  echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."

else

  BUILD_ARM="yes"

fi

AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])

AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])

dnl ----------------------- All done, finish up -----------------------

GETTEXT_PACKAGE=lxdream

AC_SUBST(GETTEXT_PACKAGE)

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])

dnl Add the languages which your application supports here.

ALL_LINGUAS="de es it pt_BR"

AM_GLIB_GNU_GETTEXT

AC_OUTPUT([

Makefile

src/Makefile

po/Makefile.in

test/Makefile

])

dnl ------------------------- Print out a summary ----------------------

echo

echo "Configuration complete"

echo

if test "x$HAVE_GTK" = x; then

  if test "x$HAVE_COCOA" = x; then

     echo "  User interface: none"

  else

     echo "  User interface: Cocoa"

  fi

else

  echo "  User interface: GTK"

fi

if test "x$SH4_TRANSLATOR" = "x"; then

  echo "  SH4 translator: None (emulation core only)"

else

  echo "  SH4 translator: $SH4_TRANSLATOR"

fi

if test "x$VIDEO_DRIVERS" = "x"; then

   echo "  Video drivers: none (no supported GL found)"

else

   echo "  Video drivers: $VIDEO_DRIVERS"

fi

if test "x$AUDIO_DRIVERS" = "x"; then

   echo "  Audio drivers: none (no supported output devices found)"

else

   echo "  Audio drivers: $AUDIO_DRIVERS"

fi

if test "x$CDROM_DRIVER" = "x"; then

   echo "  CD-ROM driver: none (no supported cd-rom devices found)"

else

   echo "  CD-ROM driver: $CDROM_DRIVER"

fi