lxdream.org :: lxdream/configure.in r989:7baf5ecd8e98

tree revision 996:2e8cf0a87243

filename	configure.in
changeset	989:7baf5ecd8e98
prev	987:3bd03f1ce0a7
next	1002:8ad76ddbdc58
author	nkeynes
date	Tue Mar 10 04:56:43 2009 +0000 (15 years ago)
permissions	-rw-r--r--
last change	Fix stupid mistake in non-frame-exception path

view

     1 dnl Process this file with autoconf to produce a configure script.

     3 AC_INIT(configure.in)

     4 AM_INIT_AUTOMAKE(lxdream, 0.9)

     5 AM_MAINTAINER_MODE

     6 AM_CONFIG_HEADER(config.h)

     8 AC_ISC_POSIX

     9 AC_PROG_CC

    10 AM_PROG_CC_STDC

    11 AC_PROG_OBJC

    12 AC_PROG_SED

    13 AM_PROG_AS

    14 AC_CHECK_SIZEOF([void *])

    15 AC_HEADER_STDC

    16 AC_CANONICAL_BUILD

    17 AC_CANONICAL_HOST

    19 _AM_DEPENDENCIES([OBJC])

    21 AC_PATH_PROG(POD2MAN, [pod2man])

    22 AC_PATH_PROG(POD2HTML, [pod2html])

    24 dnl ---------------- enable/with flags ------------------

    26 AC_ARG_ENABLE( strict-warn,

    27    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),

    28    [if test "$enableval" == "yes"; then

    29       enable_strictwarn=yes

    30     fi] )

    31 AC_ARG_ENABLE( translator,

    32    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),

    33    [true], [enable_translator=yes] )

    34 AC_ARG_ENABLE( optimized,

    35    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),

    36    [true], [enable_optimized=yes] )

    37 AC_ARG_ENABLE( profiled,

    38    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),

    39    [if test "$enableval" == "yes"; then

    40       enable_profiled=yes;

    41     fi] )

    42 AC_ARG_ENABLE( trace,

    43    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),

    44    [if test "$enableval" == "yes"; then

    45      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])

    46     fi] )

    47 AC_ARG_ENABLE( watch,

    48    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),

    49    [if test "$enableval" == "yes"; then

    50      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])

    51    fi] )

    52 AC_ARG_ENABLE( sh4stats,

    53    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),

    54    [if test "$enableval" == "yes"; then

    55      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])

    56     fi] )

    57 AC_ARG_WITH( osmesa,

    58    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),

    59    [], [with_osmesa=no])

    60 AC_ARG_WITH( gtk,

    61    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )

    62 AC_ARG_WITH( esd,

    63    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )

    64 AC_ARG_WITH( pulse,

    65    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )

    66 AC_ARG_WITH( sdl,

    67    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )

    70 dnl ------------ Check if we're building on Darwin --------------

    72 dnl For starters, do we have a working objective-c compiler?

    73 AC_HAVE_OBJC([

    74    AC_CHECK_HEADER([Cocoa/Cocoa.h], [

    75       HAVE_COCOA='yes'

    76       APPLE_BUILD='yes'

    77       LIBS="$LIBS -framework AppKit"

    78       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"

    79       CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"

    80       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"

    81       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])

    82       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])

    83       if test "x$with_gtk" = "xx11"; then

    84         with_gtk=no

    85       fi

    86    ], [], [AC_INCLUDES_DEFAULT])

    88    AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"

    89                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],

    90                    [ OBJCOPT="-O2" ], [] )

    91 ])

    93 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])

    94 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then

    95   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])

    96 fi

    98 dnl ------------------ C Compiler flags -----------------------

    99 CFLAGS="-g -fexceptions"

   100 OBJCFLAGS="-g -fexceptions"

   101 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])

   103 STDCFLAG="-std=c99"

   104 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse"

   105                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   106               [ CCOPT="$CFLAGS -fast"

   107                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   108               [ CCOPT="$CFLAGS -O2" ])

   110 if test "x$enable_optimized" = "xyes"; then

   111    CFLAGS="$CFLAGS $CCOPT"

   112    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"

   113    if test "x$enable_profiled" != "xyes"; then

   114        dnl -fomit-frame-pointer can't be used with -pg

   115        CFLAGS="$CFLAGS -fomit-frame-pointer"

   116        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"

   117    fi

   118 else

   119    CFLAGS="$CFLAGS -g3"

   120    OBJCFLAGS="$OBJCFLAGS -g3"

   121 fi

   123 if test "x$enable_profiled" = "xyes"; then

   124    CFLAGS="$CFLAGS -pg"

   125    LDFLAGS="$LDFLAGS -pg";

   126    OBJCFLAGS="$OBJCFLAGS -pg";

   127 fi

   129 if test "x$enable_strictwarn" = "xyes"; then

   130    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"

   131    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"

   132 fi

   134 AC_CHECK_FASTCALL([

   135    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])

   136 ])

   137 AC_CHECK_FRAME_ADDRESS( [

   138    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])

   139 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])

   143 dnl ----------- Check for mandatory dependencies --------------

   144 dnl Check for libpng (required)

   145 PKG_CHECK_MODULES(LIBPNG, [libpng] )

   147 dnl Implied by libpng, but check explicitly just in case

   148 AC_CHECK_LIB(z, uncompress, [], [

   149     echo "Zlib (libz.so) could not be found, but is required."

   150     exit 1])

   152 if test "x$with_gtk" = "xno"; then

   153    dnl Check for GLIB only

   154    PKG_CHECK_MODULES(GLIB, glib-2.0)

   155 else

   156    dnl Check for GTK

   157    PKG_CHECK_MODULES(GTK, gtk+-2.0, [

   158        HAVE_GTK='yes'

   159        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])

   160    ])

   162    dnl Which GTK port do we have?

   163    LIBS="$LIBS $GTK_LIBS"

   164    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [

   165       HAVE_GTK_X11='yes'

   166       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])

   167    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [

   168       HAVE_GTK_OSX='yes'

   169       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])

   170 fi

   172 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])

   174 dnl ------------------ Video driver support -------------------

   175 AS_IF([test "x$with_osmesa" != xno], [

   177 dnl User requested OSMesa (ie pure software rendering)

   178   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],

   179     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])

   180   AC_CHECK_HEADER([GL/osmesa.h], [],

   181     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])

   182   HAVE_OSMESA='yes'

   183   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"

   184   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [

   186 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already

   187 dnl taken care of above).

   188    if test "x$APPLE_BUILD" != 'xyes'; then

   189       AC_CHECK_LIB(GL, glVertex3f, [], [

   190           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])

   191       AC_CHECK_HEADER([GL/gl.h], [], [

   192           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])

   193    else

   194       AC_CHECK_FUNC(NSOpenGLGetVersion, [

   195          HAVE_NSGL='yes'

   196          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"

   197          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )

   198    fi

   200 dnl Now work out how to get from the UI to GL - this is usually the painful part.

   201    if test "x$HAVE_GTK_X11" = "xyes"; then

   202       if test "x$APPLE_BUILD" = "xyes"; then

   203          LIBS="$LIBS -L/usr/X11/lib -lGL"

   204       fi

   205       AC_CHECK_FUNC(glXQueryVersion, [

   206          HAVE_GLX='yes'

   207          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"

   208          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )

   209    fi

   211 ])

   215 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])

   216 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])

   217 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])

   219 dnl Check for optional (but highly desireable) OpenGL features

   220 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])

   221 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])

   222 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])

   223 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])

   226 dnl ------------------- SH4 translator target -------------------

   228 if test "x$enable_translator" != "xno"; then

   229     case $host_cpu in

   230         i386|i486|i586|i686|x86_64)

   231 	    SH4_TRANSLATOR="x86"

   232             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;

   233     esac

   234 fi

   235 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])

   237 dnl ------------------ Optional driver support -------------------

   238 dnl Check for Apple CoreAudio

   239 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [

   240      HAVE_CORE_AUDIO=yes

   241      LIBS="$LIBS -framework CoreAudio"

   242      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"

   243      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])

   244 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )

   246 dnl Check for SDL (only used for audio at the moment)

   247 if test "x$with_sdl" != "xno"; then

   248    PKG_CHECK_MODULES(SDL, [sdl], [

   249        HAVE_SDL='yes'

   250        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"

   251        AC_DEFINE([HAVE_SDL],1,[Have SDL support])

   252    ], [

   253       if test "x$with_sdl" = "xyes"; then

   254          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )

   255       fi

   256    ])

   257 fi

   258 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )

   260 dnl Check for pulseaudio

   261 if test "x$with_pulse" != "xno"; then

   262    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [

   263        HAVE_PULSE='yes'

   264        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"

   265        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])

   266    ], [

   267        if test "x$with_pulse" = "xyes"; then

   268           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )

   269        fi

   270    ])

   271 fi

   272 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )

   274 dnl Check for esound

   275 if test "x$with_esd" != "xno"; then

   276    PKG_CHECK_MODULES(ESOUND, [esound], [

   277        HAVE_ESOUND='yes'

   278        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"

   279        AC_DEFINE([HAVE_ESOUND],1,[Have esound support])

   280    ], [

   281        if test "x$with_esd" = "xyes"; then

   282           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )

   283        fi

   284    ])

   285 fi

   286 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )

   288 dnl Check for alsa support

   289 PKG_CHECK_MODULES(ALSA, [alsa], [

   290      HAVE_ALSA='yes'

   291      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"

   292      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])

   293 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )

   296 dnl Check for native cdrom support. There can be only one.

   297 AC_CHECK_HEADER([linux/cdrom.h], [

   298      CDROM_DRIVER=linux

   299      dnl Some kernel versions have non-c99 compliant headers - check here

   300      AC_MSG_CHECKING([C99 compliant kernel headers])

   301      old_CFLAGS="$CFLAGS"

   302      CFLAGS="$CFLAGS $STDCFLAG"

   303      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [

   304         AC_MSG_RESULT([No])

   305         STDCFLAG="-std=gnu99"])

   306      CFLAGS="$old_CFLAGS"

   307 ], [true])

   308 AC_CHECK_HEADER([IOKit/IOKitLib.h], [

   309      CDROM_DRIVER=osx

   310      LIBS="$LIBS -framework IOKit"],[true])

   311 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])

   312 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])

   313 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])

   315 AC_CHECK_HEADER([linux/joystick.h], [

   316     HAVE_LINUX_JOYSTICK_H=yes

   317     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ],

   318   [ echo "Linux Joystick support not found, building without it."] )

   319 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])

   321 dnl Check for cross-compiler availability - needed for system tests

   322 AC_PATH_PROG(SHCC, [sh-elf-gcc])

   323 AC_PATH_PROG(SHLD, [sh-elf-ld])

   324 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])

   325 AC_PATH_PROG(ARMCC, [arm-elf-gcc])

   326 AC_PATH_PROG(ARMLD, [arm-elf-ld])

   327 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])

   329 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then

   330   BUILD_SH="no"

   331   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."

   332 else

   333   BUILD_SH="yes"

   334 fi

   335 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then

   336   BUILD_ARM="no"

   337   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."

   338 else

   339   BUILD_ARM="yes"

   340 fi

   341 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])

   342 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])

   344 CFLAGS="$CFLAGS $STDCFLAG"

   346 dnl ----------------------- All done, finish up -----------------------

   347 GETTEXT_PACKAGE=lxdream

   348 AC_SUBST(GETTEXT_PACKAGE)

   349 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])

   351 dnl Add the languages which your application supports here.

   352 ALL_LINGUAS="de es it pt_BR"

   353 AM_GLIB_GNU_GETTEXT

   355 AC_OUTPUT([

   356 Makefile

   357 src/Makefile

   358 po/Makefile.in

   359 test/Makefile

   360 Info.plist

   361 ])

   362 AS_MKDIR_P(test/sh4)

   364 dnl ------------------------- Print out a summary ----------------------

   366 echo

   367 echo "Configuration complete"

   368 echo

   370 if test "x$HAVE_GTK" = x; then

   371   if test "x$HAVE_COCOA" = x; then

   372      echo "  User interface: none"

   373   else

   374      echo "  User interface: Cocoa"

   375   fi

   376 else

   377   echo "  User interface: GTK"

   378 fi

   380 if test "x$SH4_TRANSLATOR" = "x"; then

   381   echo "  SH4 translator: None (emulation core only)"

   382 else

   383   echo "  SH4 translator: $SH4_TRANSLATOR"

   384 fi

   386 if test "x$VIDEO_DRIVERS" = "x"; then

   387    echo "  Video drivers: none (no supported GL found)"

   388 else

   389    echo "  Video drivers: $VIDEO_DRIVERS"

   390 fi

   392 if test "x$AUDIO_DRIVERS" = "x"; then

   393    echo "  Audio drivers: none (no supported output devices found)"

   394 else

   395    echo "  Audio drivers: $AUDIO_DRIVERS"

   396 fi

   398 if test "x$CDROM_DRIVER" = "x"; then

   399    echo "  CD-ROM driver: none (no supported cd-rom devices found)"

   400 else

   401    echo "  CD-ROM driver: $CDROM_DRIVER"

   402 fi