filename | configure.in |
changeset | 923:13ac59a786f4 |
prev | 913:edc494bde24b |
next | 927:17b6b9e245d8 |
author | nkeynes |
date | Sun Dec 14 07:50:48 2008 +0000 (15 years ago) |
permissions | -rw-r--r-- |
last change | Setup a 'proper' stackframe in translated blocks. This doesn't affect performance noticeably, but does ensure that a) The stack is aligned correctly on OS X with no extra effort, and b) We can't mess up the stack and crash that way anymore. Replace all PUSH/POP instructions (outside of prologue/epilogue) with ESP-rel moves to stack local variables. Finally merge ia32mac and ia32abi together, since they're pretty much the same now anyway (and thereby simplifying maintenance a good deal) |
view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.9)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_ISC_POSIX
9 AC_PROG_CC
10 AM_PROG_CC_STDC
11 AM_PROG_AS
12 AC_CHECK_SIZEOF([void *])
13 AC_HEADER_STDC
14 AC_CANONICAL_BUILD
15 AC_CANONICAL_HOST
17 AC_PATH_PROG(POD2MAN, [pod2man])
18 AC_PATH_PROG(POD2HTML, [pod2html])
20 dnl ---------------- enable/with flags ------------------
22 AC_ARG_ENABLE( strict-warn,
23 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
24 [CFLAGS="$CFLAGS -Werror -Wall -Wno-unused"], [])
25 AC_ARG_ENABLE( translator,
26 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
27 [true], [enable_translator=yes] )
28 AC_ARG_ENABLE( optimized,
29 AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
30 [true], [enable_optimized=yes] )
31 AC_ARG_ENABLE( profiled,
32 AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
33 [if test "$enableval" == "yes"; then
34 enable_profiled=yes;
35 fi] )
36 AC_ARG_ENABLE( trace,
37 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
38 [if test "$enableval" == "yes"; then
39 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
40 fi] )
41 AC_ARG_ENABLE( watch,
42 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
43 [if test "$enableval" == "yes"; then
44 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
45 fi] )
46 AC_ARG_ENABLE( sh4stats,
47 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
48 [if test "$enableval" == "yes"; then
49 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
50 fi] )
51 AC_ARG_WITH( osmesa,
52 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
53 [], [with_osmesa=no])
54 AC_ARG_WITH( gtk,
55 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
56 AC_ARG_WITH( esd,
57 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
58 AC_ARG_WITH( pulse,
59 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
61 dnl ------------
63 if test "x$enable_optimized" = "xyes"; then
64 CFLAGS="-g -O2 -msse2 -mfpmath=sse"
65 if test "x$enable_profiled" != "xyes"; then
66 dnl -fomit-frame-pointer can't be used with -pg
67 CFLAGS="$CFLAGS -fexceptions -fomit-frame-pointer"
68 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
69 fi
70 else
71 CFLAGS="-g3"
72 fi
74 if test "x$enable_profiled" = "xyes"; then
75 CFLAGS="$CFLAGS -pg"
76 LDFLAGS="$LDFLAGS -pg";
77 fi
79 if test "x$GCC" = "xyes"; then
80 CFLAGS="$CFLAGS -fno-strict-aliasing"
81 fi
83 AC_CHECK_FASTCALL([
84 AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
85 ])
88 dnl ------------ Check if we're building on Darwin --------------
90 dnl For starters, do we have a working objective-c compiler?
91 lxdream_save_cppflags="$CPPFLAGS"
92 CPPFLAGS="$CPPFLAGS -x objective-c"
93 AC_TRY_COMPILE([@interface Foo @end],, [
95 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
96 HAVE_COCOA='yes'
97 APPLE_BUILD='yes'
98 LIBS="$LIBS -framework AppKit"
99 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
100 CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
101 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
102 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
103 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
104 if test "x$with_gtk" = "xx11"; then
105 with_gtk=no
106 fi
107 ])
109 ], [CPPFLAGS="$lxdream_save_cppflags"] )
110 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
111 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
112 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
113 fi
115 dnl ----------- Check for mandatory dependencies --------------
116 dnl Check for libpng (required)
117 PKG_CHECK_MODULES(LIBPNG, [libpng] )
119 dnl Implied by libpng, but check explicitly just in case
120 AC_CHECK_LIB(z, uncompress, [], [
121 echo "Zlib (libz.so) could not be found, but is required."
122 exit 1])
124 if test "x$with_gtk" = "xno"; then
125 dnl Check for GLIB only
126 PKG_CHECK_MODULES(GLIB, glib-2.0)
127 else
128 dnl Check for GTK
129 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
130 HAVE_GTK='yes'
131 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
132 ])
134 dnl Which GTK port do we have?
135 LIBS="$LIBS $GTK_LIBS"
136 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
137 HAVE_GTK_X11='yes'
138 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
139 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
140 HAVE_GTK_OSX='yes'
141 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
142 fi
144 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
146 dnl ------------------ Video driver support -------------------
147 AS_IF([test "x$with_osmesa" != xno], [
149 dnl User requested OSMesa (ie pure software rendering)
150 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
151 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
152 AC_CHECK_HEADER([GL/osmesa.h], [],
153 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
154 HAVE_OSMESA='yes'
155 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
156 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
158 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
159 dnl taken care of above).
160 if test "x$APPLE_BUILD" != 'xyes'; then
161 AC_CHECK_LIB(GL, glVertex3f, [], [
162 AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
163 AC_CHECK_HEADER([GL/gl.h], [], [
164 AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
165 else
166 AC_CHECK_FUNC(NSOpenGLGetVersion, [
167 HAVE_NSGL='yes'
168 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
169 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
170 fi
172 dnl Now work out how to get from the UI to GL - this is usually the painful part.
173 if test "x$HAVE_GTK_X11" = "xyes"; then
174 if test "x$APPLE_BUILD" = "xyes"; then
175 LIBS="$LIBS -L/usr/X11/lib -lGL"
176 fi
177 AC_CHECK_FUNC(glXQueryVersion, [
178 HAVE_GLX='yes'
179 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
180 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
181 fi
183 ])
187 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
188 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
189 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
191 dnl Check for optional (but highly desireable) OpenGL features
192 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
193 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
194 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
195 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
198 dnl ------------------- SH4 translator target -------------------
200 if test "x$enable_translator" != "xno"; then
201 case $host_cpu in
202 i386|i486|i586|i686|x86_64)
203 SH4_TRANSLATOR="x86"
204 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
205 esac
206 fi
207 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
209 dnl ------------------ Optional driver support -------------------
210 dnl Check for Apple CoreAudio
211 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
212 HAVE_CORE_AUDIO=yes
213 LIBS="$LIBS -framework CoreAudio"
214 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
215 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
216 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
218 dnl Check for pulseaudio
219 if test "x$with_pulse" != "xno"; then
220 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
221 HAVE_PULSE='yes'
222 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
223 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
224 ], [
225 if test "x$with_pulse" = "xyes"; then
226 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
227 fi
228 ])
229 fi
230 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
232 dnl Check for esound
233 if test "x$with_esd" != "xno"; then
234 PKG_CHECK_MODULES(ESOUND, [esound], [
235 HAVE_ESOUND='yes'
236 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
237 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
238 ], [
239 if test "x$with_esd" = "xyes"; then
240 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
241 fi
242 ])
243 fi
244 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
246 dnl Check for alsa support
247 PKG_CHECK_MODULES(ALSA, [alsa], [
248 HAVE_ALSA='yes'
249 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
250 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
251 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
254 dnl Check for native cdrom support. There can be only one.
255 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
256 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
257 CDROM_DRIVER=osx
258 LIBS="$LIBS -framework IOKit"],[true])
259 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
260 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
261 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
263 AC_CHECK_HEADER([linux/joystick.h], [
264 HAVE_LINUX_JOYSTICK_H=yes
265 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ],
266 [ echo "Linux Joystick support not found, building without it."] )
267 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
269 dnl Check for cross-compiler availability - needed for system tests
270 AC_PATH_PROG(SHCC, [sh-elf-gcc])
271 AC_PATH_PROG(SHLD, [sh-elf-ld])
272 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
273 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
274 AC_PATH_PROG(ARMLD, [arm-elf-ld])
275 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
277 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
278 BUILD_SH="no"
279 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
280 else
281 BUILD_SH="yes"
282 fi
283 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
284 BUILD_ARM="no"
285 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
286 else
287 BUILD_ARM="yes"
288 fi
289 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
290 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
293 dnl ----------------------- All done, finish up -----------------------
294 GETTEXT_PACKAGE=lxdream
295 AC_SUBST(GETTEXT_PACKAGE)
296 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
298 dnl Add the languages which your application supports here.
299 ALL_LINGUAS="de es it pt_BR"
300 AM_GLIB_GNU_GETTEXT
302 AC_OUTPUT([
303 Makefile
304 src/Makefile
305 po/Makefile.in
306 test/Makefile
307 Info.plist
308 ])
309 AS_MKDIR_P(test/sh4)
311 dnl ------------------------- Print out a summary ----------------------
313 echo
314 echo "Configuration complete"
315 echo
317 if test "x$HAVE_GTK" = x; then
318 if test "x$HAVE_COCOA" = x; then
319 echo " User interface: none"
320 else
321 echo " User interface: Cocoa"
322 fi
323 else
324 echo " User interface: GTK"
325 fi
327 if test "x$SH4_TRANSLATOR" = "x"; then
328 echo " SH4 translator: None (emulation core only)"
329 else
330 echo " SH4 translator: $SH4_TRANSLATOR"
331 fi
333 if test "x$VIDEO_DRIVERS" = "x"; then
334 echo " Video drivers: none (no supported GL found)"
335 else
336 echo " Video drivers: $VIDEO_DRIVERS"
337 fi
339 if test "x$AUDIO_DRIVERS" = "x"; then
340 echo " Audio drivers: none (no supported output devices found)"
341 else
342 echo " Audio drivers: $AUDIO_DRIVERS"
343 fi
345 if test "x$CDROM_DRIVER" = "x"; then
346 echo " CD-ROM driver: none (no supported cd-rom devices found)"
347 else
348 echo " CD-ROM driver: $CDROM_DRIVER"
349 fi
.