filename | configure.in |
changeset | 987:3bd03f1ce0a7 |
prev | 985:52e64faac752 |
next | 989:7baf5ecd8e98 |
author | nkeynes |
date | Wed Feb 25 09:00:05 2009 +0000 (15 years ago) |
permissions | -rw-r--r-- |
last change | Argh. Apparently we still do really need _BSD_SOURCE and _GNU_SOURCE I think that's everything now... |
view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.9)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_ISC_POSIX
9 AC_PROG_CC
10 AM_PROG_CC_STDC
11 AC_PROG_OBJC
12 AC_PROG_SED
13 AM_PROG_AS
14 AC_CHECK_SIZEOF([void *])
15 AC_HEADER_STDC
16 AC_CANONICAL_BUILD
17 AC_CANONICAL_HOST
19 _AM_DEPENDENCIES([OBJC])
21 AC_PATH_PROG(POD2MAN, [pod2man])
22 AC_PATH_PROG(POD2HTML, [pod2html])
24 dnl ---------------- enable/with flags ------------------
26 AC_ARG_ENABLE( strict-warn,
27 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
28 [if test "$enableval" == "yes"; then
29 enable_strictwarn=yes
30 fi] )
31 AC_ARG_ENABLE( translator,
32 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
33 [true], [enable_translator=yes] )
34 AC_ARG_ENABLE( optimized,
35 AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
36 [true], [enable_optimized=yes] )
37 AC_ARG_ENABLE( profiled,
38 AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
39 [if test "$enableval" == "yes"; then
40 enable_profiled=yes;
41 fi] )
42 AC_ARG_ENABLE( trace,
43 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
44 [if test "$enableval" == "yes"; then
45 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
46 fi] )
47 AC_ARG_ENABLE( watch,
48 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
49 [if test "$enableval" == "yes"; then
50 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
51 fi] )
52 AC_ARG_ENABLE( sh4stats,
53 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
54 [if test "$enableval" == "yes"; then
55 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
56 fi] )
57 AC_ARG_WITH( osmesa,
58 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
59 [], [with_osmesa=no])
60 AC_ARG_WITH( gtk,
61 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
62 AC_ARG_WITH( esd,
63 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
64 AC_ARG_WITH( pulse,
65 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
67 dnl ------------ Check if we're building on Darwin --------------
69 dnl For starters, do we have a working objective-c compiler?
70 AC_HAVE_OBJC([
71 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
72 HAVE_COCOA='yes'
73 APPLE_BUILD='yes'
74 LIBS="$LIBS -framework AppKit"
75 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
76 CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
77 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
78 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
79 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
80 if test "x$with_gtk" = "xx11"; then
81 with_gtk=no
82 fi
83 ], [], [AC_INCLUDES_DEFAULT])
85 AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"
86 OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
87 [ OBJCOPT="-O2" ], [] )
88 ])
90 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
91 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
92 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
93 fi
95 dnl ------------------ C Compiler flags -----------------------
96 CFLAGS="-g -fexceptions"
97 OBJCFLAGS="-g -fexceptions"
98 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
100 STDCFLAG="-std=c99"
101 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse"
102 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
103 [ CCOPT="$CFLAGS -fast"
104 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
105 [ CCOPT="$CFLAGS -O2" ])
107 if test "x$enable_optimized" = "xyes"; then
108 CFLAGS="$CFLAGS $CCOPT"
109 OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
110 if test "x$enable_profiled" != "xyes"; then
111 dnl -fomit-frame-pointer can't be used with -pg
112 CFLAGS="$CFLAGS -fomit-frame-pointer"
113 OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
114 fi
115 else
116 CFLAGS="$CFLAGS -g3"
117 OBJCFLAGS="$OBJCFLAGS -g3"
118 fi
120 if test "x$enable_profiled" = "xyes"; then
121 CFLAGS="$CFLAGS -pg"
122 LDFLAGS="$LDFLAGS -pg";
123 OBJCFLAGS="$OBJCFLAGS -pg";
124 fi
126 if test "x$enable_strictwarn" = "xyes"; then
127 CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
128 OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
129 fi
131 AC_CHECK_FASTCALL([
132 AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
133 ])
134 AC_CHECK_FRAME_ADDRESS( [
135 AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
136 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
140 dnl ----------- Check for mandatory dependencies --------------
141 dnl Check for libpng (required)
142 PKG_CHECK_MODULES(LIBPNG, [libpng] )
144 dnl Implied by libpng, but check explicitly just in case
145 AC_CHECK_LIB(z, uncompress, [], [
146 echo "Zlib (libz.so) could not be found, but is required."
147 exit 1])
149 if test "x$with_gtk" = "xno"; then
150 dnl Check for GLIB only
151 PKG_CHECK_MODULES(GLIB, glib-2.0)
152 else
153 dnl Check for GTK
154 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
155 HAVE_GTK='yes'
156 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
157 ])
159 dnl Which GTK port do we have?
160 LIBS="$LIBS $GTK_LIBS"
161 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
162 HAVE_GTK_X11='yes'
163 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
164 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
165 HAVE_GTK_OSX='yes'
166 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
167 fi
169 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
171 dnl ------------------ Video driver support -------------------
172 AS_IF([test "x$with_osmesa" != xno], [
174 dnl User requested OSMesa (ie pure software rendering)
175 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
176 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
177 AC_CHECK_HEADER([GL/osmesa.h], [],
178 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
179 HAVE_OSMESA='yes'
180 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
181 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
183 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
184 dnl taken care of above).
185 if test "x$APPLE_BUILD" != 'xyes'; then
186 AC_CHECK_LIB(GL, glVertex3f, [], [
187 AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
188 AC_CHECK_HEADER([GL/gl.h], [], [
189 AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
190 else
191 AC_CHECK_FUNC(NSOpenGLGetVersion, [
192 HAVE_NSGL='yes'
193 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
194 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
195 fi
197 dnl Now work out how to get from the UI to GL - this is usually the painful part.
198 if test "x$HAVE_GTK_X11" = "xyes"; then
199 if test "x$APPLE_BUILD" = "xyes"; then
200 LIBS="$LIBS -L/usr/X11/lib -lGL"
201 fi
202 AC_CHECK_FUNC(glXQueryVersion, [
203 HAVE_GLX='yes'
204 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
205 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
206 fi
208 ])
212 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
213 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
214 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
216 dnl Check for optional (but highly desireable) OpenGL features
217 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
218 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
219 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
220 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
223 dnl ------------------- SH4 translator target -------------------
225 if test "x$enable_translator" != "xno"; then
226 case $host_cpu in
227 i386|i486|i586|i686|x86_64)
228 SH4_TRANSLATOR="x86"
229 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
230 esac
231 fi
232 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
234 dnl ------------------ Optional driver support -------------------
235 dnl Check for Apple CoreAudio
236 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
237 HAVE_CORE_AUDIO=yes
238 LIBS="$LIBS -framework CoreAudio"
239 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
240 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
241 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
243 dnl Check for pulseaudio
244 if test "x$with_pulse" != "xno"; then
245 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
246 HAVE_PULSE='yes'
247 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
248 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
249 ], [
250 if test "x$with_pulse" = "xyes"; then
251 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
252 fi
253 ])
254 fi
255 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
257 dnl Check for esound
258 if test "x$with_esd" != "xno"; then
259 PKG_CHECK_MODULES(ESOUND, [esound], [
260 HAVE_ESOUND='yes'
261 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
262 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
263 ], [
264 if test "x$with_esd" = "xyes"; then
265 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
266 fi
267 ])
268 fi
269 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
271 dnl Check for alsa support
272 PKG_CHECK_MODULES(ALSA, [alsa], [
273 HAVE_ALSA='yes'
274 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
275 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
276 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
279 dnl Check for native cdrom support. There can be only one.
280 AC_CHECK_HEADER([linux/cdrom.h], [
281 CDROM_DRIVER=linux
282 dnl Some kernel versions have non-c99 compliant headers - check here
283 AC_MSG_CHECKING([C99 compliant kernel headers])
284 old_CFLAGS="$CFLAGS"
285 CFLAGS="$CFLAGS $STDCFLAG"
286 AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
287 AC_MSG_RESULT([No])
288 STDCFLAG="-std=gnu99"])
289 CFLAGS="$old_CFLAGS"
290 ], [true])
291 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
292 CDROM_DRIVER=osx
293 LIBS="$LIBS -framework IOKit"],[true])
294 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
295 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
296 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
298 AC_CHECK_HEADER([linux/joystick.h], [
299 HAVE_LINUX_JOYSTICK_H=yes
300 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ],
301 [ echo "Linux Joystick support not found, building without it."] )
302 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
304 dnl Check for cross-compiler availability - needed for system tests
305 AC_PATH_PROG(SHCC, [sh-elf-gcc])
306 AC_PATH_PROG(SHLD, [sh-elf-ld])
307 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
308 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
309 AC_PATH_PROG(ARMLD, [arm-elf-ld])
310 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
312 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
313 BUILD_SH="no"
314 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
315 else
316 BUILD_SH="yes"
317 fi
318 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
319 BUILD_ARM="no"
320 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
321 else
322 BUILD_ARM="yes"
323 fi
324 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
325 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
327 CFLAGS="$CFLAGS $STDCFLAG"
329 dnl ----------------------- All done, finish up -----------------------
330 GETTEXT_PACKAGE=lxdream
331 AC_SUBST(GETTEXT_PACKAGE)
332 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
334 dnl Add the languages which your application supports here.
335 ALL_LINGUAS="de es it pt_BR"
336 AM_GLIB_GNU_GETTEXT
338 AC_OUTPUT([
339 Makefile
340 src/Makefile
341 po/Makefile.in
342 test/Makefile
343 Info.plist
344 ])
345 AS_MKDIR_P(test/sh4)
347 dnl ------------------------- Print out a summary ----------------------
349 echo
350 echo "Configuration complete"
351 echo
353 if test "x$HAVE_GTK" = x; then
354 if test "x$HAVE_COCOA" = x; then
355 echo " User interface: none"
356 else
357 echo " User interface: Cocoa"
358 fi
359 else
360 echo " User interface: GTK"
361 fi
363 if test "x$SH4_TRANSLATOR" = "x"; then
364 echo " SH4 translator: None (emulation core only)"
365 else
366 echo " SH4 translator: $SH4_TRANSLATOR"
367 fi
369 if test "x$VIDEO_DRIVERS" = "x"; then
370 echo " Video drivers: none (no supported GL found)"
371 else
372 echo " Video drivers: $VIDEO_DRIVERS"
373 fi
375 if test "x$AUDIO_DRIVERS" = "x"; then
376 echo " Audio drivers: none (no supported output devices found)"
377 else
378 echo " Audio drivers: $AUDIO_DRIVERS"
379 fi
381 if test "x$CDROM_DRIVER" = "x"; then
382 echo " CD-ROM driver: none (no supported cd-rom devices found)"
383 else
384 echo " CD-ROM driver: $CDROM_DRIVER"
385 fi
.