Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 804:567a684e1e7a
prev793:7877d947228d
next866:86cd01c2b2d3
author nkeynes
date Thu Aug 07 23:50:52 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Add --enable-strict-warn to build with -Wall -Werror
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.4)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( strict-warn,
    23    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    24    [CFLAGS="$CFLAGS -Werror -Wall -Wno-unused"], [])
    25 AC_ARG_ENABLE( translator, 
    26    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enable by default)]),
    27    [true], [enable_translator=yes] )
    28 AC_ARG_ENABLE( trace, 
    29    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    30    [if test "$enableval" == "yes"; then
    31      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    32     fi] )
    33 AC_ARG_ENABLE( watch,
    34    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    35    [if test "$enableval" == "yes"; then
    36      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    37    fi] )
    38 AC_ARG_ENABLE( sh4stats,
    39    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    40    [if test "$enableval" == "yes"; then
    41      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    42     fi] )
    43 AC_ARG_WITH( osmesa,
    44    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    45    [], [with_osmesa=no])
    46 AC_ARG_WITH( gtk,
    47    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    48 AC_ARG_WITH( esd,
    49    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    50 AC_ARG_WITH( pulse,
    51    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    53 dnl ------------ 
    55 if test "x$GCC" = "xyes"; then
    56    CFLAGS="$CFLAGS -fno-strict-aliasing"
    57 fi
    59 dnl ------------ Check if we're building on Darwin --------------
    61 dnl For starters, do we have a working objective-c compiler?
    62 lxdream_save_cppflags="$CPPFLAGS"
    63 CPPFLAGS="$CPPFLAGS -x objective-c"
    64 AC_TRY_COMPILE([@interface Foo @end],, [
    66    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    67       HAVE_COCOA='yes'
    68       APPLE_BUILD='yes'
    69       LIBS="$LIBS -framework AppKit"
    70       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    71       CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4"
    72       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    73       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    74       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    75       if test "x$with_gtk" = "xx11"; then
    76         with_gtk=no
    77       fi
    78    ])
    80 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    81 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    83 dnl ----------- Check for mandatory dependencies --------------
    84 dnl Check for libpng (required)
    85 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    87 dnl Implied by libpng, but check explicitly just in case
    88 AC_CHECK_LIB(z, uncompress, [], [
    89     echo "Zlib (libz.so) could not be found, but is required."
    90     exit 1])
    92 if test "x$with_gtk" = "xno"; then
    93    dnl Check for GLIB only
    94    PKG_CHECK_MODULES(GLIB, glib-2.0)
    95 else
    96    dnl Check for GTK
    97    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    98        HAVE_GTK='yes'
    99        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   100    ])
   102    dnl Which GTK port do we have?
   103    LIBS="$LIBS $GTK_LIBS"
   104    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   105       HAVE_GTK_X11='yes'
   106       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   107    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   108       HAVE_GTK_OSX='yes'
   109       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   110 fi
   112 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   114 dnl ------------------ Video driver support -------------------
   115 AS_IF([test "x$with_osmesa" != xno], [ 
   117 dnl User requested OSMesa (ie pure software rendering)
   118   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   119     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   120   AC_CHECK_HEADER([GL/osmesa.h], [],
   121     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   122   HAVE_OSMESA='yes'
   123   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   124   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   126 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   127 dnl taken care of above).
   128    if test "x$APPLE_BUILD" != 'xyes'; then
   129       AC_CHECK_LIB(GL, glVertex3f, [], [
   130           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   131       AC_CHECK_HEADER([GL/gl.h], [], [
   132           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   133    else
   134       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   135          HAVE_NSGL='yes'
   136          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   137          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   138    fi
   140 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   141    if test "x$HAVE_GTK_X11" = "xyes"; then
   142       if test "x$APPLE_BUILD" = "xyes"; then
   143          LIBS="$LIBS -L/usr/X11/lib -lGL"
   144       fi
   145       AC_CHECK_FUNC(glXQueryVersion, [
   146          HAVE_GLX='yes'
   147          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   148          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   149    fi
   151 ])
   155 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   156 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   157 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   159 dnl Check for optional (but highly desireable) OpenGL features
   160 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   161 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   162 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   163 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   166 dnl ------------------- SH4 translator target -------------------
   168 if test "x$enable_translator" != "xno"; then
   169     case $host_cpu in
   170         i386|i486|i586|i686|x86_64)
   171 	    SH4_TRANSLATOR="x86"
   172             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   173     esac
   174 fi
   175 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   177 dnl ------------------ Optional driver support -------------------
   178 dnl Check for Apple CoreAudio
   179 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   180      HAVE_CORE_AUDIO=yes
   181      LIBS="$LIBS -framework CoreAudio"
   182      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   183      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   184 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   186 dnl Check for pulseaudio
   187 if test "x$with_pulse" != "xno"; then
   188    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   189        HAVE_PULSE='yes'
   190        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   191        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   192    ], [
   193        if test "x$with_pulse" = "xyes"; then
   194           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   195        fi
   196    ])
   197 fi
   198 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   200 dnl Check for esound
   201 if test "x$with_esd" != "xno"; then
   202    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   203        HAVE_ESOUND='yes'
   204        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   205        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   206    ], [
   207        if test "x$with_esd" = "xyes"; then
   208           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   209        fi
   210    ])
   211 fi
   212 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   214 dnl Check for alsa support
   215 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   216      HAVE_ALSA='yes'
   217      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   218      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   219 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   222 dnl Check for native cdrom support. There can be only one.
   223 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   224 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   225      CDROM_DRIVER=osx
   226      LIBS="$LIBS -framework IOKit"],[true])
   227 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   228 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   229 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   231 AC_CHECK_HEADER([linux/joystick.h], [
   232     HAVE_LINUX_JOYSTICK_H=yes
   233     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   234   [ echo "Linux Joystick support not found, building without it."] )
   235 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   237 dnl Check for cross-compiler availability - needed for system tests
   238 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   239 AC_PATH_PROG(SHLD, [sh-elf-ld])
   240 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   241 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   242 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   243 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   245 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   246   BUILD_SH="no"
   247   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   248 else
   249   BUILD_SH="yes"
   250 fi
   251 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   252   BUILD_ARM="no"
   253   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   254 else
   255   BUILD_ARM="yes"
   256 fi
   257 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   258 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   261 dnl ----------------------- All done, finish up -----------------------
   262 GETTEXT_PACKAGE=lxdream
   263 AC_SUBST(GETTEXT_PACKAGE)
   264 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   266 dnl Add the languages which your application supports here.
   267 ALL_LINGUAS="de es it pt_BR"
   268 AM_GLIB_GNU_GETTEXT
   270 AC_OUTPUT([
   271 Makefile
   272 src/Makefile
   273 po/Makefile.in
   274 test/Makefile
   275 Info.plist
   276 ])
   277 AS_MKDIR_P(test/sh4)
   279 dnl ------------------------- Print out a summary ----------------------
   281 echo
   282 echo "Configuration complete"
   283 echo
   285 if test "x$HAVE_GTK" = x; then
   286   if test "x$HAVE_COCOA" = x; then
   287      echo "  User interface: none"
   288   else
   289      echo "  User interface: Cocoa"
   290   fi
   291 else
   292   echo "  User interface: GTK"
   293 fi
   295 if test "x$SH4_TRANSLATOR" = "x"; then
   296   echo "  SH4 translator: None (emulation core only)"
   297 else
   298   echo "  SH4 translator: $SH4_TRANSLATOR"
   299 fi
   301 if test "x$VIDEO_DRIVERS" = "x"; then
   302    echo "  Video drivers: none (no supported GL found)"
   303 else
   304    echo "  Video drivers: $VIDEO_DRIVERS"
   305 fi
   307 if test "x$AUDIO_DRIVERS" = "x"; then
   308    echo "  Audio drivers: none (no supported output devices found)"
   309 else
   310    echo "  Audio drivers: $AUDIO_DRIVERS"
   311 fi
   313 if test "x$CDROM_DRIVER" = "x"; then
   314    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   315 else
   316    echo "  CD-ROM driver: $CDROM_DRIVER"
   317 fi
.