Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 697:479b8c213f61
prev687:6bdc2b7032ea
next700:4650d0c7f6f9
author nkeynes
date Sun Jun 22 04:30:38 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Set log-level to trace automatically if we've asked for a trace on the command line
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    16 AC_ARG_ENABLE( trace, 
    17    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    18    [if test "$enableval" == "yes"; then
    19      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    20     fi] )
    21 AC_ARG_ENABLE( watch,
    22    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    23    [if test "$enableval" == "yes"; then
    24      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    25    fi] )
    26 AC_ARG_ENABLE( sh4stats,
    27    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    28    [if test "$enableval" == "yes"; then
    29      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    30     fi] )
    31 AC_ARG_WITH( osmesa,
    32    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    33    [], [with_osmesa=no])
    34 AC_ARG_WITH( gtk,
    35    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    37 dnl ------------ Check if we're building on Darwin --------------
    39 dnl For starters, do we have a working objective-c compiler?
    40 lxdream_save_cppflags="$CPPFLAGS"
    41 CPPFLAGS="$CPPFLAGS -x objective-c"
    42 AC_TRY_COMPILE([@interface Foo @end],, [
    44    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    45       HAVE_COCOA='yes'
    46       APPLE_BUILD='yes'
    47       LIBS="$LIBS -framework AppKit"
    48       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    49       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    50       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    51    ])
    53    if test "x$with_gtk" = "xx11"; then
    54       with_gtk=no
    55    fi
    57 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    58 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    60 dnl ----------- Check for mandatory dependencies --------------
    61 dnl Check for libpng (required)
    62 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    64 dnl Implied by libpng, but check explicitly just in case
    65 AC_CHECK_LIB(z, uncompress, [], [
    66     echo "Zlib (libz.so) could not be found, but is required."
    67     exit 1])
    69 if test "x$with_gtk" = "xno"; then
    70    dnl Check for GLIB only
    71    PKG_CHECK_MODULES(GLIB, glib-2.0)
    72 else
    73    dnl Check for GTK
    74    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    75        HAVE_GTK='yes'
    76        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    77    ])
    79    dnl Which GTK port do we have?
    80    LIBS="$LIBS $GTK_LIBS"
    81    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    82       HAVE_GTK_X11='yes'
    83       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    84    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    85       HAVE_GTK_OSX='yes'
    86       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    87 fi
    89 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    91 dnl ------------------ Video driver support -------------------
    92 AS_IF([test "x$with_osmesa" != xno], [ 
    94 dnl User requested OSMesa (ie pure software rendering)
    95   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
    96     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
    97   AC_CHECK_HEADER([GL/osmesa.h], [],
    98     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
    99   HAVE_OSMESA='yes'
   100   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   102 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   103 dnl taken care of above).
   104    if test "x$APPLE_BUILD" != 'xyes'; then
   105       AC_CHECK_LIB(GL, glVertex3f, [], [
   106           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   107       AC_CHECK_HEADER([GL/gl.h], [], [
   108           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   109    else
   110       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   111          HAVE_NSGL='yes'
   112          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   113    fi
   115 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   116    if test "x$HAVE_GTK_X11" = "xyes"; then
   117       if test "x$APPLE_BUILD" = "xyes"; then
   118          LIBS="$LIBS -L/usr/X11/lib -lGL"
   119       fi
   120       AC_CHECK_FUNC(glXQueryVersion, [
   121          HAVE_GLX='yes'
   122          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   123 dnl   elif test "x$HAVE_GTK_OSX" = "xyes"; then
   124    fi
   126 ])
   129 dnl OK, now decide which video driver(s) we can build
   130 if test "x$HAVE_OSMESA" = "x" -a "x$HAVE_GLX" = "x" -a "x$HAVE_NSGL" = "x"; then
   131    echo "Warning: Building with no video support"
   132 fi
   134 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   135 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   136 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   138 dnl Check for optional (but highly desireable) OpenGL features
   139 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   140 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   141 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   142 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   145 dnl Check for a supported cpu target for translation purposes
   146 case $host_cpu in
   147     i386|i486|i586|i686|x86_64)
   148 	SH4_TRANSLATOR="x86"
   149         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   150     *)
   151 	echo "Warning: No translator available for $host. Building emulation core only";;
   152 esac
   153 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   154 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   156 dnl ------------------ Optional driver support -------------------
   157 dnl Check for Apple CoreAudio
   158 AC_CHECK_HEADER([AudioToolbox/AudioToolbox.h], [
   159      HAVE_CORE_AUDIO=yes
   160      LIBS="$LIBS -framework AudioToolbox -framework AudioUnit"
   161      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   162 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   164 dnl Check for pulseaudio
   165 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   166      HAVE_PULSE='yes'
   167      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
   168 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   170 dnl Check for esound
   171 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   172      HAVE_ESOUND='yes'
   173      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   174 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   176 dnl Check for alsa support
   177 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   178      HAVE_ALSA='yes'
   179      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   180 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   182 if test "x$HAVE_ESOUND" = "x" -a "x$HAVE_ALSA" = "x" -a "x$HAVE_PULSE" = "x"; then
   183    echo "Warning: Building without audio support"
   184 fi
   186 dnl Check for linux cdrom device support
   187 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   188     echo "Linux CDROM support not found, building without it."]  )
   189 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   191 AC_CHECK_HEADER([linux/joystick.h], [
   192     HAVE_LINUX_JOYSTICK_H=yes
   193     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   194   [ echo "Linux Joystick support not found, building without it."] )
   195 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   197 dnl Check for cross-compiler availability - needed for system tests
   198 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   199 AC_PATH_PROG(SHLD, [sh-elf-ld])
   200 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   201 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   202 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   203 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   205 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   206   BUILD_SH="no"
   207   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   208 else
   209   BUILD_SH="yes"
   210 fi
   211 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   212   BUILD_ARM="no"
   213   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   214 else
   215   BUILD_ARM="yes"
   216 fi
   217 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   218 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   221 dnl ----------------------- All done, finish up -----------------------
   222 GETTEXT_PACKAGE=lxdream
   223 AC_SUBST(GETTEXT_PACKAGE)
   224 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   226 dnl Add the languages which your application supports here.
   227 ALL_LINGUAS="de es it pt_BR"
   228 AM_GLIB_GNU_GETTEXT
   230 AC_OUTPUT([
   231 Makefile
   232 src/Makefile
   233 po/Makefile.in
   234 test/Makefile
   235 ])
.