Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 966:0f0320cb3650
prev964:f2f3c7612d06
next977:8514fb4bc101
author nkeynes
date Thu Jan 15 11:16:48 2009 +0000 (10 years ago)
permissions -rw-r--r--
last change Make --enable-strict-warn work again
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AC_PROG_OBJC
    12 AC_PROG_SED
    13 AM_PROG_AS
    14 AC_CHECK_SIZEOF([void *])
    15 AC_HEADER_STDC
    16 AC_CANONICAL_BUILD
    17 AC_CANONICAL_HOST
    19 _AM_DEPENDENCIES([OBJC])
    21 AC_PATH_PROG(POD2MAN, [pod2man])
    22 AC_PATH_PROG(POD2HTML, [pod2html])
    24 dnl ---------------- enable/with flags ------------------
    26 AC_ARG_ENABLE( strict-warn,
    27    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    28    [if test "$enableval" == "yes"; then
    29       enable_strictwarn=yes
    30     fi] )
    31 AC_ARG_ENABLE( translator, 
    32    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    33    [true], [enable_translator=yes] )
    34 AC_ARG_ENABLE( optimized,
    35    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    36    [true], [enable_optimized=yes] )
    37 AC_ARG_ENABLE( profiled,
    38    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    39    [if test "$enableval" == "yes"; then
    40       enable_profiled=yes;
    41     fi] )
    42 AC_ARG_ENABLE( trace, 
    43    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    44    [if test "$enableval" == "yes"; then
    45      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    46     fi] )
    47 AC_ARG_ENABLE( watch,
    48    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    49    [if test "$enableval" == "yes"; then
    50      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    51    fi] )
    52 AC_ARG_ENABLE( sh4stats,
    53    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    54    [if test "$enableval" == "yes"; then
    55      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    56     fi] )
    57 AC_ARG_WITH( osmesa,
    58    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    59    [], [with_osmesa=no])
    60 AC_ARG_WITH( gtk,
    61    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    62 AC_ARG_WITH( esd,
    63    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    64 AC_ARG_WITH( pulse,
    65    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    67 dnl ------------------ Compiler flags -----------------------
    68 CFLAGS="-g -fexceptions"
    69 OBJCFLAGS="-g -fexceptions"
    70 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
    72 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse" 
    73                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
    74               [ CCOPT="$CFLAGS -fast" ],
    75               [ CCOPT="$CFLAGS -O2" ])
    76 AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"
    77                   OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
    78                 [ OBJCOPT="-O2" ], [] )
    80 if test "x$enable_optimized" = "xyes"; then
    81    CFLAGS="$CFLAGS $CCOPT"
    82    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
    83    if test "x$enable_profiled" != "xyes"; then
    84        dnl -fomit-frame-pointer can't be used with -pg
    85        CFLAGS="$CFLAGS -fomit-frame-pointer"
    86        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
    87    fi
    88 else
    89    CFLAGS="$CFLAGS -g3"
    90    OBJCFLAGS="$OBJCFLAGS -g3"
    91 fi
    93 if test "x$enable_profiled" = "xyes"; then
    94    CFLAGS="$CFLAGS -pg"
    95    LDFLAGS="$LDFLAGS -pg";
    96    OBJCFLAGS="$OBJCFLAGS -pg";
    97 fi
    99 if test "x$enable_strictwarn" = "xyes"; then
   100    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   101    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   102 fi
   104 AC_CHECK_FASTCALL([
   105    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   106 ])
   107 AC_CHECK_FRAME_ADDRESS( [
   108    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   109 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   112 dnl ------------ Check if we're building on Darwin --------------
   114 dnl For starters, do we have a working objective-c compiler?
   115 AC_LANG_OBJC
   117 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
   118       HAVE_COCOA='yes'
   119       APPLE_BUILD='yes'
   120       LIBS="$LIBS -framework AppKit"
   121       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
   122       CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
   123       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
   124       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
   125       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
   126       if test "x$with_gtk" = "xx11"; then
   127         with_gtk=no
   128       fi
   129 ])
   131 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
   132 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
   133   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
   134 fi
   136 AC_LANG_C
   138 dnl ----------- Check for mandatory dependencies --------------
   139 dnl Check for libpng (required)
   140 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   142 dnl Implied by libpng, but check explicitly just in case
   143 AC_CHECK_LIB(z, uncompress, [], [
   144     echo "Zlib (libz.so) could not be found, but is required."
   145     exit 1])
   147 if test "x$with_gtk" = "xno"; then
   148    dnl Check for GLIB only
   149    PKG_CHECK_MODULES(GLIB, glib-2.0)
   150 else
   151    dnl Check for GTK
   152    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   153        HAVE_GTK='yes'
   154        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   155    ])
   157    dnl Which GTK port do we have?
   158    LIBS="$LIBS $GTK_LIBS"
   159    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   160       HAVE_GTK_X11='yes'
   161       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   162    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   163       HAVE_GTK_OSX='yes'
   164       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   165 fi
   167 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   169 dnl ------------------ Video driver support -------------------
   170 AS_IF([test "x$with_osmesa" != xno], [ 
   172 dnl User requested OSMesa (ie pure software rendering)
   173   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   174     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   175   AC_CHECK_HEADER([GL/osmesa.h], [],
   176     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   177   HAVE_OSMESA='yes'
   178   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   179   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   181 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   182 dnl taken care of above).
   183    if test "x$APPLE_BUILD" != 'xyes'; then
   184       AC_CHECK_LIB(GL, glVertex3f, [], [
   185           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   186       AC_CHECK_HEADER([GL/gl.h], [], [
   187           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   188    else
   189       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   190          HAVE_NSGL='yes'
   191          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   192          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   193    fi
   195 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   196    if test "x$HAVE_GTK_X11" = "xyes"; then
   197       if test "x$APPLE_BUILD" = "xyes"; then
   198          LIBS="$LIBS -L/usr/X11/lib -lGL"
   199       fi
   200       AC_CHECK_FUNC(glXQueryVersion, [
   201          HAVE_GLX='yes'
   202          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   203          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   204    fi
   206 ])
   210 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   211 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   212 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   214 dnl Check for optional (but highly desireable) OpenGL features
   215 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   216 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   217 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   218 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   221 dnl ------------------- SH4 translator target -------------------
   223 if test "x$enable_translator" != "xno"; then
   224     case $host_cpu in
   225         i386|i486|i586|i686|x86_64)
   226 	    SH4_TRANSLATOR="x86"
   227             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   228     esac
   229 fi
   230 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   232 dnl ------------------ Optional driver support -------------------
   233 dnl Check for Apple CoreAudio
   234 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   235      HAVE_CORE_AUDIO=yes
   236      LIBS="$LIBS -framework CoreAudio"
   237      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   238      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   239 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   241 dnl Check for pulseaudio
   242 if test "x$with_pulse" != "xno"; then
   243    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   244        HAVE_PULSE='yes'
   245        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   246        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   247    ], [
   248        if test "x$with_pulse" = "xyes"; then
   249           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   250        fi
   251    ])
   252 fi
   253 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   255 dnl Check for esound
   256 if test "x$with_esd" != "xno"; then
   257    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   258        HAVE_ESOUND='yes'
   259        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   260        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   261    ], [
   262        if test "x$with_esd" = "xyes"; then
   263           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   264        fi
   265    ])
   266 fi
   267 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   269 dnl Check for alsa support
   270 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   271      HAVE_ALSA='yes'
   272      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   273      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   274 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   277 dnl Check for native cdrom support. There can be only one.
   278 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   279 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   280      CDROM_DRIVER=osx
   281      LIBS="$LIBS -framework IOKit"],[true])
   282 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   283 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   284 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   286 AC_CHECK_HEADER([linux/joystick.h], [
   287     HAVE_LINUX_JOYSTICK_H=yes
   288     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   289   [ echo "Linux Joystick support not found, building without it."] )
   290 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   292 dnl Check for cross-compiler availability - needed for system tests
   293 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   294 AC_PATH_PROG(SHLD, [sh-elf-ld])
   295 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   296 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   297 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   298 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   300 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   301   BUILD_SH="no"
   302   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   303 else
   304   BUILD_SH="yes"
   305 fi
   306 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   307   BUILD_ARM="no"
   308   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   309 else
   310   BUILD_ARM="yes"
   311 fi
   312 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   313 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   316 dnl ----------------------- All done, finish up -----------------------
   317 GETTEXT_PACKAGE=lxdream
   318 AC_SUBST(GETTEXT_PACKAGE)
   319 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   321 dnl Add the languages which your application supports here.
   322 ALL_LINGUAS="de es it pt_BR"
   323 AM_GLIB_GNU_GETTEXT
   325 AC_OUTPUT([
   326 Makefile
   327 src/Makefile
   328 po/Makefile.in
   329 test/Makefile
   330 Info.plist
   331 ])
   332 AS_MKDIR_P(test/sh4)
   334 dnl ------------------------- Print out a summary ----------------------
   336 echo
   337 echo "Configuration complete"
   338 echo
   340 if test "x$HAVE_GTK" = x; then
   341   if test "x$HAVE_COCOA" = x; then
   342      echo "  User interface: none"
   343   else
   344      echo "  User interface: Cocoa"
   345   fi
   346 else
   347   echo "  User interface: GTK"
   348 fi
   350 if test "x$SH4_TRANSLATOR" = "x"; then
   351   echo "  SH4 translator: None (emulation core only)"
   352 else
   353   echo "  SH4 translator: $SH4_TRANSLATOR"
   354 fi
   356 if test "x$VIDEO_DRIVERS" = "x"; then
   357    echo "  Video drivers: none (no supported GL found)"
   358 else
   359    echo "  Video drivers: $VIDEO_DRIVERS"
   360 fi
   362 if test "x$AUDIO_DRIVERS" = "x"; then
   363    echo "  Audio drivers: none (no supported output devices found)"
   364 else
   365    echo "  Audio drivers: $AUDIO_DRIVERS"
   366 fi
   368 if test "x$CDROM_DRIVER" = "x"; then
   369    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   370 else
   371    echo "  CD-ROM driver: $CDROM_DRIVER"
   372 fi
.