Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 664:728508bb08df
prev660:d1b2695347c6
next671:a530ea88eebd
author nkeynes
date Thu Apr 17 11:01:29 2008 +0000 (12 years ago)
permissions -rw-r--r--
last change Add spanish and italian translations (contributed by segnini75 and ghost22 respectively)
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_HEADER_STDC
    13 AC_CANONICAL_BUILD
    14 AC_CANONICAL_HOST
    15 AC_ARG_ENABLE( trace, 
    16    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    17    [if test "$enableval" == "yes"; then
    18      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    19     fi] )
    20 AC_ARG_ENABLE( watch,
    21    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    22    [if test "$enableval" == "yes"; then
    23      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    24    fi] )
    25 AC_ARG_WITH( osmesa,
    26    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    27    [], [with_osmesa=no])
    30 dnl ------------ Check if we're building on Darwn --------------
    32 dnl For starters, do we have a working objective-c compiler?
    33 lxdream_save_cppflags="$CPPFLAGS"
    34 CPPFLAGS="$CPPFLAGS -x objective-c"
    35 AC_TRY_COMPILE([@interface Foo @end],, [
    37    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    38       HAVE_COCOA='yes'
    39       APPLE_BUILD='yes'
    40       LIBS="$LIBS -framework AppKit"
    41       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    42       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    43       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    44    ])
    46 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    47 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes'])
    49 dnl ----------- Check for mandatory dependencies --------------
    50 dnl Check for libpng (required)
    51 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    53 dnl Implied by libpng, but check explicitly just in case
    54 AC_CHECK_LIB(z, uncompress, [], [
    55     echo "Zlib (libz.so) could not be found, but is required."
    56     exit 1])
    59 dnl Check for GTK (currently compulsory)
    60 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    61     HAVE_GTK='yes'
    62     AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    63 ])
    64 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    66 dnl Which GTK port do we have?
    67 LIBS="$LIBS $GTK_LIBS"
    68 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    69    HAVE_GTK_X11='yes'
    70    AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    71 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    72    HAVE_GTK_OSX='yes'
    73    AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    75 dnl ------------------ Video driver support -------------------
    76 AS_IF([test "x$with_osmesa" != xno], [ 
    78 dnl User requested OSMesa (ie pure software rendering)
    79   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
    80     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
    81   AC_CHECK_HEADER([GL/osmesa.h], [],
    82     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
    83   HAVE_OSMESA='yes'
    84   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
    86 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
    87 dnl taken care of above).
    88    if test "x$APPLE_BUILD" != 'xyes'; then
    89       AC_CHECK_LIB(GL, glVertex3f, [], [
    90           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
    91       AC_CHECK_HEADER([GL/gl.h], [], [
    92           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
    93    fi
    95 dnl Now work out how to get from the UI to GL - this is usually the painful part.
    96    if test "x$HAVE_GTK_X11" = "xyes"; then
    97       if test "x$APPLE_BUILD" = "xyes"; then
    98          LIBS="$LIBS -L/usr/X11/lib -lGL"
    99       fi
   100       AC_CHECK_FUNC(glXQueryVersion, [
   101          HAVE_GLX='yes'
   102          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   103    elif test "x$HAVE_GTK_OSX" = "xyes"; then
   104       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   105          HAVE_NSGL='yes'
   106          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   107    fi
   109 ])
   112 dnl OK, now decide which video driver(s) we can build
   113 if test "x$HAVE_OSMESA" = "x" -a "x$HAVE_GLX" = "x" -a "x$HAVE_NSGL" = "x"; then
   114    echo "Warning: Building with no video support"
   115 fi
   117 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   118 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   119 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   121 dnl Check for optional (but highly desireable) OpenGL features
   122 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   123 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   124 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   127 dnl Check for a supported cpu target for translation purposes
   128 case $host_cpu in
   129     i386|i486|i586|i686)
   130 	SH4_TRANSLATOR="x86"
   131         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   132     x86_64)
   133 	SH4_TRANSLATOR="x86_64"
   134         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86_64], [SH4 Translator to use (if any)] );;
   135     *)
   136 	echo "Warning: No translator available for $host. Building emulation core only";;
   137 esac
   138 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   139 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   141 dnl ------------------ Optional driver support -------------------
   142 dnl Check for pulseaudio
   143 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   144      HAVE_PULSE='yes'
   145      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
   146 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   148 dnl Check for esound
   149 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   150      HAVE_ESOUND='yes'
   151      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   152 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   154 dnl Check for alsa support
   155 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   156      HAVE_ALSA='yes'
   157      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   158 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   160 if test "x$HAVE_ESOUND" = "x" -a "x$HAVE_ALSA" = "x" -a "x$HAVE_PULSE" = "x"; then
   161    echo "Warning: Building without audio support"
   162 fi
   164 dnl Check for linux cdrom device support
   165 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   166     echo "Linux CDROM support not found, building without it."]  )
   167 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   169 AC_CHECK_HEADER([linux/joystick.h], [
   170     HAVE_LINUX_JOYSTICK_H=yes
   171     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   172   [ echo "Linux Joystick support not found, building without it."] )
   173 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   175 dnl Check for cross-compiler availability - needed for system tests
   176 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   177 AC_PATH_PROG(SHLD, [sh-elf-ld])
   178 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   179 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   180 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   181 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   183 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   184   BUILD_SH="no"
   185   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   186 else
   187   BUILD_SH="yes"
   188 fi
   189 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   190   BUILD_ARM="no"
   191   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   192 else
   193   BUILD_ARM="yes"
   194 fi
   195 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   196 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   199 dnl ----------------------- All done, finish up -----------------------
   200 GETTEXT_PACKAGE=lxdream
   201 AC_SUBST(GETTEXT_PACKAGE)
   202 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   204 dnl Add the languages which your application supports here.
   205 ALL_LINGUAS="de es it pt_BR"
   206 AM_GLIB_GNU_GETTEXT
   208 AC_OUTPUT([
   209 Makefile
   210 src/Makefile
   211 po/Makefile.in
   212 test/Makefile
   213 ])
.