filename | configure.in |
changeset | 1287:dac8f363f1fe |
prev | 1284:0db0a5e72698 |
author | nkeynes |
date | Sat Aug 04 08:46:28 2012 +1000 (11 years ago) |
permissions | -rw-r--r-- |
last change | Handle corner case in pvr2_run_slice when we've previously slightly overrun the end of the time slice |
view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_CANONICAL_BUILD
9 AC_CANONICAL_HOST
11 m4_include([m4/ccforbuild.m4])
12 m4_include([m4/android.m4])
14 AC_ISC_POSIX
15 AC_PROG_CC
16 AM_PROG_CC_STDC
17 AC_PROG_CC_FOR_BUILD
18 AC_PROG_OBJC
19 AC_PROG_SED
20 AM_PROG_AS
21 AC_PROG_RANLIB
22 AC_CHECK_SIZEOF([void *])
23 AC_HEADER_STDC
25 _AM_DEPENDENCIES([OBJC])
27 AC_PATH_PROG(POD2MAN, [pod2man])
28 AC_PATH_PROG(POD2HTML, [pod2html])
30 AC_DEFINE_UNQUOTED(BUILD_SED_PROG, ["${SED}"], [Sed to use for build tools])
31 AC_DEFINE_UNQUOTED(BUILD_CPP_PROG, ["${CPP}"], [CPP to use for build tools])
33 dnl ---------------- enable/with flags ------------------
35 AC_ARG_ENABLE( strict-warn,
36 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
37 [if test "$enableval" == "yes"; then
38 enable_strictwarn=yes
39 fi] )
40 AC_ARG_ENABLE( translator,
41 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
42 [true], [enable_translator=yes] )
43 AC_ARG_ENABLE( optimized,
44 AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
45 [true], [enable_optimized=yes] )
46 AC_ARG_ENABLE( shared,
47 AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
48 [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
49 AC_ARG_ENABLE( profiled,
50 AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
51 [if test "$enableval" == "yes"; then
52 enable_profiled=yes;
53 fi] )
54 AC_ARG_ENABLE( trace,
55 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
56 [if test "$enableval" == "yes"; then
57 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
58 fi] )
59 AC_ARG_ENABLE( watch,
60 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
61 [if test "$enableval" == "yes"; then
62 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
63 fi] )
64 AC_ARG_ENABLE( sh4stats,
65 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
66 [if test "$enableval" == "yes"; then
67 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
68 fi] )
69 AC_ARG_WITH( osmesa,
70 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
71 [], [with_osmesa=no])
72 AC_ARG_WITH( gtk,
73 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
74 AC_ARG_WITH( esd,
75 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
76 AC_ARG_WITH( pulse,
77 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
78 AC_ARG_WITH( sdl,
79 AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
81 AC_ARG_WITH( sysroot,
82 AS_HELP_STRING( [--with-sysroot=SYSROOT], [Build using an alternate sysroot]),
83 [ m4_pattern_allow([PKG_CONFIG_LIBDIR])
84 if test -d "$with_sysroot/lib/pkgconfig"; then
85 LDFLAGS="$LDFLAGS -L$with_sysroot/lib"
86 CPPFLAGS="$CPPFLAGS -I$with_sysroot/include"
87 BUILD_PKG_CONFIG_LIBDIR="$PKG_CONFIG_LIBDIR"
88 TARGET_PKG_CONFIG_LIBDIR="$with_sysroot/lib/pkgconfig"
89 PKG_CONFIG_LIBDIR="$TARGET_PKG_CONFIG_LIBDIR"
90 export PKG_CONFIG_LIBDIR;
91 else
92 AC_MSG_FAILURE([pkg-config directory $with_sysroot/lib/pkgconfig not found, when using --with-sysroot=$with_sysroot option])
93 fi
94 ])
96 LX_ANDROID_BUILD
98 dnl ------------ Check if we're building on Darwin or Android --------------
100 dnl For starters, do we have a working objective-c compiler?
101 if test "$ANDROID_BUILD" = "yes"; then
102 with_gtk=no;
103 EXTRA_OUTPUT_FILES="src/android/build.properties"
104 UI_DRIVER="Android"
105 with_sdl=no
106 else
107 AC_HAVE_OBJC([
108 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
109 HAVE_COCOA='yes'
110 APPLE_BUILD='yes'
111 LIBS="$LIBS -framework AppKit -framework Carbon"
112 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
113 LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
114 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
115 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
116 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
117 UI_DRIVER="Cocoa"
118 if test "x$with_gtk" = "xx11"; then
119 with_gtk=no
120 fi
121 ], [], [AC_INCLUDES_DEFAULT])
123 AC_OBJC_VERSION([ OBJCOPT="-O2"
124 OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
125 [ OBJCOPT="-O2" ], [] )
126 AC_CHECK_OBJCFLAG([-msse2])
127 AC_CHECK_OBJCFLAG([-mfpmath=sse])
128 ])
129 fi
131 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
132 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
133 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
134 fi
136 dnl ------------------ C Compiler flags -----------------------
137 CFLAGS_FOR_BUILD="-O2 -std=c99"
138 CFLAGS="-g -fexceptions"
139 OBJCFLAGS="-g -fexceptions"
140 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
142 STDCFLAG="-std=c99"
143 AC_CC_VERSION([ CCOPT="-O2"
144 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
145 [ CCOPT="$CFLAGS -fast"
146 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
147 [ CCOPT="$CFLAGS -O2" ])
148 AC_CHECK_CFLAG([-msse2])
149 AC_CHECK_CFLAG([-mfpmath=sse])
151 if test "x$enable_optimized" = "xyes"; then
152 CFLAGS="$CFLAGS $CCOPT"
153 OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
154 if test "x$enable_profiled" != "xyes"; then
155 dnl -fomit-frame-pointer can't be used with -pg
156 CFLAGS="$CFLAGS -fomit-frame-pointer"
157 OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
158 fi
159 else
160 CFLAGS="$CFLAGS -g3"
161 OBJCFLAGS="$OBJCFLAGS -g3"
162 fi
164 if test "x$enable_profiled" = "xyes"; then
165 CFLAGS="$CFLAGS -pg"
166 LDFLAGS="$LDFLAGS -pg";
167 OBJCFLAGS="$OBJCFLAGS -pg";
168 fi
170 if test "x$enable_strictwarn" = "xyes"; then
171 CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
172 OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
173 fi
175 if test "x$enable_shared" != "xno"; then
176 if test "x$APPLE_BUILD" = "xyes"; then
177 SOEXT="dylib"
178 PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
179 else
180 SOEXT="so"
181 PLUGINLDFLAGS="-shared"
182 fi
183 PLUGINCFLAGS="-fPIC"
185 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
186 AC_CHECK_HEADER( [dlfcn.h], [
187 AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
188 if test "x$have_dlopen" != "xyes"; then
189 if test "x$enable_shared" == "xyes"; then
190 AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
191 else
192 AC_MSG_WARN("Statically linking all plugins")
193 fi
194 fi
196 dnl Check if linker accepts -rdynamic
197 AC_MSG_CHECKING([if linker accepts -rdynamic])
198 old_LDFLAGS="$LDFLAGS"
199 LDFLAGS="$LDFLAGS -rdynamic"
200 AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
201 LXDREAMLDFLAGS="-rdynamic"
202 AC_MSG_RESULT([yes])
203 ], [
204 LXDREAMLDFLAGS=""
205 AC_MSG_RESULT([no]) ])
206 LDFLAGS="$old_LDFLAGS"
208 AC_SUBST(SOEXT)
209 AC_SUBST(PLUGINCFLAGS)
210 AC_SUBST(PLUGINLDFLAGS)
211 AC_SUBST(LXDREAMLDFLAGS)
212 fi
213 if test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"; then
214 AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])
215 fi
216 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"])
218 AC_CHECK_FASTCALL([
219 AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
220 ])
221 AC_CHECK_FORCEINLINE()
222 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
223 AC_CHECK_FRAME_ADDRESS( [
224 AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
225 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
227 AC_SUBST(LXDREAMCPPFLAGS)
228 AC_SEARCH_LIBS(listen, [socket])
229 AC_SEARCH_LIBS(inet_ntoa,[nsl])
231 dnl ----------- Check for mandatory dependencies --------------
232 dnl Check for libpng (required)
233 PKG_CHECK_MODULES(LIBPNG, [libpng] )
235 dnl Implied by libpng, but check explicitly just in case
236 AC_CHECK_LIB(z, uncompress, [], [
237 echo "Zlib (libz.so) could not be found, but is required."
238 exit 1])
240 dnl Check for libm (optional, required on some platforms)
241 AC_CHECK_LIB(m, sqrt)
243 if test "x$with_gtk" = "xno"; then
244 dnl Check for GLIB only
245 PKG_CHECK_MODULES(GLIB, glib-2.0)
246 else
247 dnl Check for GTK
248 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
249 HAVE_GTK='yes'
250 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
251 UI_DRIVER="GTK"
252 ])
254 dnl Which GTK port do we have?
255 LIBS="$LIBS $GTK_LIBS"
256 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
257 HAVE_GTK_X11='yes'
258 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
259 dnl Add -lX11 explicitly as some pkg-configs get it wrong
260 GTK_LIBS="$GTK_LIBS -lX11"
261 LIBS="$LIBS -lX11"
262 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
263 HAVE_GTK_OSX='yes'
264 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
265 if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
266 AC_MSG_FAILURE( [Unable to identify GTK platform] )
267 fi
268 fi
270 AC_PUSH_CC_FOR_BUILD
271 if test "$BUILD_PKG_CONFIG_LIBDIR" != "$TARGET_PKG_CONFIG_LIBDIR"; then
272 PKG_CONFIG_LIBDIR="$BUILD_PKG_CONFIG_LIBDIR";
273 if test "x$PKG_CONFIG_LIBDIR" = "x"; then
274 export -n PKG_CONFIG_LIBDIR
275 fi
276 fi
277 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)
278 if test "$BUILD_PKG_CONFIG_LIBDIR" != "$TARGET_PKG_CONFIG_LIBDIR"; then
279 PKG_CONFIG_LIBDIR="$TARGET_PKG_CONFIG_LIBDIR";
280 export PKG_CONFIG_LIBDIR
281 fi
282 AC_POP_CC_FOR_BUILD
284 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
286 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
287 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
288 dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
289 dnl LIBS="-lisofs $LIBS"
290 dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])],
291 dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
293 dnl ------------------ Video driver support -------------------
294 AS_IF([test "x$with_osmesa" != xno], [
296 dnl User requested OSMesa (ie pure software rendering)
297 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
298 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
299 AC_CHECK_HEADER([GL/osmesa.h], [],
300 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
301 HAVE_OSMESA='yes'
302 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
303 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
305 dnl Otherwise we want a real GL library (unless we're on darwin or android, in which case it's already
306 dnl taken care of above).
307 if test "x$APPLE_BUILD" != 'xyes'; then
308 PKG_CHECK_MODULES(LIBGL, [gl], [
309 LIBS="$LIBS $LIBGL_LIBS";
310 CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
311 ], [
312 dnl GL library not found, try for GLESv2 + EGL
313 AC_CHECK_LIB(GLESv2, glEnable, [LIBS="-lGLESv2 $LIBS"; HAVE_GLES2='yes'],
314 [ AC_MSG_FAILURE([Neither the OpenGL library (libGL.so) nor the OpenGL ES 2.0 library (libGLESv2.so) could be found, but one is required.]) ])
315 ])
317 else
318 AC_CHECK_FUNC(NSOpenGLGetVersion, [
319 HAVE_NSGL='yes'
320 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
321 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
322 if test "x$HAVE_GTK_X11" = "xyes"; then
323 LIBS="$LIBS -L/usr/X11/lib -lGL"
324 fi
325 fi
327 dnl Now work out how to get from the UI to GL - this is usually the painful part.
328 AC_CHECK_FUNC(glXQueryVersion, [
329 HAVE_GLX='yes'
330 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
331 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
332 AC_CHECK_LIB(EGL, eglGetDisplay, [
333 LIBS="-lEGL $LIBS"
334 HAVE_EGL='yes'
335 VIDEO_DRIVERS="$VIDEO_DRIVERS egl"])
336 ])
338 if test "x$HAVE_GLES2" = "xyes"; then
339 AC_DEFINE(HAVE_GLES2, 1, [Using GLESv2])
340 fi
342 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
343 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
344 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
345 AM_CONDITIONAL(VIDEO_EGL, [test "x$HAVE_EGL" = "xyes"])
347 dnl Check for optional (but highly desireable) OpenGL features
348 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
349 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
350 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
351 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
352 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
353 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])
354 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident function]) ], [])
355 AC_CHECK_FUNC(glDrawBuffer, [ AC_DEFINE([HAVE_OPENGL_DRAW_BUFFER],1,[Have glDrawBuffer function])], [])
356 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.
358 dnl ------------------- SH4 translator target -------------------
360 if test "x$enable_translator" != "xno"; then
361 case $host_cpu in
362 i386|i486|i586|i686|x86_64)
363 SH4_TRANSLATOR="x86"
364 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
365 esac
366 fi
367 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
369 dnl ------------------ Optional driver support -------------------
370 dnl Check for Apple CoreAudio
371 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
372 HAVE_CORE_AUDIO=yes
373 LIBS="$LIBS -framework CoreAudio"
374 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
375 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
376 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
378 dnl Check for SDL (only used for audio at the moment)
379 if test "x$with_sdl" != "xno"; then
380 PKG_CHECK_MODULES(SDL, [sdl], [
381 HAVE_SDL='yes'
382 AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
383 AC_DEFINE([HAVE_SDL],1,[Have SDL support])
384 ], [
385 if test "x$with_sdl" = "xyes"; then
386 AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
387 fi
388 ])
389 fi
390 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
392 dnl Check for pulseaudio
393 if test "x$with_pulse" != "xno"; then
394 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
395 HAVE_PULSE='yes'
396 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
397 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
398 ], [
399 if test "x$with_pulse" = "xyes"; then
400 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
401 fi
402 ])
403 fi
404 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
406 dnl Check for esound
407 if test "x$with_esd" != "xno"; then
408 PKG_CHECK_MODULES(ESOUND, [esound], [
409 HAVE_ESOUND='yes'
410 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
411 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
412 ], [
413 if test "x$with_esd" = "xyes"; then
414 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
415 fi
416 ])
417 fi
418 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
420 dnl Check for alsa support
421 PKG_CHECK_MODULES(ALSA, [alsa], [
422 HAVE_ALSA='yes'
423 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
424 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
425 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
428 dnl Check for native cdrom support. There can be only one.
429 if test "$ANDROID_BUILD" != "yes"; then
430 AC_CHECK_HEADER([linux/cdrom.h], [
431 CDROM_DRIVER=linux
432 dnl Some kernel versions have non-c99 compliant headers - check here
433 AC_MSG_CHECKING([C99 compliant kernel headers])
434 old_CFLAGS="$CFLAGS"
435 CFLAGS="$CFLAGS $STDCFLAG"
436 AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
437 AC_MSG_RESULT([No])
438 STDCFLAG="-std=gnu99"])
439 CFLAGS="$old_CFLAGS"
440 ], [true])
441 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
442 CDROM_DRIVER=osx
443 LIBS="$LIBS -framework IOKit"],[true])
444 fi
445 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
446 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
447 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
448 if test "x$CDROM_DRIVER" = "xlinux"; then
449 AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
450 fi
452 AC_CHECK_HEADER([linux/joystick.h], [
453 HAVE_LINUX_JOYSTICK_H=yes
454 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support])
455 INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ],
456 [ echo "Linux Joystick support not found, building without it."] )
457 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
459 dnl Check for LIRC
460 if test "x$with_lirc" != "xno"; then
461 AC_CHECK_HEADER([lirc/lirc_client.h], [
462 HAVE_LIRC_CLIENT_H=yes
463 AC_DEFINE([HAVE_LIRC],1,[Have LIRC support])
464 INPUT_DRIVERS="$INPUT_DRIVERS lirc"
465 ],
466 [ echo "LIRC support not found, building without it." ] )
467 fi
468 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
470 dnl Check for cross-compiler availability - needed for system tests
471 AC_PATH_PROG(SHCC, [sh-elf-gcc])
472 AC_PATH_PROG(SHLD, [sh-elf-ld])
473 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
474 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
475 AC_PATH_PROG(ARMLD, [arm-elf-ld])
476 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
478 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
479 BUILD_SH="no"
480 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
481 else
482 BUILD_SH="yes"
483 fi
484 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
485 BUILD_ARM="no"
486 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
487 else
488 BUILD_ARM="yes"
489 fi
490 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
491 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
493 CFLAGS="$CFLAGS $STDCFLAG"
495 dnl ----------------------- All done, finish up -----------------------
496 GETTEXT_PACKAGE=lxdream
497 LXDREAM_LIBS="$LIBS"
498 LIBS=""
499 AC_SUBST(LXDREAM_LIBS)
500 AC_SUBST(GETTEXT_PACKAGE)
501 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
503 dnl Add the languages which your application supports here.
504 ALL_LINGUAS="de es it nl pt_BR"
505 AM_GLIB_GNU_GETTEXT
507 AC_OUTPUT([
508 Makefile
509 src/Makefile
510 src/tools/Makefile
511 po/Makefile.in
512 test/Makefile
513 Info.plist
514 ])
515 AS_MKDIR_P(test/sh4)
517 dnl ------------------------- Print out a summary ----------------------
519 echo
520 echo "Configuration complete"
521 echo
523 if test "x$UI_DRIVER" = x; then
524 echo " User interface: none"
525 else
526 echo " User interface: $UI_DRIVER"
527 fi
529 if test "x$SH4_TRANSLATOR" = "x"; then
530 echo " SH4 translator: none (emulation core only)"
531 else
532 echo " SH4 translator: $SH4_TRANSLATOR"
533 fi
535 if test "x$VIDEO_DRIVERS" = "x"; then
536 echo " Video drivers: none (no supported GL found)"
537 else
538 echo " Video drivers: $VIDEO_DRIVERS"
539 fi
541 if test "x$AUDIO_DRIVERS" = "x"; then
542 echo " Audio drivers: none (no supported output devices found)"
543 else
544 echo " Audio drivers: $AUDIO_DRIVERS"
545 fi
547 if test "x$INPUT_DRIVERS" = "x"; then
548 echo " Input drivers: none (no supported input devices found)"
549 else
550 echo " Input drivers: $INPUT_DRIVERS"
551 fi
553 if test "x$CDROM_DRIVER" = "x"; then
554 echo " CD-ROM driver: none (no supported cd-rom devices found)"
555 else
556 echo " CD-ROM driver: $CDROM_DRIVER"
557 fi
.