Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 1284:0db0a5e72698
prev1266:e6079b9c69ba
next1287:dac8f363f1fe
author nkeynes
date Tue Apr 17 21:35:38 2012 +1000 (9 years ago)
permissions -rw-r--r--
last change Check for sqrt() in libm if needed (required on some platforms)
Baesd on patch from guinux, thanks!
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_CANONICAL_BUILD
     9 AC_CANONICAL_HOST
    11 m4_include([m4/ccforbuild.m4])
    12 m4_include([m4/android.m4])
    13 LX_ANDROID_BUILD
    15 AC_ISC_POSIX
    16 AC_PROG_CC
    17 AM_PROG_CC_STDC
    18 AC_PROG_CC_FOR_BUILD
    19 AC_PROG_OBJC
    20 AC_PROG_SED
    21 AM_PROG_AS
    22 AC_PROG_RANLIB
    23 AC_CHECK_SIZEOF([void *])
    24 AC_HEADER_STDC
    26 _AM_DEPENDENCIES([OBJC])
    28 AC_PATH_PROG(POD2MAN, [pod2man])
    29 AC_PATH_PROG(POD2HTML, [pod2html])
    31 AC_DEFINE_UNQUOTED(BUILD_SED_PROG, ["${SED}"], [Sed to use for build tools])
    32 AC_DEFINE_UNQUOTED(BUILD_CPP_PROG, ["${CPP}"], [CPP to use for build tools])
    34 dnl ---------------- enable/with flags ------------------
    36 AC_ARG_ENABLE( strict-warn,
    37    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    38    [if test "$enableval" == "yes"; then
    39       enable_strictwarn=yes
    40     fi] )
    41 AC_ARG_ENABLE( translator, 
    42    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    43    [true], [enable_translator=yes] )
    44 AC_ARG_ENABLE( optimized,
    45    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    46    [true], [enable_optimized=yes] )
    47 AC_ARG_ENABLE( shared,
    48    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
    49    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
    50 AC_ARG_ENABLE( profiled,
    51    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    52    [if test "$enableval" == "yes"; then
    53       enable_profiled=yes;
    54     fi] )
    55 AC_ARG_ENABLE( trace, 
    56    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    57    [if test "$enableval" == "yes"; then
    58      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    59     fi] )
    60 AC_ARG_ENABLE( watch,
    61    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    62    [if test "$enableval" == "yes"; then
    63      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    64    fi] )
    65 AC_ARG_ENABLE( sh4stats,
    66    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    67    [if test "$enableval" == "yes"; then
    68      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    69     fi] )
    70 AC_ARG_WITH( osmesa,
    71    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    72    [], [with_osmesa=no])
    73 AC_ARG_WITH( gtk,
    74    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    75 AC_ARG_WITH( esd,
    76    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    77 AC_ARG_WITH( pulse,
    78    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    79 AC_ARG_WITH( sdl,
    80    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
    82 dnl ------------ Check if we're building on Darwin or Android --------------
    84 dnl For starters, do we have a working objective-c compiler?
    85 if test "$ANDROID_BUILD" = "yes"; then
    86    with_gtk=no;
    87    EXTRA_OUTPUT_FILES="src/android/build.properties"
    88    LIBS="-lEGL -lGLESv2 $LIBS"
    89    AC_DEFINE(HAVE_GLES2, 1, [Using GLESv2])
    90    UI_DRIVER="Android"
    91    VIDEO_DRIVERS="egl"
    92    with_sdl=no
    93 else
    94 AC_HAVE_OBJC([
    95    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    96       HAVE_COCOA='yes'
    97       APPLE_BUILD='yes'
    98       LIBS="$LIBS -framework AppKit -framework Carbon"
    99       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
   100       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
   101       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
   102       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
   103       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
   104       UI_DRIVER="Cocoa"
   105       if test "x$with_gtk" = "xx11"; then
   106         with_gtk=no
   107       fi
   108    ], [], [AC_INCLUDES_DEFAULT])
   110    AC_OBJC_VERSION([ OBJCOPT="-O2"
   111                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
   112                    [ OBJCOPT="-O2" ], [] )
   113    AC_CHECK_OBJCFLAG([-msse2])
   114    AC_CHECK_OBJCFLAG([-mfpmath=sse])
   115 ])
   116 fi
   118 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
   119 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
   120   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
   121 fi
   123 dnl ------------------ C Compiler flags -----------------------
   124 CFLAGS_FOR_BUILD="-O2 -std=c99"
   125 CFLAGS="-g -fexceptions"
   126 OBJCFLAGS="-g -fexceptions"
   127 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
   129 STDCFLAG="-std=c99"
   130 AC_CC_VERSION([ CCOPT="-O2" 
   131                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   132               [ CCOPT="$CFLAGS -fast"
   133                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   134               [ CCOPT="$CFLAGS -O2" ])
   135 AC_CHECK_CFLAG([-msse2])
   136 AC_CHECK_CFLAG([-mfpmath=sse])
   138 if test "x$enable_optimized" = "xyes"; then
   139    CFLAGS="$CFLAGS $CCOPT"
   140    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
   141    if test "x$enable_profiled" != "xyes"; then
   142        dnl -fomit-frame-pointer can't be used with -pg
   143        CFLAGS="$CFLAGS -fomit-frame-pointer"
   144        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
   145    fi
   146 else
   147    CFLAGS="$CFLAGS -g3"
   148    OBJCFLAGS="$OBJCFLAGS -g3"
   149 fi
   151 if test "x$enable_profiled" = "xyes"; then
   152    CFLAGS="$CFLAGS -pg"
   153    LDFLAGS="$LDFLAGS -pg";
   154    OBJCFLAGS="$OBJCFLAGS -pg";
   155 fi
   157 if test "x$enable_strictwarn" = "xyes"; then
   158    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   159    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   160 fi
   162 if test "x$enable_shared" != "xno"; then
   163    if test "x$APPLE_BUILD" = "xyes"; then
   164       SOEXT="dylib"
   165       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
   166    else 
   167       SOEXT="so"
   168       PLUGINLDFLAGS="-shared"
   169    fi
   170    PLUGINCFLAGS="-fPIC"
   172 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
   173    AC_CHECK_HEADER( [dlfcn.h], [
   174       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
   175    if test "x$have_dlopen" != "xyes"; then
   176       if test "x$enable_shared" == "xyes"; then
   177          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
   178       else
   179          AC_MSG_WARN("Statically linking all plugins")
   180       fi
   181    fi
   183 dnl Check if linker accepts -rdynamic
   184    AC_MSG_CHECKING([if linker accepts -rdynamic])
   185    old_LDFLAGS="$LDFLAGS"
   186    LDFLAGS="$LDFLAGS -rdynamic"
   187    AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
   188      LXDREAMLDFLAGS="-rdynamic"
   189      AC_MSG_RESULT([yes]) 
   190    ], [
   191      LXDREAMLDFLAGS=""
   192      AC_MSG_RESULT([no]) ])
   193    LDFLAGS="$old_LDFLAGS"
   195    AC_SUBST(SOEXT)
   196    AC_SUBST(PLUGINCFLAGS)
   197    AC_SUBST(PLUGINLDFLAGS)
   198    AC_SUBST(LXDREAMLDFLAGS)
   199 fi
   200 if test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"; then
   201     AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])
   202 fi
   203 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"])
   205 AC_CHECK_FASTCALL([
   206    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   207 ])
   208 AC_CHECK_FORCEINLINE()
   209 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
   210 AC_CHECK_FRAME_ADDRESS( [
   211    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   212 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   214 AC_SUBST(LXDREAMCPPFLAGS)
   215 AC_SEARCH_LIBS(listen, [socket])
   216 AC_SEARCH_LIBS(inet_ntoa,[nsl])
   218 dnl ----------- Check for mandatory dependencies --------------
   219 dnl Check for libpng (required)
   220 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   222 dnl Implied by libpng, but check explicitly just in case
   223 AC_CHECK_LIB(z, uncompress, [], [
   224     echo "Zlib (libz.so) could not be found, but is required."
   225     exit 1])
   227 dnl Check for libm (optional, required on some platforms)
   228 AC_CHECK_LIB(m, sqrt)
   230 if test "x$with_gtk" = "xno"; then
   231    dnl Check for GLIB only
   232    PKG_CHECK_MODULES(GLIB, glib-2.0)
   233 else
   234    dnl Check for GTK
   235    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   236        HAVE_GTK='yes'
   237        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   238        UI_DRIVER="GTK"
   239    ])
   241    dnl Which GTK port do we have?
   242    LIBS="$LIBS $GTK_LIBS"
   243    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   244       HAVE_GTK_X11='yes'
   245       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   246       dnl Add -lX11 explicitly as some pkg-configs get it wrong
   247       GTK_LIBS="$GTK_LIBS -lX11"
   248       LIBS="$LIBS -lX11"
   249    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   250       HAVE_GTK_OSX='yes'
   251       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   252    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
   253       AC_MSG_FAILURE( [Unable to identify GTK platform] )
   254    fi
   255 fi
   257 AC_PUSH_CC_FOR_BUILD
   258 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)
   259 AC_POP_CC_FOR_BUILD
   261 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   263 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
   264 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
   265    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
   266       dnl LIBS="-lisofs $LIBS"
   267    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])], 
   268       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
   270 dnl ------------------ Video driver support -------------------
   271 AS_IF([test "x$with_osmesa" != xno], [ 
   273 dnl User requested OSMesa (ie pure software rendering)
   274   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   275     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   276   AC_CHECK_HEADER([GL/osmesa.h], [],
   277     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   278   HAVE_OSMESA='yes'
   279   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   280   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   282 dnl Otherwise we want a real GL library (unless we're on darwin or android, in which case it's already
   283 dnl taken care of above).
   284    if test "x$APPLE_BUILD" != 'xyes' -a "x$ANDROID_BUILD" != 'xyes'; then
   285       PKG_CHECK_MODULES(LIBGL, [gl] )
   286       dnl AC_CHECK_LIB(GL, glVertex3f, [], [
   287           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   288       dnl AC_CHECK_HEADER([GL/gl.h], [], [
   289           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   290       LIBS="$LIBS $LIBGL_LIBS";
   291       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
   292    else
   293       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   294          HAVE_NSGL='yes'
   295          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   296          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   297    fi
   299 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   300    if test "x$HAVE_GTK_X11" = "xyes"; then
   301       if test "x$APPLE_BUILD" = "xyes"; then
   302          LIBS="$LIBS -L/usr/X11/lib -lGL"
   303       fi
   304       AC_CHECK_FUNC(glXQueryVersion, [
   305          HAVE_GLX='yes'
   306          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   307          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   308    fi
   310 ])
   314 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   315 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   316 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   318 dnl Check for optional (but highly desireable) OpenGL features
   319 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
   320 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
   321 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   322 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   323 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   324 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])
   325 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident function]) ], [])
   326 AC_CHECK_FUNC(glDrawBuffer, [ AC_DEFINE([HAVE_OPENGL_DRAW_BUFFER],1,[Have glDrawBuffer function])], [])
   327 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.
   329 dnl ------------------- SH4 translator target -------------------
   331 if test "x$enable_translator" != "xno"; then
   332     case $host_cpu in
   333         i386|i486|i586|i686|x86_64)
   334 	    SH4_TRANSLATOR="x86"
   335             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   336     esac
   337 fi
   338 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   340 dnl ------------------ Optional driver support -------------------
   341 dnl Check for Apple CoreAudio
   342 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   343      HAVE_CORE_AUDIO=yes
   344      LIBS="$LIBS -framework CoreAudio"
   345      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   346      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   347 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   349 dnl Check for SDL (only used for audio at the moment)
   350 if test "x$with_sdl" != "xno"; then
   351    PKG_CHECK_MODULES(SDL, [sdl], [
   352        HAVE_SDL='yes'
   353        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
   354        AC_DEFINE([HAVE_SDL],1,[Have SDL support])
   355    ], [
   356       if test "x$with_sdl" = "xyes"; then
   357          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
   358       fi
   359    ])
   360 fi
   361 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
   363 dnl Check for pulseaudio
   364 if test "x$with_pulse" != "xno"; then
   365    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   366        HAVE_PULSE='yes'
   367        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   368        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   369    ], [
   370        if test "x$with_pulse" = "xyes"; then
   371           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   372        fi
   373    ])
   374 fi
   375 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   377 dnl Check for esound
   378 if test "x$with_esd" != "xno"; then
   379    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   380        HAVE_ESOUND='yes'
   381        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   382        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   383    ], [
   384        if test "x$with_esd" = "xyes"; then
   385           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   386        fi
   387    ])
   388 fi
   389 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   391 dnl Check for alsa support
   392 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   393      HAVE_ALSA='yes'
   394      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   395      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   396 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   399 dnl Check for native cdrom support. There can be only one.
   400 if test "$ANDROID_BUILD" != "yes"; then
   401   AC_CHECK_HEADER([linux/cdrom.h], [
   402      CDROM_DRIVER=linux
   403      dnl Some kernel versions have non-c99 compliant headers - check here
   404      AC_MSG_CHECKING([C99 compliant kernel headers])
   405      old_CFLAGS="$CFLAGS"
   406      CFLAGS="$CFLAGS $STDCFLAG"
   407      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
   408         AC_MSG_RESULT([No])
   409         STDCFLAG="-std=gnu99"])
   410      CFLAGS="$old_CFLAGS"
   411   ], [true])
   412   AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   413        CDROM_DRIVER=osx
   414        LIBS="$LIBS -framework IOKit"],[true])
   415 fi
   416 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   417 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   418 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   419 if test "x$CDROM_DRIVER" = "xlinux"; then
   420    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
   421 fi
   423 AC_CHECK_HEADER([linux/joystick.h], [
   424     HAVE_LINUX_JOYSTICK_H=yes
   425     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) 
   426     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ], 
   427   [ echo "Linux Joystick support not found, building without it."] )
   428 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   430 dnl Check for LIRC
   431 if test "x$with_lirc" != "xno"; then
   432     AC_CHECK_HEADER([lirc/lirc_client.h], [
   433         HAVE_LIRC_CLIENT_H=yes
   434         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) 
   435         INPUT_DRIVERS="$INPUT_DRIVERS lirc"
   436       ],
   437       [ echo "LIRC support not found, building without it." ] )
   438 fi
   439 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
   441 dnl Check for cross-compiler availability - needed for system tests
   442 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   443 AC_PATH_PROG(SHLD, [sh-elf-ld])
   444 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   445 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   446 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   447 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   449 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   450   BUILD_SH="no"
   451   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   452 else
   453   BUILD_SH="yes"
   454 fi
   455 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   456   BUILD_ARM="no"
   457   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   458 else
   459   BUILD_ARM="yes"
   460 fi
   461 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   462 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   464 CFLAGS="$CFLAGS $STDCFLAG"
   466 dnl ----------------------- All done, finish up -----------------------
   467 GETTEXT_PACKAGE=lxdream
   468 LXDREAM_LIBS="$LIBS"
   469 LIBS=""
   470 AC_SUBST(LXDREAM_LIBS)
   471 AC_SUBST(GETTEXT_PACKAGE)
   472 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   474 dnl Add the languages which your application supports here.
   475 ALL_LINGUAS="de es it nl pt_BR"
   476 AM_GLIB_GNU_GETTEXT
   478 AC_OUTPUT([
   479 Makefile
   480 src/Makefile
   481 src/tools/Makefile
   482 po/Makefile.in
   483 test/Makefile
   484 Info.plist
   485 ])
   486 AS_MKDIR_P(test/sh4)
   488 dnl ------------------------- Print out a summary ----------------------
   490 echo
   491 echo "Configuration complete"
   492 echo
   494 if test "x$UI_DRIVER" = x; then
   495   echo "  User interface: none"
   496 else
   497   echo "  User interface: $UI_DRIVER"
   498 fi
   500 if test "x$SH4_TRANSLATOR" = "x"; then
   501   echo "  SH4 translator: none (emulation core only)"
   502 else
   503   echo "  SH4 translator: $SH4_TRANSLATOR"
   504 fi
   506 if test "x$VIDEO_DRIVERS" = "x"; then
   507    echo "  Video drivers: none (no supported GL found)"
   508 else
   509    echo "  Video drivers: $VIDEO_DRIVERS"
   510 fi
   512 if test "x$AUDIO_DRIVERS" = "x"; then
   513    echo "  Audio drivers: none (no supported output devices found)"
   514 else
   515    echo "  Audio drivers: $AUDIO_DRIVERS"
   516 fi
   518 if test "x$INPUT_DRIVERS" = "x"; then
   519    echo "  Input drivers: none (no supported input devices found)"
   520 else
   521    echo "  Input drivers: $INPUT_DRIVERS"
   522 fi
   524 if test "x$CDROM_DRIVER" = "x"; then
   525    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   526 else
   527    echo "  CD-ROM driver:  $CDROM_DRIVER"
   528 fi
.