Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 1199:62d0a21fac1c
prev1174:252d50f93cf6
next1200:3b2097efa97d
author nkeynes
date Wed Dec 21 12:15:06 2011 +1000 (7 years ago)
permissions -rw-r--r--
last change Add checks for -msse3 and -mfpmath=sse before adding them (in case the
compiler doesn't actually support them)
Tweak configure for forward compatibility with more recent autoconfs
Update config.guess + config.sub to more recent versions
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AC_PROG_OBJC
    12 AC_PROG_SED
    13 AM_PROG_AS
    14 AC_CHECK_SIZEOF([void *])
    15 AC_HEADER_STDC
    16 AC_CANONICAL_BUILD
    17 AC_CANONICAL_HOST
    19 _AM_DEPENDENCIES([OBJC])
    21 AC_PATH_PROG(POD2MAN, [pod2man])
    22 AC_PATH_PROG(POD2HTML, [pod2html])
    24 dnl ---------------- enable/with flags ------------------
    26 AC_ARG_ENABLE( strict-warn,
    27    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    28    [if test "$enableval" == "yes"; then
    29       enable_strictwarn=yes
    30     fi] )
    31 AC_ARG_ENABLE( translator, 
    32    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    33    [true], [enable_translator=yes] )
    34 AC_ARG_ENABLE( optimized,
    35    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    36    [true], [enable_optimized=yes] )
    37 AC_ARG_ENABLE( shared,
    38    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
    39    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
    40 AC_ARG_ENABLE( profiled,
    41    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    42    [if test "$enableval" == "yes"; then
    43       enable_profiled=yes;
    44     fi] )
    45 AC_ARG_ENABLE( trace, 
    46    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    47    [if test "$enableval" == "yes"; then
    48      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    49     fi] )
    50 AC_ARG_ENABLE( watch,
    51    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    52    [if test "$enableval" == "yes"; then
    53      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    54    fi] )
    55 AC_ARG_ENABLE( sh4stats,
    56    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    57    [if test "$enableval" == "yes"; then
    58      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    59     fi] )
    60 AC_ARG_WITH( osmesa,
    61    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    62    [], [with_osmesa=no])
    63 AC_ARG_WITH( gtk,
    64    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    65 AC_ARG_WITH( esd,
    66    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    67 AC_ARG_WITH( pulse,
    68    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    69 AC_ARG_WITH( sdl,
    70    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
    73 dnl ------------ Check if we're building on Darwin --------------
    75 dnl For starters, do we have a working objective-c compiler?
    76 AC_HAVE_OBJC([
    77    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    78       HAVE_COCOA='yes'
    79       APPLE_BUILD='yes'
    80       LIBS="$LIBS -framework AppKit -framework Carbon"
    81       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    82       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
    83       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    84       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    85       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    86       if test "x$with_gtk" = "xx11"; then
    87         with_gtk=no
    88       fi
    89    ], [], [AC_INCLUDES_DEFAULT])
    91    AC_OBJC_VERSION([ OBJCOPT="-O2"
    92                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
    93                    [ OBJCOPT="-O2" ], [] )
    94    AC_CHECK_OBJCFLAG([-msse2])
    95    AC_CHECK_OBJCFLAG([-mfpmath=sse])
    96 ])
    98 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    99 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
   100   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
   101 fi
   103 dnl ------------------ C Compiler flags -----------------------
   104 CFLAGS="-g -fexceptions"
   105 OBJCFLAGS="-g -fexceptions"
   106 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
   108 STDCFLAG="-std=c99"
   109 AC_CC_VERSION([ CCOPT="-O2" 
   110                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   111               [ CCOPT="$CFLAGS -fast"
   112                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   113               [ CCOPT="$CFLAGS -O2" ])
   114 AC_CHECK_CFLAG([-msse2])
   115 AC_CHECK_CFLAG([-mfpmath=sse])
   117 if test "x$enable_optimized" = "xyes"; then
   118    CFLAGS="$CFLAGS $CCOPT"
   119    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
   120    if test "x$enable_profiled" != "xyes"; then
   121        dnl -fomit-frame-pointer can't be used with -pg
   122        CFLAGS="$CFLAGS -fomit-frame-pointer"
   123        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
   124    fi
   125 else
   126    CFLAGS="$CFLAGS -g3"
   127    OBJCFLAGS="$OBJCFLAGS -g3"
   128 fi
   130 if test "x$enable_profiled" = "xyes"; then
   131    CFLAGS="$CFLAGS -pg"
   132    LDFLAGS="$LDFLAGS -pg";
   133    OBJCFLAGS="$OBJCFLAGS -pg";
   134 fi
   136 if test "x$enable_strictwarn" = "xyes"; then
   137    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   138    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   139 fi
   141 if test "x$enable_shared" != "xno"; then
   142    AC_DEFINE(ENABLE_SHARED, [1], [Enable shared-library plugins])
   143    if test "x$APPLE_BUILD" = "xyes"; then
   144       SOEXT="dylib"
   145       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
   146    else 
   147       SOEXT="so"
   148       PLUGINLDFLAGS="-shared"
   149    fi
   150    PLUGINCFLAGS="-fPIC"
   152 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
   153    AC_CHECK_HEADER( [dlfcn.h], [
   154       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
   155    if test "x$have_dlopen" != "xyes"; then
   156       if test "x$enable_shared" == "xyes"; then
   157          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
   158       else
   159          AC_MSG_WARN("Statically linking all plugins")
   160       fi
   161    fi
   163 dnl Check if linker accepts -rdynamic
   164    AC_MSG_CHECKING([if linker accepts -rdynamic])
   165    old_LDFLAGS="$LDFLAGS"
   166    LDFLAGS="$LDFLAGS -rdynamic"
   167    AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
   168      LXDREAMLDFLAGS="-rdynamic"
   169      AC_MSG_RESULT([yes]) 
   170    ], [
   171      LXDREAMLDFLAGS=""
   172      AC_MSG_RESULT([no]) ])
   173    LDFLAGS="$old_LDFLAGS"
   175    AC_SUBST(SOEXT)
   176    AC_SUBST(PLUGINCFLAGS)
   177    AC_SUBST(PLUGINLDFLAGS)
   178    AC_SUBST(LXDREAMLDFLAGS)
   179 fi
   180 AM_CONDITIONAL(BUILD_SHARED, [test "x$have_dlopen" = "xyes"])
   182 AC_CHECK_FASTCALL([
   183    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   184 ])
   185 AC_CHECK_FORCEINLINE()
   186 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
   187 AC_CHECK_FRAME_ADDRESS( [
   188    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   189 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   191 AC_SUBST(LXDREAMCPPFLAGS)
   192 AC_SEARCH_LIBS(listen, [socket])
   193 AC_SEARCH_LIBS(inet_ntoa,[nsl])
   195 dnl ----------- Check for mandatory dependencies --------------
   196 dnl Check for libpng (required)
   197 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   199 dnl Implied by libpng, but check explicitly just in case
   200 AC_CHECK_LIB(z, uncompress, [], [
   201     echo "Zlib (libz.so) could not be found, but is required."
   202     exit 1])
   204 if test "x$with_gtk" = "xno"; then
   205    dnl Check for GLIB only
   206    PKG_CHECK_MODULES(GLIB, glib-2.0)
   207 else
   208    dnl Check for GTK
   209    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   210        HAVE_GTK='yes'
   211        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   212    ])
   214    dnl Which GTK port do we have?
   215    LIBS="$LIBS $GTK_LIBS"
   216    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   217       HAVE_GTK_X11='yes'
   218       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   219       dnl Add -lX11 explicitly as some pkg-configs get it wrong
   220       GTK_LIBS="$GTK_LIBS -lX11"
   221       LIBS="$LIBS -lX11"
   222    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   223       HAVE_GTK_OSX='yes'
   224       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   225    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
   226       AC_MSG_FAILURE( [Unable to identify GTK platform] )
   227    fi
   228 fi
   230 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   232 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
   233 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
   234    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
   235       dnl LIBS="$LIBS -lisofs"
   236    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])], 
   237       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
   239 dnl ------------------ Video driver support -------------------
   240 AS_IF([test "x$with_osmesa" != xno], [ 
   242 dnl User requested OSMesa (ie pure software rendering)
   243   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   244     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   245   AC_CHECK_HEADER([GL/osmesa.h], [],
   246     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   247   HAVE_OSMESA='yes'
   248   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   249   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   251 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   252 dnl taken care of above).
   253    if test "x$APPLE_BUILD" != 'xyes'; then
   254       PKG_CHECK_MODULES(LIBGL, [gl] )
   255       dnl AC_CHECK_LIB(GL, glVertex3f, [], [
   256           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   257       dnl AC_CHECK_HEADER([GL/gl.h], [], [
   258           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   259       LIBS="$LIBS $LIBGL_LIBS";
   260       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
   261    else
   262       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   263          HAVE_NSGL='yes'
   264          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   265          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   266    fi
   268 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   269    if test "x$HAVE_GTK_X11" = "xyes"; then
   270       if test "x$APPLE_BUILD" = "xyes"; then
   271          LIBS="$LIBS -L/usr/X11/lib -lGL"
   272       fi
   273       AC_CHECK_FUNC(glXQueryVersion, [
   274          HAVE_GLX='yes'
   275          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   276          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   277    fi
   279 ])
   283 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   284 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   285 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   287 dnl Check for optional (but highly desireable) OpenGL features
   288 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   289 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   290 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   291 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   294 dnl ------------------- SH4 translator target -------------------
   296 if test "x$enable_translator" != "xno"; then
   297     case $host_cpu in
   298         i386|i486|i586|i686|x86_64)
   299 	    SH4_TRANSLATOR="x86"
   300             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   301     esac
   302 fi
   303 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   305 dnl ------------------ Optional driver support -------------------
   306 dnl Check for Apple CoreAudio
   307 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   308      HAVE_CORE_AUDIO=yes
   309      LIBS="$LIBS -framework CoreAudio"
   310      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   311      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   312 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   314 dnl Check for SDL (only used for audio at the moment)
   315 if test "x$with_sdl" != "xno"; then
   316    PKG_CHECK_MODULES(SDL, [sdl], [
   317        HAVE_SDL='yes'
   318        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
   319        AC_DEFINE([HAVE_SDL],1,[Have SDL support])
   320    ], [
   321       if test "x$with_sdl" = "xyes"; then
   322          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
   323       fi
   324    ])
   325 fi
   326 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
   328 dnl Check for pulseaudio
   329 if test "x$with_pulse" != "xno"; then
   330    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   331        HAVE_PULSE='yes'
   332        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   333        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   334    ], [
   335        if test "x$with_pulse" = "xyes"; then
   336           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   337        fi
   338    ])
   339 fi
   340 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   342 dnl Check for esound
   343 if test "x$with_esd" != "xno"; then
   344    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   345        HAVE_ESOUND='yes'
   346        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   347        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   348    ], [
   349        if test "x$with_esd" = "xyes"; then
   350           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   351        fi
   352    ])
   353 fi
   354 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   356 dnl Check for alsa support
   357 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   358      HAVE_ALSA='yes'
   359      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   360      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   361 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   364 dnl Check for native cdrom support. There can be only one.
   365 AC_CHECK_HEADER([linux/cdrom.h], [
   366      CDROM_DRIVER=linux
   367      dnl Some kernel versions have non-c99 compliant headers - check here
   368      AC_MSG_CHECKING([C99 compliant kernel headers])
   369      old_CFLAGS="$CFLAGS"
   370      CFLAGS="$CFLAGS $STDCFLAG"
   371      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
   372         AC_MSG_RESULT([No])
   373         STDCFLAG="-std=gnu99"])
   374      CFLAGS="$old_CFLAGS"
   375 ], [true])
   376 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   377      CDROM_DRIVER=osx
   378      LIBS="$LIBS -framework IOKit"],[true])
   379 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   380 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   381 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   382 if test "x$CDROM_DRIVER" = "xlinux"; then
   383    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
   384 fi
   386 AC_CHECK_HEADER([linux/joystick.h], [
   387     HAVE_LINUX_JOYSTICK_H=yes
   388     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) 
   389     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ], 
   390   [ echo "Linux Joystick support not found, building without it."] )
   391 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   393 dnl Check for LIRC
   394 if test "x$with_lirc" != "xno"; then
   395     AC_CHECK_HEADER([lirc/lirc_client.h], [
   396         HAVE_LIRC_CLIENT_H=yes
   397         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) 
   398         INPUT_DRIVERS="$INPUT_DRIVERS lirc"
   399       ],
   400       [ echo "LIRC support not found, building without it." ] )
   401 fi
   402 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
   404 dnl Check for cross-compiler availability - needed for system tests
   405 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   406 AC_PATH_PROG(SHLD, [sh-elf-ld])
   407 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   408 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   409 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   410 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   412 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   413   BUILD_SH="no"
   414   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   415 else
   416   BUILD_SH="yes"
   417 fi
   418 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   419   BUILD_ARM="no"
   420   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   421 else
   422   BUILD_ARM="yes"
   423 fi
   424 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   425 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   427 CFLAGS="$CFLAGS $STDCFLAG"
   429 dnl ----------------------- All done, finish up -----------------------
   430 GETTEXT_PACKAGE=lxdream
   431 LXDREAM_LIBS="$LIBS"
   432 LIBS=""
   433 AC_SUBST(LXDREAM_LIBS)
   434 AC_SUBST(GETTEXT_PACKAGE)
   435 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   437 dnl Add the languages which your application supports here.
   438 ALL_LINGUAS="de es it nl pt_BR"
   439 AM_GLIB_GNU_GETTEXT
   441 AC_OUTPUT([
   442 Makefile
   443 src/Makefile
   444 po/Makefile.in
   445 test/Makefile
   446 Info.plist
   447 ])
   448 AS_MKDIR_P(test/sh4)
   450 dnl ------------------------- Print out a summary ----------------------
   452 echo
   453 echo "Configuration complete"
   454 echo
   456 if test "x$HAVE_GTK" = x; then
   457   if test "x$HAVE_COCOA" = x; then
   458      echo "  User interface: none"
   459   else
   460      echo "  User interface: Cocoa"
   461   fi
   462 else
   463   echo "  User interface: GTK"
   464 fi
   466 if test "x$SH4_TRANSLATOR" = "x"; then
   467   echo "  SH4 translator: None (emulation core only)"
   468 else
   469   echo "  SH4 translator: $SH4_TRANSLATOR"
   470 fi
   472 if test "x$VIDEO_DRIVERS" = "x"; then
   473    echo "  Video drivers: none (no supported GL found)"
   474 else
   475    echo "  Video drivers: $VIDEO_DRIVERS"
   476 fi
   478 if test "x$AUDIO_DRIVERS" = "x"; then
   479    echo "  Audio drivers: none (no supported output devices found)"
   480 else
   481    echo "  Audio drivers: $AUDIO_DRIVERS"
   482 fi
   484 if test "x$INPUT_DRIVERS" = "x"; then
   485    echo "  Input drivers: none (no supported input devices found)"
   486 else
   487    echo "  Input drivers: $INPUT_DRIVERS"
   488 fi
   490 if test "x$CDROM_DRIVER" = "x"; then
   491    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   492 else
   493    echo "  CD-ROM driver:  $CDROM_DRIVER"
   494 fi
.