Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 653:3202ff01d48e
prev643:653b0a70f173
next656:031d23fa6d0b
author nkeynes
date Fri Mar 28 12:32:25 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Merge lxdream-render branch (643:670) to trunk
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_HEADER_STDC
    13 AC_CANONICAL_BUILD
    14 AC_CANONICAL_HOST
    15 AC_ARG_ENABLE( trace, 
    16    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    17    [if test "$enableval" == "yes"; then
    18      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    19     fi] )
    20 AC_ARG_ENABLE( watch,
    21    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    22    [if test "$enableval" == "yes"; then
    23      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    24    fi] )
    25 AC_ARG_WITH( osmesa,
    26    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    27    [], [with_osmesa=no])
    29 AS_IF([test "x$with_osmesa" != xno], [ 
    30   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
    31     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
    32   AC_CHECK_HEADER([GL/osmesa.h], [],
    33     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
    34   ])
    35 AM_CONDITIONAL(OSMESA_DRIVER, [test "x$with_osmesa" != xno])
    37 dnl ----------- Check for mandatory dependencies --------------
    38 dnl Building on MAC?
    39 AC_CHECK_HEADER([Carbon/Carbon.h], [
    40    HAVE_CARBON='yes'
    41    APPLE_BUILD='yes'
    42    LIBS="$LIBS -framework OpenGL -framework AGL -framework Carbon -L/usr/X11R6/lib -lGL"
    43    AC_DEFINE(HAVE_CARBON,[1],[Have Carbon framework])
    44    AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    45 ])
    47 dnl Check for libpng (required)
    48 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    50 dnl Implied by libpng, but check explicitly just in case
    51 AC_CHECK_LIB(z, uncompress, [], [
    52     echo "Zlib (libz.so) could not be found, but is required."
    53     exit 1])
    55 if test "$APPLE_BUILD" != 'yes'; then
    56 if test "x$with_osmesa" == "xno"; then
    57 AC_CHECK_LIB(GL, glXQueryVersion, [], [
    58     echo "The OpenGL library (libGL.so) could not be found, but is required."
    59     exit 1])
    60 AC_CHECK_HEADER([GL/gl.h], [], [
    61     echo "The OpenGL header files (eg GL/gl.h) could not be found, but are required."
    62     exit 1])
    63 fi
    64 fi
    66 dnl Check for GTK (required for unix systems)
    67 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    68     HAVE_GTK='yes'
    69     AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    70 ])
    72 AM_CONDITIONAL(GUI_CARBON, [test "$HAVE_CARBON" = 'yes'])
    73 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    75 dnl Check for a supported cpu target for translation purposes
    76 case $host_cpu in
    77     i386|i486|i586|i686)
    78 	SH4_TRANSLATOR="x86"
    79         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
    80     x86_64)
    81 	SH4_TRANSLATOR="x86_64"
    82         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86_64], [SH4 Translator to use (if any)] );;
    83     *)
    84 	echo "Warning: No translator available for $host. Building emulation core only";;
    85 esac
    86 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
    87 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
    89 dnl ------------------ Optional driver support -------------------
    90 dnl Check for esound
    91 PKG_CHECK_MODULES(ESOUND, [esound], [ 
    92      HAVE_ESOUND='yes'
    93      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], 
    94    [ echo "Warning: esound not found - building without esd audio support" ])
    95 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
    97 dnl Check for alsa support
    98 PKG_CHECK_MODULES(ALSA, [alsa], [ 
    99      HAVE_ALSA='yes'
   100      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], 
   101    [ echo "Warning: alsa not found - building without alsa audio support" ])
   102 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   104 dnl Check for linux cdrom device support
   105 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   106     echo "Linux CDROM support not found, building without it."]  )
   107 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   109 AC_CHECK_HEADER([linux/joystick.h], [
   110     HAVE_LINUX_JOYSTICK_H=yes
   111     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   112   [ echo "Linux Joystick support not found, building without it."] )
   113 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   115 dnl Check for cross-compiler availability - needed for system tests
   116 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   117 AC_PATH_PROG(SHLD, [sh-elf-ld])
   118 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   119 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   120 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   121 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   123 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   124   BUILD_SH="no"
   125   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   126 else
   127   BUILD_SH="yes"
   128 fi
   129 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   130   BUILD_ARM="no"
   131   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   132 else
   133   BUILD_ARM="yes"
   134 fi
   135 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   136 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   139 dnl ----------------------- All done, finish up -----------------------
   140 GETTEXT_PACKAGE=lxdream
   141 AC_SUBST(GETTEXT_PACKAGE)
   142 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   144 dnl Add the languages which your application supports here.
   145 ALL_LINGUAS="de pt_BR"
   146 AM_GLIB_GNU_GETTEXT
   148 AC_OUTPUT([
   149 Makefile
   150 src/Makefile
   151 po/Makefile.in
   152 test/Makefile
   153 ])
.