Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 709:18c39a8e504c
prev704:2c1d6f8e69e7
next714:009591ac251e
author nkeynes
date Wed Jun 25 10:40:45 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Commit OSX CD-ROM driver work-in-progress
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( trace, 
    23    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    24    [if test "$enableval" == "yes"; then
    25      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    26     fi] )
    27 AC_ARG_ENABLE( watch,
    28    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    29    [if test "$enableval" == "yes"; then
    30      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    31    fi] )
    32 AC_ARG_ENABLE( sh4stats,
    33    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    34    [if test "$enableval" == "yes"; then
    35      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    36     fi] )
    37 AC_ARG_WITH( osmesa,
    38    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    39    [], [with_osmesa=no])
    40 AC_ARG_WITH( gtk,
    41    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    43 dnl ------------ Check if we're building on Darwin --------------
    45 dnl For starters, do we have a working objective-c compiler?
    46 lxdream_save_cppflags="$CPPFLAGS"
    47 CPPFLAGS="$CPPFLAGS -x objective-c"
    48 AC_TRY_COMPILE([@interface Foo @end],, [
    50    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    51       HAVE_COCOA='yes'
    52       APPLE_BUILD='yes'
    53       LIBS="$LIBS -framework AppKit"
    54       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    55       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    56       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    57       if test "x$with_gtk" = "xx11"; then
    58         with_gtk=no
    59       fi
    60    ])
    62 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    63 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    65 dnl ----------- Check for mandatory dependencies --------------
    66 dnl Check for libpng (required)
    67 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    69 dnl Implied by libpng, but check explicitly just in case
    70 AC_CHECK_LIB(z, uncompress, [], [
    71     echo "Zlib (libz.so) could not be found, but is required."
    72     exit 1])
    74 if test "x$with_gtk" = "xno"; then
    75    dnl Check for GLIB only
    76    PKG_CHECK_MODULES(GLIB, glib-2.0)
    77 else
    78    dnl Check for GTK
    79    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    80        HAVE_GTK='yes'
    81        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    82    ])
    84    dnl Which GTK port do we have?
    85    LIBS="$LIBS $GTK_LIBS"
    86    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    87       HAVE_GTK_X11='yes'
    88       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    89    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    90       HAVE_GTK_OSX='yes'
    91       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    92 fi
    94 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    96 dnl ------------------ Video driver support -------------------
    97 AS_IF([test "x$with_osmesa" != xno], [ 
    99 dnl User requested OSMesa (ie pure software rendering)
   100   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   101     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   102   AC_CHECK_HEADER([GL/osmesa.h], [],
   103     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   104   HAVE_OSMESA='yes'
   105   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   106   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   108 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   109 dnl taken care of above).
   110    if test "x$APPLE_BUILD" != 'xyes'; then
   111       AC_CHECK_LIB(GL, glVertex3f, [], [
   112           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   113       AC_CHECK_HEADER([GL/gl.h], [], [
   114           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   115    else
   116       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   117          HAVE_NSGL='yes'
   118          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   119          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   120    fi
   122 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   123    if test "x$HAVE_GTK_X11" = "xyes"; then
   124       if test "x$APPLE_BUILD" = "xyes"; then
   125          LIBS="$LIBS -L/usr/X11/lib -lGL"
   126       fi
   127       AC_CHECK_FUNC(glXQueryVersion, [
   128          HAVE_GLX='yes'
   129          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   130          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   131    fi
   133 ])
   137 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   138 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   139 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   141 dnl Check for optional (but highly desireable) OpenGL features
   142 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   143 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   144 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   145 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   148 dnl Check for a supported cpu target for translation purposes
   149 case $host_cpu in
   150     i386|i486|i586|i686|x86_64)
   151 	SH4_TRANSLATOR="x86"
   152         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   153 esac
   154 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   155 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   157 dnl ------------------ Optional driver support -------------------
   158 dnl Check for Apple CoreAudio
   159 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   160      HAVE_CORE_AUDIO=yes
   161      LIBS="$LIBS -framework CoreAudio"
   162      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   163      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   164 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   166 dnl Check for pulseaudio
   167 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   168      HAVE_PULSE='yes'
   169      AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   170      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
   171 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   173 dnl Check for esound
   174 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   175      HAVE_ESOUND='yes'
   176      AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   177      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   178 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   180 dnl Check for alsa support
   181 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   182      HAVE_ALSA='yes'
   183      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   184      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   185 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   188 dnl Check for native cdrom support. There can be only one.
   189 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   190 dnl AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   191 dnl     CDROM_DRIVER=osx
   192 dnl     LIBS="$LIBS -framework IOKit"],[true])
   193 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   194 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   195 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   197 AC_CHECK_HEADER([linux/joystick.h], [
   198     HAVE_LINUX_JOYSTICK_H=yes
   199     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   200   [ echo "Linux Joystick support not found, building without it."] )
   201 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   203 dnl Check for cross-compiler availability - needed for system tests
   204 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   205 AC_PATH_PROG(SHLD, [sh-elf-ld])
   206 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   207 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   208 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   209 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   211 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   212   BUILD_SH="no"
   213   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   214 else
   215   BUILD_SH="yes"
   216 fi
   217 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   218   BUILD_ARM="no"
   219   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   220 else
   221   BUILD_ARM="yes"
   222 fi
   223 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   224 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   227 dnl ----------------------- All done, finish up -----------------------
   228 GETTEXT_PACKAGE=lxdream
   229 AC_SUBST(GETTEXT_PACKAGE)
   230 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   232 dnl Add the languages which your application supports here.
   233 ALL_LINGUAS="de es it pt_BR"
   234 AM_GLIB_GNU_GETTEXT
   236 AC_OUTPUT([
   237 Makefile
   238 src/Makefile
   239 po/Makefile.in
   240 test/Makefile
   241 ])
   243 dnl ------------------------- Print out a summary ----------------------
   245 echo
   246 echo "Configuration complete"
   247 echo
   249 if test "x$HAVE_GTK" = x; then
   250   if test "x$HAVE_COCOA" = x; then
   251      echo "  User interface: none"
   252   else
   253      echo "  User interface: Cocoa"
   254   fi
   255 else
   256   echo "  User interface: GTK"
   257 fi
   259 if test "x$SH4_TRANSLATOR" = "x"; then
   260   echo "  SH4 translator: None (emulation core only)"
   261 else
   262   echo "  SH4 translator: $SH4_TRANSLATOR"
   263 fi
   265 if test "x$VIDEO_DRIVERS" = "x"; then
   266    echo "  Video drivers: none (no supported GL found)"
   267 else
   268    echo "  Video drivers: $VIDEO_DRIVERS"
   269 fi
   271 if test "x$AUDIO_DRIVERS" = "x"; then
   272    echo "  Audio drivers: none (no supported output devices found)"
   273 else
   274    echo "  Audio drivers: $AUDIO_DRIVERS"
   275 fi
   277 if test "x$CDROM_DRIVER" = "x"; then
   278    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   279 else
   280    echo "  CD-ROM driver: $CDROM_DRIVER"
   281 fi
.