dnl Process this file with autoconf to produce a configure script.

AC_INIT(configure.in)

AM_INIT_AUTOMAKE(lxdream, 0.8.1)

AM_MAINTAINER_MODE

AM_CONFIG_HEADER(config.h)

AC_ISC_POSIX

AC_PROG_CC

AM_PROG_CC_STDC

AM_PROG_AS

AC_HEADER_STDC

AC_CANONICAL_BUILD

AC_CANONICAL_HOST

AC_ARG_ENABLE( trace, 

   AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),

   [if test "$enableval" == "yes"; then

     AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])

    fi] )

AC_ARG_ENABLE( watch,

   AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),

   [if test "$enableval" == "yes"; then

     AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])

   fi] )

AC_ARG_WITH( osmesa,

   AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),

   [], [with_osmesa=no])

AS_IF([test "x$with_osmesa" != xno], [ 

  AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],

    [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])

  AC_CHECK_HEADER([GL/osmesa.h], [],

    [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])

  ])

AM_CONDITIONAL(OSMESA_DRIVER, [test "x$with_osmesa" != xno])

dnl ----------- Check for mandatory dependencies --------------

dnl Building on MAC?

AC_CHECK_HEADER([Carbon/Carbon.h], [

   HAVE_CARBON='yes'

   APPLE_BUILD='yes'

   LIBS="$LIBS -framework OpenGL -framework AGL -framework Carbon -L/usr/X11R6/lib -lGL"

   AC_DEFINE(HAVE_CARBON,[1],[Have Carbon framework])

   AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])

])

dnl Check for libpng (required)

PKG_CHECK_MODULES(LIBPNG, [libpng] )

dnl Implied by libpng, but check explicitly just in case

AC_CHECK_LIB(z, uncompress, [], [

    echo "Zlib (libz.so) could not be found, but is required."

    exit 1])

if test "$APPLE_BUILD" != 'yes'; then

if test "x$with_osmesa" == "xno"; then

AC_CHECK_LIB(GL, glXQueryVersion, [], [

    echo "The OpenGL library (libGL.so) could not be found, but is required."

    exit 1])

AC_CHECK_HEADER([GL/gl.h], [], [

    echo "The OpenGL header files (eg GL/gl.h) could not be found, but are required."

    exit 1])

fi

fi

dnl Check for GTK (required for unix systems)

PKG_CHECK_MODULES(GTK, gtk+-2.0, [

    HAVE_GTK='yes'

    AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])

])

AM_CONDITIONAL(GUI_CARBON, [test "$HAVE_CARBON" = 'yes'])

AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])

dnl Check for a supported cpu target for translation purposes

case $host_cpu in

    i386|i486|i586|i686)

	SH4_TRANSLATOR="x86"

        AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;

    x86_64)

	SH4_TRANSLATOR="x86_64"

        AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86_64], [SH4 Translator to use (if any)] );;

    *)

	echo "Warning: No translator available for $host. Building emulation core only";;

esac

AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])

AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])

dnl ------------------ Optional driver support -------------------

dnl Check for esound

PKG_CHECK_MODULES(ESOUND, [esound], [ 

     HAVE_ESOUND='yes'

     AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], 

   [ echo "Warning: esound not found - building without audio support" ])

AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )

dnl Check for linux cdrom device support

AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [

    echo "Linux CDROM support not found, building without it."]  )

AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])

AC_CHECK_HEADER([linux/joystick.h], [

    HAVE_LINUX_JOYSTICK_H=yes

    AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 

  [ echo "Linux Joystick support not found, building without it."] )

AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])

dnl Check for cross-compiler availability - needed for system tests

AC_PATH_PROG(SHCC, [sh-elf-gcc])

AC_PATH_PROG(SHLD, [sh-elf-ld])

AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])

AC_PATH_PROG(ARMCC, [arm-elf-gcc])

AC_PATH_PROG(ARMLD, [arm-elf-ld])

AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])

if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then

  BUILD_SH="no"

  echo "Warning: SH4 cross-compiler not found, system tests will be disabled."

else

  BUILD_SH="yes"

fi

if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then

  BUILD_ARM="no"

  echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."

else

  BUILD_ARM="yes"

fi

AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])

AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])

dnl ----------------------- All done, finish up -----------------------

GETTEXT_PACKAGE=lxdream

AC_SUBST(GETTEXT_PACKAGE)

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])

dnl Add the languages which your application supports here.

ALL_LINGUAS="de pt_BR"

AM_GLIB_GNU_GETTEXT

AC_OUTPUT([

Makefile

src/Makefile

po/Makefile.in

test/Makefile

])