Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 1245:01e0020adf88
prev1239:be3121267597
next1266:e6079b9c69ba
author nkeynes
date Fri Mar 02 23:49:10 2012 +1000 (8 years ago)
permissions -rw-r--r--
last change Android WIP:
* Rename gui_jni.c to gui_android.c - now quite android specific.
* Implement generic EGL driver with very minimal Java wrapper
* Run emulation in separate thread, and implement simple queue for
inter-thread communication.
* Add menu/action-bar items for start + reset
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_CANONICAL_BUILD
     9 AC_CANONICAL_HOST
    11 m4_include([m4/ccforbuild.m4])
    12 m4_include([m4/android.m4])
    13 LX_ANDROID_BUILD
    15 AC_ISC_POSIX
    16 AC_PROG_CC
    17 AM_PROG_CC_STDC
    18 AC_PROG_CC_FOR_BUILD
    19 AC_PROG_OBJC
    20 AC_PROG_SED
    21 AM_PROG_AS
    22 AC_PROG_RANLIB
    23 AC_CHECK_SIZEOF([void *])
    24 AC_HEADER_STDC
    26 _AM_DEPENDENCIES([OBJC])
    28 AC_PATH_PROG(POD2MAN, [pod2man])
    29 AC_PATH_PROG(POD2HTML, [pod2html])
    31 AC_DEFINE_UNQUOTED(BUILD_SED_PROG, ["${SED}"], [Sed to use for build tools])
    32 AC_DEFINE_UNQUOTED(BUILD_CPP_PROG, ["${CPP}"], [CPP to use for build tools])
    34 dnl ---------------- enable/with flags ------------------
    36 AC_ARG_ENABLE( strict-warn,
    37    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    38    [if test "$enableval" == "yes"; then
    39       enable_strictwarn=yes
    40     fi] )
    41 AC_ARG_ENABLE( translator, 
    42    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    43    [true], [enable_translator=yes] )
    44 AC_ARG_ENABLE( optimized,
    45    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    46    [true], [enable_optimized=yes] )
    47 AC_ARG_ENABLE( shared,
    48    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
    49    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
    50 AC_ARG_ENABLE( profiled,
    51    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    52    [if test "$enableval" == "yes"; then
    53       enable_profiled=yes;
    54     fi] )
    55 AC_ARG_ENABLE( trace, 
    56    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    57    [if test "$enableval" == "yes"; then
    58      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    59     fi] )
    60 AC_ARG_ENABLE( watch,
    61    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    62    [if test "$enableval" == "yes"; then
    63      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    64    fi] )
    65 AC_ARG_ENABLE( sh4stats,
    66    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    67    [if test "$enableval" == "yes"; then
    68      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    69     fi] )
    70 AC_ARG_WITH( osmesa,
    71    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    72    [], [with_osmesa=no])
    73 AC_ARG_WITH( gtk,
    74    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    75 AC_ARG_WITH( esd,
    76    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    77 AC_ARG_WITH( pulse,
    78    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    79 AC_ARG_WITH( sdl,
    80    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
    82 dnl ------------ Check if we're building on Darwin or Android --------------
    84 dnl For starters, do we have a working objective-c compiler?
    85 if test "$ANDROID_BUILD" = "yes"; then
    86    with_gtk=no;
    87    EXTRA_OUTPUT_FILES="src/android/build.properties"
    88    LIBS="-lEGL -lGLESv2 $LIBS"
    89    AC_DEFINE(HAVE_GLES2, 1, [Using GLESv2])
    90    UI_DRIVER="Android"
    91    with_sdl=no
    92 else
    93 AC_HAVE_OBJC([
    94    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    95       HAVE_COCOA='yes'
    96       APPLE_BUILD='yes'
    97       LIBS="$LIBS -framework AppKit -framework Carbon"
    98       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    99       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
   100       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
   101       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
   102       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
   103       UI_DRIVER="Cocoa"
   104       if test "x$with_gtk" = "xx11"; then
   105         with_gtk=no
   106       fi
   107    ], [], [AC_INCLUDES_DEFAULT])
   109    AC_OBJC_VERSION([ OBJCOPT="-O2"
   110                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
   111                    [ OBJCOPT="-O2" ], [] )
   112    AC_CHECK_OBJCFLAG([-msse2])
   113    AC_CHECK_OBJCFLAG([-mfpmath=sse])
   114 ])
   115 fi
   117 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
   118 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
   119   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
   120 fi
   122 dnl ------------------ C Compiler flags -----------------------
   123 CFLAGS_FOR_BUILD="-O2 -std=c99"
   124 CFLAGS="-g -fexceptions"
   125 OBJCFLAGS="-g -fexceptions"
   126 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
   128 STDCFLAG="-std=c99"
   129 AC_CC_VERSION([ CCOPT="-O2" 
   130                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   131               [ CCOPT="$CFLAGS -fast"
   132                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   133               [ CCOPT="$CFLAGS -O2" ])
   134 AC_CHECK_CFLAG([-msse2])
   135 AC_CHECK_CFLAG([-mfpmath=sse])
   137 if test "x$enable_optimized" = "xyes"; then
   138    CFLAGS="$CFLAGS $CCOPT"
   139    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
   140    if test "x$enable_profiled" != "xyes"; then
   141        dnl -fomit-frame-pointer can't be used with -pg
   142        CFLAGS="$CFLAGS -fomit-frame-pointer"
   143        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
   144    fi
   145 else
   146    CFLAGS="$CFLAGS -g3"
   147    OBJCFLAGS="$OBJCFLAGS -g3"
   148 fi
   150 if test "x$enable_profiled" = "xyes"; then
   151    CFLAGS="$CFLAGS -pg"
   152    LDFLAGS="$LDFLAGS -pg";
   153    OBJCFLAGS="$OBJCFLAGS -pg";
   154 fi
   156 if test "x$enable_strictwarn" = "xyes"; then
   157    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   158    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   159 fi
   161 if test "x$enable_shared" != "xno"; then
   162    if test "x$APPLE_BUILD" = "xyes"; then
   163       SOEXT="dylib"
   164       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
   165    else 
   166       SOEXT="so"
   167       PLUGINLDFLAGS="-shared"
   168    fi
   169    PLUGINCFLAGS="-fPIC"
   171 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
   172    AC_CHECK_HEADER( [dlfcn.h], [
   173       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
   174    if test "x$have_dlopen" != "xyes"; then
   175       if test "x$enable_shared" == "xyes"; then
   176          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
   177       else
   178          AC_MSG_WARN("Statically linking all plugins")
   179       fi
   180    fi
   182 dnl Check if linker accepts -rdynamic
   183    AC_MSG_CHECKING([if linker accepts -rdynamic])
   184    old_LDFLAGS="$LDFLAGS"
   185    LDFLAGS="$LDFLAGS -rdynamic"
   186    AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
   187      LXDREAMLDFLAGS="-rdynamic"
   188      AC_MSG_RESULT([yes]) 
   189    ], [
   190      LXDREAMLDFLAGS=""
   191      AC_MSG_RESULT([no]) ])
   192    LDFLAGS="$old_LDFLAGS"
   194    AC_SUBST(SOEXT)
   195    AC_SUBST(PLUGINCFLAGS)
   196    AC_SUBST(PLUGINLDFLAGS)
   197    AC_SUBST(LXDREAMLDFLAGS)
   198 fi
   199 if test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"; then
   200     AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])
   201 fi
   202 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"])
   204 AC_CHECK_FASTCALL([
   205    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   206 ])
   207 AC_CHECK_FORCEINLINE()
   208 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
   209 AC_CHECK_FRAME_ADDRESS( [
   210    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   211 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   213 AC_SUBST(LXDREAMCPPFLAGS)
   214 AC_SEARCH_LIBS(listen, [socket])
   215 AC_SEARCH_LIBS(inet_ntoa,[nsl])
   217 dnl ----------- Check for mandatory dependencies --------------
   218 dnl Check for libpng (required)
   219 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   221 dnl Implied by libpng, but check explicitly just in case
   222 AC_CHECK_LIB(z, uncompress, [], [
   223     echo "Zlib (libz.so) could not be found, but is required."
   224     exit 1])
   226 if test "x$with_gtk" = "xno"; then
   227    dnl Check for GLIB only
   228    PKG_CHECK_MODULES(GLIB, glib-2.0)
   229 else
   230    dnl Check for GTK
   231    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   232        HAVE_GTK='yes'
   233        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   234        UI_DRIVER="GTK"
   235    ])
   237    dnl Which GTK port do we have?
   238    LIBS="$LIBS $GTK_LIBS"
   239    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   240       HAVE_GTK_X11='yes'
   241       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   242       dnl Add -lX11 explicitly as some pkg-configs get it wrong
   243       GTK_LIBS="$GTK_LIBS -lX11"
   244       LIBS="$LIBS -lX11"
   245    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   246       HAVE_GTK_OSX='yes'
   247       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   248    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
   249       AC_MSG_FAILURE( [Unable to identify GTK platform] )
   250    fi
   251 fi
   253 AC_PUSH_CC_FOR_BUILD
   254 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)
   255 AC_POP_CC_FOR_BUILD
   257 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   259 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
   260 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
   261    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
   262       dnl LIBS="-lisofs $LIBS"
   263    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])], 
   264       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
   266 dnl ------------------ Video driver support -------------------
   267 AS_IF([test "x$with_osmesa" != xno], [ 
   269 dnl User requested OSMesa (ie pure software rendering)
   270   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   271     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   272   AC_CHECK_HEADER([GL/osmesa.h], [],
   273     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   274   HAVE_OSMESA='yes'
   275   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   276   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   278 dnl Otherwise we want a real GL library (unless we're on darwin or android, in which case it's already
   279 dnl taken care of above).
   280    if test "x$APPLE_BUILD" != 'xyes' -a "x$ANDROID_BUILD" != 'xyes'; then
   281       PKG_CHECK_MODULES(LIBGL, [gl] )
   282       dnl AC_CHECK_LIB(GL, glVertex3f, [], [
   283           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   284       dnl AC_CHECK_HEADER([GL/gl.h], [], [
   285           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   286       LIBS="$LIBS $LIBGL_LIBS";
   287       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
   288    else
   289       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   290          HAVE_NSGL='yes'
   291          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   292          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   293    fi
   295 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   296    if test "x$HAVE_GTK_X11" = "xyes"; then
   297       if test "x$APPLE_BUILD" = "xyes"; then
   298          LIBS="$LIBS -L/usr/X11/lib -lGL"
   299       fi
   300       AC_CHECK_FUNC(glXQueryVersion, [
   301          HAVE_GLX='yes'
   302          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   303          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   304    fi
   306 ])
   310 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   311 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   312 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   314 dnl Check for optional (but highly desireable) OpenGL features
   315 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
   316 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
   317 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   318 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   319 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   320 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])
   321 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident function]) ], [])
   322 AC_CHECK_FUNC(glDrawBuffer, [ AC_DEFINE([HAVE_OPENGL_DRAW_BUFFER],1,[Have glDrawBuffer function])], [])
   323 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.
   325 dnl ------------------- SH4 translator target -------------------
   327 if test "x$enable_translator" != "xno"; then
   328     case $host_cpu in
   329         i386|i486|i586|i686|x86_64)
   330 	    SH4_TRANSLATOR="x86"
   331             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   332     esac
   333 fi
   334 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   336 dnl ------------------ Optional driver support -------------------
   337 dnl Check for Apple CoreAudio
   338 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   339      HAVE_CORE_AUDIO=yes
   340      LIBS="$LIBS -framework CoreAudio"
   341      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   342      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   343 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   345 dnl Check for SDL (only used for audio at the moment)
   346 if test "x$with_sdl" != "xno"; then
   347    PKG_CHECK_MODULES(SDL, [sdl], [
   348        HAVE_SDL='yes'
   349        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
   350        AC_DEFINE([HAVE_SDL],1,[Have SDL support])
   351    ], [
   352       if test "x$with_sdl" = "xyes"; then
   353          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
   354       fi
   355    ])
   356 fi
   357 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
   359 dnl Check for pulseaudio
   360 if test "x$with_pulse" != "xno"; then
   361    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   362        HAVE_PULSE='yes'
   363        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   364        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   365    ], [
   366        if test "x$with_pulse" = "xyes"; then
   367           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   368        fi
   369    ])
   370 fi
   371 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   373 dnl Check for esound
   374 if test "x$with_esd" != "xno"; then
   375    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   376        HAVE_ESOUND='yes'
   377        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   378        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   379    ], [
   380        if test "x$with_esd" = "xyes"; then
   381           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   382        fi
   383    ])
   384 fi
   385 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   387 dnl Check for alsa support
   388 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   389      HAVE_ALSA='yes'
   390      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   391      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   392 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   395 dnl Check for native cdrom support. There can be only one.
   396 if test "$ANDROID_BUILD" != "yes"; then
   397   AC_CHECK_HEADER([linux/cdrom.h], [
   398      CDROM_DRIVER=linux
   399      dnl Some kernel versions have non-c99 compliant headers - check here
   400      AC_MSG_CHECKING([C99 compliant kernel headers])
   401      old_CFLAGS="$CFLAGS"
   402      CFLAGS="$CFLAGS $STDCFLAG"
   403      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
   404         AC_MSG_RESULT([No])
   405         STDCFLAG="-std=gnu99"])
   406      CFLAGS="$old_CFLAGS"
   407   ], [true])
   408   AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   409        CDROM_DRIVER=osx
   410        LIBS="$LIBS -framework IOKit"],[true])
   411 fi
   412 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   413 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   414 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   415 if test "x$CDROM_DRIVER" = "xlinux"; then
   416    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
   417 fi
   419 AC_CHECK_HEADER([linux/joystick.h], [
   420     HAVE_LINUX_JOYSTICK_H=yes
   421     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) 
   422     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ], 
   423   [ echo "Linux Joystick support not found, building without it."] )
   424 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   426 dnl Check for LIRC
   427 if test "x$with_lirc" != "xno"; then
   428     AC_CHECK_HEADER([lirc/lirc_client.h], [
   429         HAVE_LIRC_CLIENT_H=yes
   430         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) 
   431         INPUT_DRIVERS="$INPUT_DRIVERS lirc"
   432       ],
   433       [ echo "LIRC support not found, building without it." ] )
   434 fi
   435 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
   437 dnl Check for cross-compiler availability - needed for system tests
   438 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   439 AC_PATH_PROG(SHLD, [sh-elf-ld])
   440 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   441 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   442 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   443 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   445 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   446   BUILD_SH="no"
   447   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   448 else
   449   BUILD_SH="yes"
   450 fi
   451 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   452   BUILD_ARM="no"
   453   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   454 else
   455   BUILD_ARM="yes"
   456 fi
   457 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   458 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   460 CFLAGS="$CFLAGS $STDCFLAG"
   462 dnl ----------------------- All done, finish up -----------------------
   463 GETTEXT_PACKAGE=lxdream
   464 LXDREAM_LIBS="$LIBS"
   465 LIBS=""
   466 AC_SUBST(LXDREAM_LIBS)
   467 AC_SUBST(GETTEXT_PACKAGE)
   468 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   470 dnl Add the languages which your application supports here.
   471 ALL_LINGUAS="de es it nl pt_BR"
   472 AM_GLIB_GNU_GETTEXT
   474 AC_OUTPUT([
   475 Makefile
   476 src/Makefile
   477 src/tools/Makefile
   478 po/Makefile.in
   479 test/Makefile
   480 Info.plist
   481 ])
   482 AS_MKDIR_P(test/sh4)
   484 dnl ------------------------- Print out a summary ----------------------
   486 echo
   487 echo "Configuration complete"
   488 echo
   490 if test "x$UI_DRIVER" = x; then
   491   echo "  User interface: none"
   492 else
   493   echo "  User interface: $UI_DRIVER"
   494 fi
   496 if test "x$SH4_TRANSLATOR" = "x"; then
   497   echo "  SH4 translator: none (emulation core only)"
   498 else
   499   echo "  SH4 translator: $SH4_TRANSLATOR"
   500 fi
   502 if test "x$VIDEO_DRIVERS" = "x"; then
   503    echo "  Video drivers: none (no supported GL found)"
   504 else
   505    echo "  Video drivers: $VIDEO_DRIVERS"
   506 fi
   508 if test "x$AUDIO_DRIVERS" = "x"; then
   509    echo "  Audio drivers: none (no supported output devices found)"
   510 else
   511    echo "  Audio drivers: $AUDIO_DRIVERS"
   512 fi
   514 if test "x$INPUT_DRIVERS" = "x"; then
   515    echo "  Input drivers: none (no supported input devices found)"
   516 else
   517    echo "  Input drivers: $INPUT_DRIVERS"
   518 fi
   520 if test "x$CDROM_DRIVER" = "x"; then
   521    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   522 else
   523    echo "  CD-ROM driver:  $CDROM_DRIVER"
   524 fi
.