Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 1210:79bbd30363f4
prev1200:3b2097efa97d
next1211:eecdeb37934a
author nkeynes
date Tue Feb 07 14:27:13 2012 +1000 (7 years ago)
permissions -rw-r--r--
last change Add wrangling for some of the core vs EXT/ARB versions of functions + macros
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AC_PROG_CC_FOR_BUILD
    11 AM_PROG_CC_STDC
    12 AC_PROG_OBJC
    13 AC_PROG_SED
    14 AM_PROG_AS
    15 AC_CHECK_SIZEOF([void *])
    16 AC_HEADER_STDC
    17 AC_CANONICAL_BUILD
    18 AC_CANONICAL_HOST
    20 _AM_DEPENDENCIES([OBJC])
    22 AC_PATH_PROG(POD2MAN, [pod2man])
    23 AC_PATH_PROG(POD2HTML, [pod2html])
    25 dnl ---------------- enable/with flags ------------------
    27 AC_ARG_ENABLE( strict-warn,
    28    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    29    [if test "$enableval" == "yes"; then
    30       enable_strictwarn=yes
    31     fi] )
    32 AC_ARG_ENABLE( translator, 
    33    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    34    [true], [enable_translator=yes] )
    35 AC_ARG_ENABLE( optimized,
    36    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    37    [true], [enable_optimized=yes] )
    38 AC_ARG_ENABLE( shared,
    39    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
    40    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
    41 AC_ARG_ENABLE( profiled,
    42    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    43    [if test "$enableval" == "yes"; then
    44       enable_profiled=yes;
    45     fi] )
    46 AC_ARG_ENABLE( trace, 
    47    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    48    [if test "$enableval" == "yes"; then
    49      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    50     fi] )
    51 AC_ARG_ENABLE( watch,
    52    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    53    [if test "$enableval" == "yes"; then
    54      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    55    fi] )
    56 AC_ARG_ENABLE( sh4stats,
    57    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    58    [if test "$enableval" == "yes"; then
    59      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    60     fi] )
    61 AC_ARG_WITH( osmesa,
    62    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    63    [], [with_osmesa=no])
    64 AC_ARG_WITH( gtk,
    65    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    66 AC_ARG_WITH( esd,
    67    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    68 AC_ARG_WITH( pulse,
    69    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    70 AC_ARG_WITH( sdl,
    71    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
    74 dnl ------------ Check if we're building on Darwin --------------
    76 dnl For starters, do we have a working objective-c compiler?
    77 AC_HAVE_OBJC([
    78    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    79       HAVE_COCOA='yes'
    80       APPLE_BUILD='yes'
    81       LIBS="$LIBS -framework AppKit -framework Carbon"
    82       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    83       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
    84       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    85       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    86       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    87       if test "x$with_gtk" = "xx11"; then
    88         with_gtk=no
    89       fi
    90    ], [], [AC_INCLUDES_DEFAULT])
    92    AC_OBJC_VERSION([ OBJCOPT="-O2"
    93                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
    94                    [ OBJCOPT="-O2" ], [] )
    95    AC_CHECK_OBJCFLAG([-msse2])
    96    AC_CHECK_OBJCFLAG([-mfpmath=sse])
    97 ])
    99 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
   100 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
   101   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
   102 fi
   104 dnl ------------------ C Compiler flags -----------------------
   105 CFLAGS="-g -fexceptions"
   106 OBJCFLAGS="-g -fexceptions"
   107 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
   109 STDCFLAG="-std=c99"
   110 AC_CC_VERSION([ CCOPT="-O2" 
   111                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   112               [ CCOPT="$CFLAGS -fast"
   113                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   114               [ CCOPT="$CFLAGS -O2" ])
   115 AC_CHECK_CFLAG([-msse2])
   116 AC_CHECK_CFLAG([-mfpmath=sse])
   118 if test "x$enable_optimized" = "xyes"; then
   119    CFLAGS="$CFLAGS $CCOPT"
   120    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
   121    if test "x$enable_profiled" != "xyes"; then
   122        dnl -fomit-frame-pointer can't be used with -pg
   123        CFLAGS="$CFLAGS -fomit-frame-pointer"
   124        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
   125    fi
   126 else
   127    CFLAGS="$CFLAGS -g3"
   128    OBJCFLAGS="$OBJCFLAGS -g3"
   129 fi
   131 if test "x$enable_profiled" = "xyes"; then
   132    CFLAGS="$CFLAGS -pg"
   133    LDFLAGS="$LDFLAGS -pg";
   134    OBJCFLAGS="$OBJCFLAGS -pg";
   135 fi
   137 if test "x$enable_strictwarn" = "xyes"; then
   138    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   139    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   140 fi
   142 if test "x$enable_shared" != "xno"; then
   143    AC_DEFINE(ENABLE_SHARED, [1], [Enable shared-library plugins])
   144    if test "x$APPLE_BUILD" = "xyes"; then
   145       SOEXT="dylib"
   146       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
   147    else 
   148       SOEXT="so"
   149       PLUGINLDFLAGS="-shared"
   150    fi
   151    PLUGINCFLAGS="-fPIC"
   153 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
   154    AC_CHECK_HEADER( [dlfcn.h], [
   155       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
   156    if test "x$have_dlopen" != "xyes"; then
   157       if test "x$enable_shared" == "xyes"; then
   158          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
   159       else
   160          AC_MSG_WARN("Statically linking all plugins")
   161       fi
   162    fi
   164 dnl Check if linker accepts -rdynamic
   165    AC_MSG_CHECKING([if linker accepts -rdynamic])
   166    old_LDFLAGS="$LDFLAGS"
   167    LDFLAGS="$LDFLAGS -rdynamic"
   168    AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
   169      LXDREAMLDFLAGS="-rdynamic"
   170      AC_MSG_RESULT([yes]) 
   171    ], [
   172      LXDREAMLDFLAGS=""
   173      AC_MSG_RESULT([no]) ])
   174    LDFLAGS="$old_LDFLAGS"
   176    AC_SUBST(SOEXT)
   177    AC_SUBST(PLUGINCFLAGS)
   178    AC_SUBST(PLUGINLDFLAGS)
   179    AC_SUBST(LXDREAMLDFLAGS)
   180 fi
   181 AM_CONDITIONAL(BUILD_SHARED, [test "x$have_dlopen" = "xyes"])
   183 AC_CHECK_FASTCALL([
   184    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   185 ])
   186 AC_CHECK_FORCEINLINE()
   187 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
   188 AC_CHECK_FRAME_ADDRESS( [
   189    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   190 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   192 AC_SUBST(LXDREAMCPPFLAGS)
   193 AC_SEARCH_LIBS(listen, [socket])
   194 AC_SEARCH_LIBS(inet_ntoa,[nsl])
   196 dnl ----------- Check for mandatory dependencies --------------
   197 dnl Check for libpng (required)
   198 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   200 dnl Implied by libpng, but check explicitly just in case
   201 AC_CHECK_LIB(z, uncompress, [], [
   202     echo "Zlib (libz.so) could not be found, but is required."
   203     exit 1])
   205 if test "x$with_gtk" = "xno"; then
   206    dnl Check for GLIB only
   207    PKG_CHECK_MODULES(GLIB, glib-2.0)
   208 else
   209    dnl Check for GTK
   210    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   211        HAVE_GTK='yes'
   212        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   213    ])
   215    dnl Which GTK port do we have?
   216    LIBS="$LIBS $GTK_LIBS"
   217    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   218       HAVE_GTK_X11='yes'
   219       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   220       dnl Add -lX11 explicitly as some pkg-configs get it wrong
   221       GTK_LIBS="$GTK_LIBS -lX11"
   222       LIBS="$LIBS -lX11"
   223    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   224       HAVE_GTK_OSX='yes'
   225       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   226    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
   227       AC_MSG_FAILURE( [Unable to identify GTK platform] )
   228    fi
   229 fi
   231 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   233 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
   234 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
   235    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
   236       dnl LIBS="$LIBS -lisofs"
   237    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])], 
   238       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
   240 dnl ------------------ Video driver support -------------------
   241 AS_IF([test "x$with_osmesa" != xno], [ 
   243 dnl User requested OSMesa (ie pure software rendering)
   244   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   245     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   246   AC_CHECK_HEADER([GL/osmesa.h], [],
   247     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   248   HAVE_OSMESA='yes'
   249   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   250   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   252 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   253 dnl taken care of above).
   254    if test "x$APPLE_BUILD" != 'xyes'; then
   255       PKG_CHECK_MODULES(LIBGL, [gl] )
   256       dnl AC_CHECK_LIB(GL, glVertex3f, [], [
   257           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   258       dnl AC_CHECK_HEADER([GL/gl.h], [], [
   259           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   260       LIBS="$LIBS $LIBGL_LIBS";
   261       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
   262    else
   263       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   264          HAVE_NSGL='yes'
   265          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   266          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   267    fi
   269 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   270    if test "x$HAVE_GTK_X11" = "xyes"; then
   271       if test "x$APPLE_BUILD" = "xyes"; then
   272          LIBS="$LIBS -L/usr/X11/lib -lGL"
   273       fi
   274       AC_CHECK_FUNC(glXQueryVersion, [
   275          HAVE_GLX='yes'
   276          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   277          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   278    fi
   280 ])
   284 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   285 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   286 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   288 dnl Check for optional (but highly desireable) OpenGL features
   289 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
   290 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
   291 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   292 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   293 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   296 dnl ------------------- SH4 translator target -------------------
   298 if test "x$enable_translator" != "xno"; then
   299     case $host_cpu in
   300         i386|i486|i586|i686|x86_64)
   301 	    SH4_TRANSLATOR="x86"
   302             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   303     esac
   304 fi
   305 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   307 dnl ------------------ Optional driver support -------------------
   308 dnl Check for Apple CoreAudio
   309 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   310      HAVE_CORE_AUDIO=yes
   311      LIBS="$LIBS -framework CoreAudio"
   312      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   313      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   314 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   316 dnl Check for SDL (only used for audio at the moment)
   317 if test "x$with_sdl" != "xno"; then
   318    PKG_CHECK_MODULES(SDL, [sdl], [
   319        HAVE_SDL='yes'
   320        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
   321        AC_DEFINE([HAVE_SDL],1,[Have SDL support])
   322    ], [
   323       if test "x$with_sdl" = "xyes"; then
   324          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
   325       fi
   326    ])
   327 fi
   328 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
   330 dnl Check for pulseaudio
   331 if test "x$with_pulse" != "xno"; then
   332    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   333        HAVE_PULSE='yes'
   334        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   335        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   336    ], [
   337        if test "x$with_pulse" = "xyes"; then
   338           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   339        fi
   340    ])
   341 fi
   342 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   344 dnl Check for esound
   345 if test "x$with_esd" != "xno"; then
   346    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   347        HAVE_ESOUND='yes'
   348        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   349        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   350    ], [
   351        if test "x$with_esd" = "xyes"; then
   352           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   353        fi
   354    ])
   355 fi
   356 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   358 dnl Check for alsa support
   359 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   360      HAVE_ALSA='yes'
   361      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   362      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   363 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   366 dnl Check for native cdrom support. There can be only one.
   367 AC_CHECK_HEADER([linux/cdrom.h], [
   368      CDROM_DRIVER=linux
   369      dnl Some kernel versions have non-c99 compliant headers - check here
   370      AC_MSG_CHECKING([C99 compliant kernel headers])
   371      old_CFLAGS="$CFLAGS"
   372      CFLAGS="$CFLAGS $STDCFLAG"
   373      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
   374         AC_MSG_RESULT([No])
   375         STDCFLAG="-std=gnu99"])
   376      CFLAGS="$old_CFLAGS"
   377 ], [true])
   378 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   379      CDROM_DRIVER=osx
   380      LIBS="$LIBS -framework IOKit"],[true])
   381 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   382 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   383 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   384 if test "x$CDROM_DRIVER" = "xlinux"; then
   385    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
   386 fi
   388 AC_CHECK_HEADER([linux/joystick.h], [
   389     HAVE_LINUX_JOYSTICK_H=yes
   390     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) 
   391     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ], 
   392   [ echo "Linux Joystick support not found, building without it."] )
   393 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   395 dnl Check for LIRC
   396 if test "x$with_lirc" != "xno"; then
   397     AC_CHECK_HEADER([lirc/lirc_client.h], [
   398         HAVE_LIRC_CLIENT_H=yes
   399         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) 
   400         INPUT_DRIVERS="$INPUT_DRIVERS lirc"
   401       ],
   402       [ echo "LIRC support not found, building without it." ] )
   403 fi
   404 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
   406 dnl Check for cross-compiler availability - needed for system tests
   407 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   408 AC_PATH_PROG(SHLD, [sh-elf-ld])
   409 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   410 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   411 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   412 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   414 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   415   BUILD_SH="no"
   416   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   417 else
   418   BUILD_SH="yes"
   419 fi
   420 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   421   BUILD_ARM="no"
   422   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   423 else
   424   BUILD_ARM="yes"
   425 fi
   426 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   427 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   429 CFLAGS="$CFLAGS $STDCFLAG"
   431 dnl ----------------------- All done, finish up -----------------------
   432 GETTEXT_PACKAGE=lxdream
   433 LXDREAM_LIBS="$LIBS"
   434 LIBS=""
   435 AC_SUBST(LXDREAM_LIBS)
   436 AC_SUBST(GETTEXT_PACKAGE)
   437 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   439 dnl Add the languages which your application supports here.
   440 ALL_LINGUAS="de es it nl pt_BR"
   441 AM_GLIB_GNU_GETTEXT
   443 AC_OUTPUT([
   444 Makefile
   445 src/Makefile
   446 po/Makefile.in
   447 test/Makefile
   448 Info.plist
   449 ])
   450 AS_MKDIR_P(test/sh4)
   452 dnl ------------------------- Print out a summary ----------------------
   454 echo
   455 echo "Configuration complete"
   456 echo
   458 if test "x$HAVE_GTK" = x; then
   459   if test "x$HAVE_COCOA" = x; then
   460      echo "  User interface: none"
   461   else
   462      echo "  User interface: Cocoa"
   463   fi
   464 else
   465   echo "  User interface: GTK"
   466 fi
   468 if test "x$SH4_TRANSLATOR" = "x"; then
   469   echo "  SH4 translator: None (emulation core only)"
   470 else
   471   echo "  SH4 translator: $SH4_TRANSLATOR"
   472 fi
   474 if test "x$VIDEO_DRIVERS" = "x"; then
   475    echo "  Video drivers: none (no supported GL found)"
   476 else
   477    echo "  Video drivers: $VIDEO_DRIVERS"
   478 fi
   480 if test "x$AUDIO_DRIVERS" = "x"; then
   481    echo "  Audio drivers: none (no supported output devices found)"
   482 else
   483    echo "  Audio drivers: $AUDIO_DRIVERS"
   484 fi
   486 if test "x$INPUT_DRIVERS" = "x"; then
   487    echo "  Input drivers: none (no supported input devices found)"
   488 else
   489    echo "  Input drivers: $INPUT_DRIVERS"
   490 fi
   492 if test "x$CDROM_DRIVER" = "x"; then
   493    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   494 else
   495    echo "  CD-ROM driver:  $CDROM_DRIVER"
   496 fi
.