lxdream.org :: lxdream/configure.in r1225:73dd41cb37a8

filename	configure.in
changeset	1225:73dd41cb37a8
prev	1211:eecdeb37934a
next	1226:227ceb186ba7
author	nkeynes
date	Thu Feb 23 08:41:07 2012 +1000 (12 years ago)
permissions	-rw-r--r--
last change	rename BUILD_SHARED conditional flag to BUILD_PLUGINS, for clarity

view

annotate

diff

log

raw

     1 dnl Process this file with autoconf to produce a configure script.

     3 AC_INIT(configure.in)

     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)

     5 AM_MAINTAINER_MODE

     6 AM_CONFIG_HEADER(config.h)

     8 AC_CANONICAL_BUILD

     9 AC_CANONICAL_HOST

    11 m4_include([m4/ccforbuild.m4])

    13 AC_ISC_POSIX

    14 AC_PROG_CC

    15 AM_PROG_CC_STDC

    16 AC_PROG_CC_FOR_BUILD

    17 AC_PROG_OBJC

    18 AC_PROG_SED

    19 AM_PROG_AS

    20 AC_CHECK_SIZEOF([void *])

    21 AC_HEADER_STDC

    23 _AM_DEPENDENCIES([OBJC])

    25 AC_PATH_PROG(POD2MAN, [pod2man])

    26 AC_PATH_PROG(POD2HTML, [pod2html])

    28 dnl ---------------- enable/with flags ------------------

    30 AC_ARG_ENABLE( strict-warn,

    31    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),

    32    [if test "$enableval" == "yes"; then

    33       enable_strictwarn=yes

    34     fi] )

    35 AC_ARG_ENABLE( translator,

    36    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),

    37    [true], [enable_translator=yes] )

    38 AC_ARG_ENABLE( optimized,

    39    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),

    40    [true], [enable_optimized=yes] )

    41 AC_ARG_ENABLE( shared,

    42    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),

    43    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )

    44 AC_ARG_ENABLE( profiled,

    45    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),

    46    [if test "$enableval" == "yes"; then

    47       enable_profiled=yes;

    48     fi] )

    49 AC_ARG_ENABLE( trace,

    50    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),

    51    [if test "$enableval" == "yes"; then

    52      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])

    53     fi] )

    54 AC_ARG_ENABLE( watch,

    55    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),

    56    [if test "$enableval" == "yes"; then

    57      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])

    58    fi] )

    59 AC_ARG_ENABLE( sh4stats,

    60    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),

    61    [if test "$enableval" == "yes"; then

    62      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])

    63     fi] )

    64 AC_ARG_WITH( osmesa,

    65    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),

    66    [], [with_osmesa=no])

    67 AC_ARG_WITH( gtk,

    68    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )

    69 AC_ARG_WITH( esd,

    70    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )

    71 AC_ARG_WITH( pulse,

    72    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )

    73 AC_ARG_WITH( sdl,

    74    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )

    77 dnl ------------ Check if we're building on Darwin --------------

    79 dnl For starters, do we have a working objective-c compiler?

    80 AC_HAVE_OBJC([

    81    AC_CHECK_HEADER([Cocoa/Cocoa.h], [

    82       HAVE_COCOA='yes'

    83       APPLE_BUILD='yes'

    84       LIBS="$LIBS -framework AppKit -framework Carbon"

    85       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"

    86       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"

    87       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"

    88       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])

    89       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])

    90       if test "x$with_gtk" = "xx11"; then

    91         with_gtk=no

    92       fi

    93    ], [], [AC_INCLUDES_DEFAULT])

    95    AC_OBJC_VERSION([ OBJCOPT="-O2"

    96                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],

    97                    [ OBJCOPT="-O2" ], [] )

    98    AC_CHECK_OBJCFLAG([-msse2])

    99    AC_CHECK_OBJCFLAG([-mfpmath=sse])

   100 ])

   102 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])

   103 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then

   104   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])

   105 fi

   107 dnl ------------------ C Compiler flags -----------------------

   108 CFLAGS_FOR_BUILD="-O2 -std=c99"

   109 CFLAGS="-g -fexceptions"

   110 OBJCFLAGS="-g -fexceptions"

   111 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])

   113 STDCFLAG="-std=c99"

   114 AC_CC_VERSION([ CCOPT="-O2"

   115                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   116               [ CCOPT="$CFLAGS -fast"

   117                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   118               [ CCOPT="$CFLAGS -O2" ])

   119 AC_CHECK_CFLAG([-msse2])

   120 AC_CHECK_CFLAG([-mfpmath=sse])

   122 if test "x$enable_optimized" = "xyes"; then

   123    CFLAGS="$CFLAGS $CCOPT"

   124    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"

   125    if test "x$enable_profiled" != "xyes"; then

   126        dnl -fomit-frame-pointer can't be used with -pg

   127        CFLAGS="$CFLAGS -fomit-frame-pointer"

   128        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"

   129    fi

   130 else

   131    CFLAGS="$CFLAGS -g3"

   132    OBJCFLAGS="$OBJCFLAGS -g3"

   133 fi

   135 if test "x$enable_profiled" = "xyes"; then

   136    CFLAGS="$CFLAGS -pg"

   137    LDFLAGS="$LDFLAGS -pg";

   138    OBJCFLAGS="$OBJCFLAGS -pg";

   139 fi

   141 if test "x$enable_strictwarn" = "xyes"; then

   142    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"

   143    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"

   144 fi

   146 if test "x$enable_shared" != "xno"; then

   147    if test "x$APPLE_BUILD" = "xyes"; then

   148       SOEXT="dylib"

   149       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"

   150    else

   151       SOEXT="so"

   152       PLUGINLDFLAGS="-shared"

   153    fi

   154    PLUGINCFLAGS="-fPIC"

   156 dnl Check for dlfcn.h and dlopen() (in libdl or libc)

   157    AC_CHECK_HEADER( [dlfcn.h], [

   158       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])

   159    if test "x$have_dlopen" != "xyes"; then

   160       if test "x$enable_shared" == "xyes"; then

   161          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )

   162       else

   163          AC_MSG_WARN("Statically linking all plugins")

   164       fi

   165    fi

   167 dnl Check if linker accepts -rdynamic

   168    AC_MSG_CHECKING([if linker accepts -rdynamic])

   169    old_LDFLAGS="$LDFLAGS"

   170    LDFLAGS="$LDFLAGS -rdynamic"

   171    AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [

   172      LXDREAMLDFLAGS="-rdynamic"

   173      AC_MSG_RESULT([yes])

   174    ], [

   175      LXDREAMLDFLAGS=""

   176      AC_MSG_RESULT([no]) ])

   177    LDFLAGS="$old_LDFLAGS"

   179    AC_SUBST(SOEXT)

   180    AC_SUBST(PLUGINCFLAGS)

   181    AC_SUBST(PLUGINLDFLAGS)

   182    AC_SUBST(LXDREAMLDFLAGS)

   183 fi

   184 if test "x$have_dlopen" = "xyes"; then

   185     AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])

   186 fi

   187 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes"])

   189 AC_CHECK_FASTCALL([

   190    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])

   191 ])

   192 AC_CHECK_FORCEINLINE()

   193 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])

   194 AC_CHECK_FRAME_ADDRESS( [

   195    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])

   196 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])

   198 AC_SUBST(LXDREAMCPPFLAGS)

   199 AC_SEARCH_LIBS(listen, [socket])

   200 AC_SEARCH_LIBS(inet_ntoa,[nsl])

   202 dnl ----------- Check for mandatory dependencies --------------

   203 dnl Check for libpng (required)

   204 PKG_CHECK_MODULES(LIBPNG, [libpng] )

   206 dnl Implied by libpng, but check explicitly just in case

   207 AC_CHECK_LIB(z, uncompress, [], [

   208     echo "Zlib (libz.so) could not be found, but is required."

   209     exit 1])

   211 if test "x$with_gtk" = "xno"; then

   212    dnl Check for GLIB only

   213    PKG_CHECK_MODULES(GLIB, glib-2.0)

   214 else

   215    dnl Check for GTK

   216    PKG_CHECK_MODULES(GTK, gtk+-2.0, [

   217        HAVE_GTK='yes'

   218        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])

   219    ])

   221    dnl Which GTK port do we have?

   222    LIBS="$LIBS $GTK_LIBS"

   223    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [

   224       HAVE_GTK_X11='yes'

   225       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])

   226       dnl Add -lX11 explicitly as some pkg-configs get it wrong

   227       GTK_LIBS="$GTK_LIBS -lX11"

   228       LIBS="$LIBS -lX11"

   229    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [

   230       HAVE_GTK_OSX='yes'

   231       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])

   232    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then

   233       AC_MSG_FAILURE( [Unable to identify GTK platform] )

   234    fi

   235 fi

   237 AC_PUSH_CC_FOR_BUILD

   238 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)

   239 AC_POP_CC_FOR_BUILD

   241 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])

   243 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )

   244 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [

   245    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [

   246       dnl LIBS="$LIBS -lisofs"

   247    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])],

   248       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])

   250 dnl ------------------ Video driver support -------------------

   251 AS_IF([test "x$with_osmesa" != xno], [

   253 dnl User requested OSMesa (ie pure software rendering)

   254   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],

   255     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])

   256   AC_CHECK_HEADER([GL/osmesa.h], [],

   257     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])

   258   HAVE_OSMESA='yes'

   259   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"

   260   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [

   262 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already

   263 dnl taken care of above).

   264    if test "x$APPLE_BUILD" != 'xyes'; then

   265       PKG_CHECK_MODULES(LIBGL, [gl] )

   266       dnl AC_CHECK_LIB(GL, glVertex3f, [], [

   267           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])

   268       dnl AC_CHECK_HEADER([GL/gl.h], [], [

   269           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])

   270       LIBS="$LIBS $LIBGL_LIBS";

   271       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";

   272    else

   273       AC_CHECK_FUNC(NSOpenGLGetVersion, [

   274          HAVE_NSGL='yes'

   275          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"

   276          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )

   277    fi

   279 dnl Now work out how to get from the UI to GL - this is usually the painful part.

   280    if test "x$HAVE_GTK_X11" = "xyes"; then

   281       if test "x$APPLE_BUILD" = "xyes"; then

   282          LIBS="$LIBS -L/usr/X11/lib -lGL"

   283       fi

   284       AC_CHECK_FUNC(glXQueryVersion, [

   285          HAVE_GLX='yes'

   286          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"

   287          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )

   288    fi

   290 ])

   294 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])

   295 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])

   296 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])

   298 dnl Check for optional (but highly desireable) OpenGL features

   299 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])

   300 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])

   301 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])

   302 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])

   303 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])

   304 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])

   305 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident]) ], [])

   306 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.

   311 dnl ------------------- SH4 translator target -------------------

   313 if test "x$enable_translator" != "xno"; then

   314     case $host_cpu in

   315         i386|i486|i586|i686|x86_64)

   316 	    SH4_TRANSLATOR="x86"

   317             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;

   318     esac

   319 fi

   320 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])

   322 dnl ------------------ Optional driver support -------------------

   323 dnl Check for Apple CoreAudio

   324 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [

   325      HAVE_CORE_AUDIO=yes

   326      LIBS="$LIBS -framework CoreAudio"

   327      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"

   328      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])

   329 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )

   331 dnl Check for SDL (only used for audio at the moment)

   332 if test "x$with_sdl" != "xno"; then

   333    PKG_CHECK_MODULES(SDL, [sdl], [

   334        HAVE_SDL='yes'

   335        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"

   336        AC_DEFINE([HAVE_SDL],1,[Have SDL support])

   337    ], [

   338       if test "x$with_sdl" = "xyes"; then

   339          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )

   340       fi

   341    ])

   342 fi

   343 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )

   345 dnl Check for pulseaudio

   346 if test "x$with_pulse" != "xno"; then

   347    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [

   348        HAVE_PULSE='yes'

   349        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"

   350        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])

   351    ], [

   352        if test "x$with_pulse" = "xyes"; then

   353           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )

   354        fi

   355    ])

   356 fi

   357 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )

   359 dnl Check for esound

   360 if test "x$with_esd" != "xno"; then

   361    PKG_CHECK_MODULES(ESOUND, [esound], [

   362        HAVE_ESOUND='yes'

   363        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"

   364        AC_DEFINE([HAVE_ESOUND],1,[Have esound support])

   365    ], [

   366        if test "x$with_esd" = "xyes"; then

   367           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )

   368        fi

   369    ])

   370 fi

   371 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )

   373 dnl Check for alsa support

   374 PKG_CHECK_MODULES(ALSA, [alsa], [

   375      HAVE_ALSA='yes'

   376      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"

   377      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])

   378 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )

   381 dnl Check for native cdrom support. There can be only one.

   382 AC_CHECK_HEADER([linux/cdrom.h], [

   383      CDROM_DRIVER=linux

   384      dnl Some kernel versions have non-c99 compliant headers - check here

   385      AC_MSG_CHECKING([C99 compliant kernel headers])

   386      old_CFLAGS="$CFLAGS"

   387      CFLAGS="$CFLAGS $STDCFLAG"

   388      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [

   389         AC_MSG_RESULT([No])

   390         STDCFLAG="-std=gnu99"])

   391      CFLAGS="$old_CFLAGS"

   392 ], [true])

   393 AC_CHECK_HEADER([IOKit/IOKitLib.h], [

   394      CDROM_DRIVER=osx

   395      LIBS="$LIBS -framework IOKit"],[true])

   396 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])

   397 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])

   398 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])

   399 if test "x$CDROM_DRIVER" = "xlinux"; then

   400    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])

   401 fi

   403 AC_CHECK_HEADER([linux/joystick.h], [

   404     HAVE_LINUX_JOYSTICK_H=yes

   405     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support])

   406     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ],

   407   [ echo "Linux Joystick support not found, building without it."] )

   408 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])

   410 dnl Check for LIRC

   411 if test "x$with_lirc" != "xno"; then

   412     AC_CHECK_HEADER([lirc/lirc_client.h], [

   413         HAVE_LIRC_CLIENT_H=yes

   414         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support])

   415         INPUT_DRIVERS="$INPUT_DRIVERS lirc"

   416       ],

   417       [ echo "LIRC support not found, building without it." ] )

   418 fi

   419 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])

   421 dnl Check for cross-compiler availability - needed for system tests

   422 AC_PATH_PROG(SHCC, [sh-elf-gcc])

   423 AC_PATH_PROG(SHLD, [sh-elf-ld])

   424 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])

   425 AC_PATH_PROG(ARMCC, [arm-elf-gcc])

   426 AC_PATH_PROG(ARMLD, [arm-elf-ld])

   427 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])

   429 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then

   430   BUILD_SH="no"

   431   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."

   432 else

   433   BUILD_SH="yes"

   434 fi

   435 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then

   436   BUILD_ARM="no"

   437   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."

   438 else

   439   BUILD_ARM="yes"

   440 fi

   441 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])

   442 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])

   444 CFLAGS="$CFLAGS $STDCFLAG"

   446 dnl ----------------------- All done, finish up -----------------------

   447 GETTEXT_PACKAGE=lxdream

   448 LXDREAM_LIBS="$LIBS"

   449 LIBS=""

   450 AC_SUBST(LXDREAM_LIBS)

   451 AC_SUBST(GETTEXT_PACKAGE)

   452 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])

   454 dnl Add the languages which your application supports here.

   455 ALL_LINGUAS="de es it nl pt_BR"

   456 AM_GLIB_GNU_GETTEXT

   458 AC_OUTPUT([

   459 Makefile

   460 src/Makefile

   461 src/tools/Makefile

   462 po/Makefile.in

   463 test/Makefile

   464 Info.plist

   465 ])

   466 AS_MKDIR_P(test/sh4)

   468 dnl ------------------------- Print out a summary ----------------------

   470 echo

   471 echo "Configuration complete"

   472 echo

   474 if test "x$HAVE_GTK" = x; then

   475   if test "x$HAVE_COCOA" = x; then

   476      echo "  User interface: none"

   477   else

   478      echo "  User interface: Cocoa"

   479   fi

   480 else

   481   echo "  User interface: GTK"

   482 fi

   484 if test "x$SH4_TRANSLATOR" = "x"; then

   485   echo "  SH4 translator: None (emulation core only)"

   486 else

   487   echo "  SH4 translator: $SH4_TRANSLATOR"

   488 fi

   490 if test "x$VIDEO_DRIVERS" = "x"; then

   491    echo "  Video drivers: none (no supported GL found)"

   492 else

   493    echo "  Video drivers: $VIDEO_DRIVERS"

   494 fi

   496 if test "x$AUDIO_DRIVERS" = "x"; then

   497    echo "  Audio drivers: none (no supported output devices found)"

   498 else

   499    echo "  Audio drivers: $AUDIO_DRIVERS"

   500 fi

   502 if test "x$INPUT_DRIVERS" = "x"; then

   503    echo "  Input drivers: none (no supported input devices found)"

   504 else

   505    echo "  Input drivers: $INPUT_DRIVERS"

   506 fi

   508 if test "x$CDROM_DRIVER" = "x"; then

   509    echo "  CD-ROM driver: none (no supported cd-rom devices found)"

   510 else

   511    echo "  CD-ROM driver:  $CDROM_DRIVER"

   512 fi