Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 793:7877d947228d
prev791:fc609d426806
next804:567a684e1e7a
author nkeynes
date Mon Aug 04 06:00:11 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Fix x86-64 bugs (only visible on OS X)
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.4)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( translator, 
    23    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enable by default)]),
    24    [true], [enable_translator=yes] )
    25 AC_ARG_ENABLE( trace, 
    26    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    27    [if test "$enableval" == "yes"; then
    28      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    29     fi] )
    30 AC_ARG_ENABLE( watch,
    31    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    32    [if test "$enableval" == "yes"; then
    33      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    34    fi] )
    35 AC_ARG_ENABLE( sh4stats,
    36    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    37    [if test "$enableval" == "yes"; then
    38      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    39     fi] )
    40 AC_ARG_WITH( osmesa,
    41    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    42    [], [with_osmesa=no])
    43 AC_ARG_WITH( gtk,
    44    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    45 AC_ARG_WITH( esd,
    46    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    47 AC_ARG_WITH( pulse,
    48    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    50 dnl ------------ 
    52 if test "x$GCC" = "xyes"; then
    53    CFLAGS="$CFLAGS -fno-strict-aliasing"
    54 fi
    56 dnl ------------ Check if we're building on Darwin --------------
    58 dnl For starters, do we have a working objective-c compiler?
    59 lxdream_save_cppflags="$CPPFLAGS"
    60 CPPFLAGS="$CPPFLAGS -x objective-c"
    61 AC_TRY_COMPILE([@interface Foo @end],, [
    63    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    64       HAVE_COCOA='yes'
    65       APPLE_BUILD='yes'
    66       LIBS="$LIBS -framework AppKit"
    67       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    68       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    69       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    70       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    71       if test "x$with_gtk" = "xx11"; then
    72         with_gtk=no
    73       fi
    74    ])
    76 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    77 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    79 dnl ----------- Check for mandatory dependencies --------------
    80 dnl Check for libpng (required)
    81 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    83 dnl Implied by libpng, but check explicitly just in case
    84 AC_CHECK_LIB(z, uncompress, [], [
    85     echo "Zlib (libz.so) could not be found, but is required."
    86     exit 1])
    88 if test "x$with_gtk" = "xno"; then
    89    dnl Check for GLIB only
    90    PKG_CHECK_MODULES(GLIB, glib-2.0)
    91 else
    92    dnl Check for GTK
    93    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    94        HAVE_GTK='yes'
    95        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    96    ])
    98    dnl Which GTK port do we have?
    99    LIBS="$LIBS $GTK_LIBS"
   100    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   101       HAVE_GTK_X11='yes'
   102       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   103    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   104       HAVE_GTK_OSX='yes'
   105       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   106 fi
   108 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   110 dnl ------------------ Video driver support -------------------
   111 AS_IF([test "x$with_osmesa" != xno], [ 
   113 dnl User requested OSMesa (ie pure software rendering)
   114   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   115     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   116   AC_CHECK_HEADER([GL/osmesa.h], [],
   117     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   118   HAVE_OSMESA='yes'
   119   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   120   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   122 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   123 dnl taken care of above).
   124    if test "x$APPLE_BUILD" != 'xyes'; then
   125       AC_CHECK_LIB(GL, glVertex3f, [], [
   126           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   127       AC_CHECK_HEADER([GL/gl.h], [], [
   128           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   129    else
   130       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   131          HAVE_NSGL='yes'
   132          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   133          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   134    fi
   136 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   137    if test "x$HAVE_GTK_X11" = "xyes"; then
   138       if test "x$APPLE_BUILD" = "xyes"; then
   139          LIBS="$LIBS -L/usr/X11/lib -lGL"
   140       fi
   141       AC_CHECK_FUNC(glXQueryVersion, [
   142          HAVE_GLX='yes'
   143          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   144          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   145    fi
   147 ])
   151 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   152 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   153 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   155 dnl Check for optional (but highly desireable) OpenGL features
   156 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   157 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   158 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   159 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   162 dnl ------------------- SH4 translator target -------------------
   164 if test "x$enable_translator" != "xno"; then
   165     case $host_cpu in
   166         i386|i486|i586|i686|x86_64)
   167 	    SH4_TRANSLATOR="x86"
   168             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   169     esac
   170 fi
   171 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   173 dnl ------------------ Optional driver support -------------------
   174 dnl Check for Apple CoreAudio
   175 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   176      HAVE_CORE_AUDIO=yes
   177      LIBS="$LIBS -framework CoreAudio"
   178      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   179      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   180 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   182 dnl Check for pulseaudio
   183 if test "x$with_pulse" != "xno"; then
   184    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   185        HAVE_PULSE='yes'
   186        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   187        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   188    ], [
   189        if test "x$with_pulse" = "xyes"; then
   190           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   191        fi
   192    ])
   193 fi
   194 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   196 dnl Check for esound
   197 if test "x$with_esd" != "xno"; then
   198    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   199        HAVE_ESOUND='yes'
   200        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   201        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   202    ], [
   203        if test "x$with_esd" = "xyes"; then
   204           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   205        fi
   206    ])
   207 fi
   208 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   210 dnl Check for alsa support
   211 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   212      HAVE_ALSA='yes'
   213      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   214      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   215 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   218 dnl Check for native cdrom support. There can be only one.
   219 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   220 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   221      CDROM_DRIVER=osx
   222      LIBS="$LIBS -framework IOKit"],[true])
   223 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   224 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   225 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   227 AC_CHECK_HEADER([linux/joystick.h], [
   228     HAVE_LINUX_JOYSTICK_H=yes
   229     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   230   [ echo "Linux Joystick support not found, building without it."] )
   231 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   233 dnl Check for cross-compiler availability - needed for system tests
   234 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   235 AC_PATH_PROG(SHLD, [sh-elf-ld])
   236 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   237 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   238 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   239 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   241 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   242   BUILD_SH="no"
   243   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   244 else
   245   BUILD_SH="yes"
   246 fi
   247 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   248   BUILD_ARM="no"
   249   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   250 else
   251   BUILD_ARM="yes"
   252 fi
   253 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   254 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   257 dnl ----------------------- All done, finish up -----------------------
   258 GETTEXT_PACKAGE=lxdream
   259 AC_SUBST(GETTEXT_PACKAGE)
   260 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   262 dnl Add the languages which your application supports here.
   263 ALL_LINGUAS="de es it pt_BR"
   264 AM_GLIB_GNU_GETTEXT
   266 AC_OUTPUT([
   267 Makefile
   268 src/Makefile
   269 po/Makefile.in
   270 test/Makefile
   271 Info.plist
   272 ])
   273 AS_MKDIR_P(test/sh4)
   275 dnl ------------------------- Print out a summary ----------------------
   277 echo
   278 echo "Configuration complete"
   279 echo
   281 if test "x$HAVE_GTK" = x; then
   282   if test "x$HAVE_COCOA" = x; then
   283      echo "  User interface: none"
   284   else
   285      echo "  User interface: Cocoa"
   286   fi
   287 else
   288   echo "  User interface: GTK"
   289 fi
   291 if test "x$SH4_TRANSLATOR" = "x"; then
   292   echo "  SH4 translator: None (emulation core only)"
   293 else
   294   echo "  SH4 translator: $SH4_TRANSLATOR"
   295 fi
   297 if test "x$VIDEO_DRIVERS" = "x"; then
   298    echo "  Video drivers: none (no supported GL found)"
   299 else
   300    echo "  Video drivers: $VIDEO_DRIVERS"
   301 fi
   303 if test "x$AUDIO_DRIVERS" = "x"; then
   304    echo "  Audio drivers: none (no supported output devices found)"
   305 else
   306    echo "  Audio drivers: $AUDIO_DRIVERS"
   307 fi
   309 if test "x$CDROM_DRIVER" = "x"; then
   310    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   311 else
   312    echo "  CD-ROM driver: $CDROM_DRIVER"
   313 fi
.