Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 1174:252d50f93cf6
prev1147:e04e4af64626
next1199:62d0a21fac1c
author nkeynes
date Thu Dec 01 08:02:13 2011 +1000 (8 years ago)
permissions -rw-r--r--
last change Fix make check
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AC_PROG_OBJC
    12 AC_PROG_SED
    13 AM_PROG_AS
    14 AC_CHECK_SIZEOF([void *])
    15 AC_HEADER_STDC
    16 AC_CANONICAL_BUILD
    17 AC_CANONICAL_HOST
    19 _AM_DEPENDENCIES([OBJC])
    21 AC_PATH_PROG(POD2MAN, [pod2man])
    22 AC_PATH_PROG(POD2HTML, [pod2html])
    24 dnl ---------------- enable/with flags ------------------
    26 AC_ARG_ENABLE( strict-warn,
    27    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    28    [if test "$enableval" == "yes"; then
    29       enable_strictwarn=yes
    30     fi] )
    31 AC_ARG_ENABLE( translator, 
    32    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    33    [true], [enable_translator=yes] )
    34 AC_ARG_ENABLE( optimized,
    35    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    36    [true], [enable_optimized=yes] )
    37 AC_ARG_ENABLE( shared,
    38    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
    39    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
    40 AC_ARG_ENABLE( profiled,
    41    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    42    [if test "$enableval" == "yes"; then
    43       enable_profiled=yes;
    44     fi] )
    45 AC_ARG_ENABLE( trace, 
    46    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    47    [if test "$enableval" == "yes"; then
    48      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    49     fi] )
    50 AC_ARG_ENABLE( watch,
    51    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    52    [if test "$enableval" == "yes"; then
    53      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    54    fi] )
    55 AC_ARG_ENABLE( sh4stats,
    56    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    57    [if test "$enableval" == "yes"; then
    58      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    59     fi] )
    60 AC_ARG_WITH( osmesa,
    61    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    62    [], [with_osmesa=no])
    63 AC_ARG_WITH( gtk,
    64    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    65 AC_ARG_WITH( esd,
    66    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    67 AC_ARG_WITH( pulse,
    68    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    69 AC_ARG_WITH( sdl,
    70    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
    73 dnl ------------ Check if we're building on Darwin --------------
    75 dnl For starters, do we have a working objective-c compiler?
    76 AC_HAVE_OBJC([
    77    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    78       HAVE_COCOA='yes'
    79       APPLE_BUILD='yes'
    80       LIBS="$LIBS -framework AppKit -framework Carbon"
    81       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    82       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
    83       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    84       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    85       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    86       if test "x$with_gtk" = "xx11"; then
    87         with_gtk=no
    88       fi
    89    ], [], [AC_INCLUDES_DEFAULT])
    91    AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"
    92                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
    93                    [ OBJCOPT="-O2" ], [] )
    94 ])
    96 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    97 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
    98   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
    99 fi
   101 dnl ------------------ C Compiler flags -----------------------
   102 CFLAGS="-g -fexceptions"
   103 OBJCFLAGS="-g -fexceptions"
   104 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
   106 STDCFLAG="-std=c99"
   107 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse" 
   108                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   109               [ CCOPT="$CFLAGS -fast"
   110                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   111               [ CCOPT="$CFLAGS -O2" ])
   113 if test "x$enable_optimized" = "xyes"; then
   114    CFLAGS="$CFLAGS $CCOPT"
   115    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
   116    if test "x$enable_profiled" != "xyes"; then
   117        dnl -fomit-frame-pointer can't be used with -pg
   118        CFLAGS="$CFLAGS -fomit-frame-pointer"
   119        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
   120    fi
   121 else
   122    CFLAGS="$CFLAGS -g3"
   123    OBJCFLAGS="$OBJCFLAGS -g3"
   124 fi
   126 if test "x$enable_profiled" = "xyes"; then
   127    CFLAGS="$CFLAGS -pg"
   128    LDFLAGS="$LDFLAGS -pg";
   129    OBJCFLAGS="$OBJCFLAGS -pg";
   130 fi
   132 if test "x$enable_strictwarn" = "xyes"; then
   133    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   134    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   135 fi
   137 if test "x$enable_shared" != "xno"; then
   138    AC_DEFINE(ENABLE_SHARED, [1], [Enable shared-library plugins])
   139    if test "x$APPLE_BUILD" = "xyes"; then
   140       SOEXT="dylib"
   141       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
   142    else 
   143       SOEXT="so"
   144       PLUGINLDFLAGS="-shared"
   145    fi
   146    PLUGINCFLAGS="-fPIC"
   148 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
   149    AC_CHECK_HEADER( [dlfcn.h], [
   150       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
   151    if test "x$have_dlopen" != "xyes"; then
   152       if test "x$enable_shared" == "xyes"; then
   153          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
   154       else
   155          AC_MSG_WARN("Statically linking all plugins")
   156       fi
   157    fi
   159 dnl Check if linker accepts -rdynamic
   160    AC_MSG_CHECKING([if linker accepts -rdynamic])
   161    old_LDFLAGS="$LDFLAGS"
   162    LDFLAGS="$LDFLAGS -rdynamic"
   163    AC_LINK_IFELSE( [int main(){ return 0; }], [
   164      LXDREAMLDFLAGS="-rdynamic"
   165      AC_MSG_RESULT([yes]) 
   166    ], [
   167      LXDREAMLDFLAGS=""
   168      AC_MSG_RESULT([no]) ])
   169    LDFLAGS="$old_LDFLAGS"
   171    AC_SUBST(SOEXT)
   172    AC_SUBST(PLUGINCFLAGS)
   173    AC_SUBST(PLUGINLDFLAGS)
   174    AC_SUBST(LXDREAMLDFLAGS)
   175 fi
   176 AM_CONDITIONAL(BUILD_SHARED, [test "x$have_dlopen" = "xyes"])
   178 AC_CHECK_FASTCALL([
   179    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   180 ])
   181 AC_CHECK_FORCEINLINE()
   182 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
   183 AC_CHECK_FRAME_ADDRESS( [
   184    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   185 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   187 AC_SUBST(LXDREAMCPPFLAGS)
   188 AC_SEARCH_LIBS(listen, [socket])
   189 AC_SEARCH_LIBS(inet_ntoa,[nsl])
   191 dnl ----------- Check for mandatory dependencies --------------
   192 dnl Check for libpng (required)
   193 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   195 dnl Implied by libpng, but check explicitly just in case
   196 AC_CHECK_LIB(z, uncompress, [], [
   197     echo "Zlib (libz.so) could not be found, but is required."
   198     exit 1])
   200 if test "x$with_gtk" = "xno"; then
   201    dnl Check for GLIB only
   202    PKG_CHECK_MODULES(GLIB, glib-2.0)
   203 else
   204    dnl Check for GTK
   205    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   206        HAVE_GTK='yes'
   207        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   208    ])
   210    dnl Which GTK port do we have?
   211    LIBS="$LIBS $GTK_LIBS"
   212    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   213       HAVE_GTK_X11='yes'
   214       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   215       dnl Add -lX11 explicitly as some pkg-configs get it wrong
   216       GTK_LIBS="$GTK_LIBS -lX11"
   217       LIBS="$LIBS -lX11"
   218    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   219       HAVE_GTK_OSX='yes'
   220       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   221    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
   222       AC_MSG_FAILURE( [Unable to identify GTK platform] )
   223    fi
   224 fi
   226 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   228 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
   229 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
   230    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
   231       dnl LIBS="$LIBS -lisofs"
   232    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])], 
   233       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
   235 dnl ------------------ Video driver support -------------------
   236 AS_IF([test "x$with_osmesa" != xno], [ 
   238 dnl User requested OSMesa (ie pure software rendering)
   239   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   240     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   241   AC_CHECK_HEADER([GL/osmesa.h], [],
   242     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   243   HAVE_OSMESA='yes'
   244   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   245   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   247 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   248 dnl taken care of above).
   249    if test "x$APPLE_BUILD" != 'xyes'; then
   250       PKG_CHECK_MODULES(LIBGL, [gl] )
   251       dnl AC_CHECK_LIB(GL, glVertex3f, [], [
   252           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   253       dnl AC_CHECK_HEADER([GL/gl.h], [], [
   254           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   255       LIBS="$LIBS $LIBGL_LIBS";
   256       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
   257    else
   258       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   259          HAVE_NSGL='yes'
   260          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   261          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   262    fi
   264 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   265    if test "x$HAVE_GTK_X11" = "xyes"; then
   266       if test "x$APPLE_BUILD" = "xyes"; then
   267          LIBS="$LIBS -L/usr/X11/lib -lGL"
   268       fi
   269       AC_CHECK_FUNC(glXQueryVersion, [
   270          HAVE_GLX='yes'
   271          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   272          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   273    fi
   275 ])
   279 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   280 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   281 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   283 dnl Check for optional (but highly desireable) OpenGL features
   284 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   285 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   286 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   287 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   290 dnl ------------------- SH4 translator target -------------------
   292 if test "x$enable_translator" != "xno"; then
   293     case $host_cpu in
   294         i386|i486|i586|i686|x86_64)
   295 	    SH4_TRANSLATOR="x86"
   296             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   297     esac
   298 fi
   299 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   301 dnl ------------------ Optional driver support -------------------
   302 dnl Check for Apple CoreAudio
   303 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   304      HAVE_CORE_AUDIO=yes
   305      LIBS="$LIBS -framework CoreAudio"
   306      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   307      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   308 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   310 dnl Check for SDL (only used for audio at the moment)
   311 if test "x$with_sdl" != "xno"; then
   312    PKG_CHECK_MODULES(SDL, [sdl], [
   313        HAVE_SDL='yes'
   314        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
   315        AC_DEFINE([HAVE_SDL],1,[Have SDL support])
   316    ], [
   317       if test "x$with_sdl" = "xyes"; then
   318          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
   319       fi
   320    ])
   321 fi
   322 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
   324 dnl Check for pulseaudio
   325 if test "x$with_pulse" != "xno"; then
   326    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   327        HAVE_PULSE='yes'
   328        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   329        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   330    ], [
   331        if test "x$with_pulse" = "xyes"; then
   332           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   333        fi
   334    ])
   335 fi
   336 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   338 dnl Check for esound
   339 if test "x$with_esd" != "xno"; then
   340    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   341        HAVE_ESOUND='yes'
   342        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   343        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   344    ], [
   345        if test "x$with_esd" = "xyes"; then
   346           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   347        fi
   348    ])
   349 fi
   350 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   352 dnl Check for alsa support
   353 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   354      HAVE_ALSA='yes'
   355      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   356      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   357 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   360 dnl Check for native cdrom support. There can be only one.
   361 AC_CHECK_HEADER([linux/cdrom.h], [
   362      CDROM_DRIVER=linux
   363      dnl Some kernel versions have non-c99 compliant headers - check here
   364      AC_MSG_CHECKING([C99 compliant kernel headers])
   365      old_CFLAGS="$CFLAGS"
   366      CFLAGS="$CFLAGS $STDCFLAG"
   367      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
   368         AC_MSG_RESULT([No])
   369         STDCFLAG="-std=gnu99"])
   370      CFLAGS="$old_CFLAGS"
   371 ], [true])
   372 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   373      CDROM_DRIVER=osx
   374      LIBS="$LIBS -framework IOKit"],[true])
   375 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   376 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   377 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   378 if test "x$CDROM_DRIVER" = "xlinux"; then
   379    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
   380 fi
   382 AC_CHECK_HEADER([linux/joystick.h], [
   383     HAVE_LINUX_JOYSTICK_H=yes
   384     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) 
   385     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ], 
   386   [ echo "Linux Joystick support not found, building without it."] )
   387 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   389 dnl Check for LIRC
   390 if test "x$with_lirc" != "xno"; then
   391     AC_CHECK_HEADER([lirc/lirc_client.h], [
   392         HAVE_LIRC_CLIENT_H=yes
   393         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) 
   394         INPUT_DRIVERS="$INPUT_DRIVERS lirc"
   395       ],
   396       [ echo "LIRC support not found, building without it." ] )
   397 fi
   398 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
   400 dnl Check for cross-compiler availability - needed for system tests
   401 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   402 AC_PATH_PROG(SHLD, [sh-elf-ld])
   403 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   404 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   405 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   406 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   408 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   409   BUILD_SH="no"
   410   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   411 else
   412   BUILD_SH="yes"
   413 fi
   414 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   415   BUILD_ARM="no"
   416   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   417 else
   418   BUILD_ARM="yes"
   419 fi
   420 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   421 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   423 CFLAGS="$CFLAGS $STDCFLAG"
   425 dnl ----------------------- All done, finish up -----------------------
   426 GETTEXT_PACKAGE=lxdream
   427 LXDREAM_LIBS="$LIBS"
   428 LIBS=""
   429 AC_SUBST(LXDREAM_LIBS)
   430 AC_SUBST(GETTEXT_PACKAGE)
   431 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   433 dnl Add the languages which your application supports here.
   434 ALL_LINGUAS="de es it nl pt_BR"
   435 AM_GLIB_GNU_GETTEXT
   437 AC_OUTPUT([
   438 Makefile
   439 src/Makefile
   440 po/Makefile.in
   441 test/Makefile
   442 Info.plist
   443 ])
   444 AS_MKDIR_P(test/sh4)
   446 dnl ------------------------- Print out a summary ----------------------
   448 echo
   449 echo "Configuration complete"
   450 echo
   452 if test "x$HAVE_GTK" = x; then
   453   if test "x$HAVE_COCOA" = x; then
   454      echo "  User interface: none"
   455   else
   456      echo "  User interface: Cocoa"
   457   fi
   458 else
   459   echo "  User interface: GTK"
   460 fi
   462 if test "x$SH4_TRANSLATOR" = "x"; then
   463   echo "  SH4 translator: None (emulation core only)"
   464 else
   465   echo "  SH4 translator: $SH4_TRANSLATOR"
   466 fi
   468 if test "x$VIDEO_DRIVERS" = "x"; then
   469    echo "  Video drivers: none (no supported GL found)"
   470 else
   471    echo "  Video drivers: $VIDEO_DRIVERS"
   472 fi
   474 if test "x$AUDIO_DRIVERS" = "x"; then
   475    echo "  Audio drivers: none (no supported output devices found)"
   476 else
   477    echo "  Audio drivers: $AUDIO_DRIVERS"
   478 fi
   480 if test "x$INPUT_DRIVERS" = "x"; then
   481    echo "  Input drivers: none (no supported input devices found)"
   482 else
   483    echo "  Input drivers: $INPUT_DRIVERS"
   484 fi
   486 if test "x$CDROM_DRIVER" = "x"; then
   487    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   488 else
   489    echo "  CD-ROM driver:  $CDROM_DRIVER"
   490 fi
.