Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 1235:8da2f3dad9c0
prev1228:8168aa94e6d7
next1239:be3121267597
author nkeynes
date Fri Feb 24 21:11:58 2012 +1000 (8 years ago)
permissions -rw-r--r--
last change Add preprocessing support to genglsl
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_CANONICAL_BUILD
     9 AC_CANONICAL_HOST
    11 m4_include([m4/ccforbuild.m4])
    13 AC_ISC_POSIX
    14 AC_PROG_CC
    15 AM_PROG_CC_STDC
    16 AC_PROG_CC_FOR_BUILD
    17 AC_PROG_OBJC
    18 AC_PROG_SED
    19 AM_PROG_AS
    20 AC_PROG_RANLIB
    21 AC_CHECK_SIZEOF([void *])
    22 AC_HEADER_STDC
    24 _AM_DEPENDENCIES([OBJC])
    26 AC_PATH_PROG(POD2MAN, [pod2man])
    27 AC_PATH_PROG(POD2HTML, [pod2html])
    29 AC_DEFINE_UNQUOTED(BUILD_SED_PROG, ["${SED}"], [Sed to use for build tools])
    30 AC_DEFINE_UNQUOTED(BUILD_CPP_PROG, ["${CPP}"], [CPP to use for build tools])
    32 dnl ---------------- enable/with flags ------------------
    34 AC_ARG_ENABLE( strict-warn,
    35    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
    36    [if test "$enableval" == "yes"; then
    37       enable_strictwarn=yes
    38     fi] )
    39 AC_ARG_ENABLE( translator, 
    40    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
    41    [true], [enable_translator=yes] )
    42 AC_ARG_ENABLE( optimized,
    43    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
    44    [true], [enable_optimized=yes] )
    45 AC_ARG_ENABLE( shared,
    46    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
    47    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
    48 AC_ARG_ENABLE( profiled,
    49    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
    50    [if test "$enableval" == "yes"; then
    51       enable_profiled=yes;
    52     fi] )
    53 AC_ARG_ENABLE( trace, 
    54    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    55    [if test "$enableval" == "yes"; then
    56      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    57     fi] )
    58 AC_ARG_ENABLE( watch,
    59    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    60    [if test "$enableval" == "yes"; then
    61      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    62    fi] )
    63 AC_ARG_ENABLE( sh4stats,
    64    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    65    [if test "$enableval" == "yes"; then
    66      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    67     fi] )
    68 AC_ARG_WITH( osmesa,
    69    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    70    [], [with_osmesa=no])
    71 AC_ARG_WITH( gtk,
    72    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    73 AC_ARG_WITH( esd,
    74    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    75 AC_ARG_WITH( pulse,
    76    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    77 AC_ARG_WITH( sdl,
    78    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
    81 dnl ------------ Check if we're building on Darwin --------------
    83 dnl For starters, do we have a working objective-c compiler?
    84 AC_HAVE_OBJC([
    85    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    86       HAVE_COCOA='yes'
    87       APPLE_BUILD='yes'
    88       LIBS="$LIBS -framework AppKit -framework Carbon"
    89       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    90       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
    91       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    92       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    93       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    94       if test "x$with_gtk" = "xx11"; then
    95         with_gtk=no
    96       fi
    97    ], [], [AC_INCLUDES_DEFAULT])
    99    AC_OBJC_VERSION([ OBJCOPT="-O2"
   100                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
   101                    [ OBJCOPT="-O2" ], [] )
   102    AC_CHECK_OBJCFLAG([-msse2])
   103    AC_CHECK_OBJCFLAG([-mfpmath=sse])
   104 ])
   106 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
   107 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
   108   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
   109 fi
   111 dnl ------------------ C Compiler flags -----------------------
   112 CFLAGS_FOR_BUILD="-O2 -std=c99"
   113 CFLAGS="-g -fexceptions"
   114 OBJCFLAGS="-g -fexceptions"
   115 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
   117 STDCFLAG="-std=c99"
   118 AC_CC_VERSION([ CCOPT="-O2" 
   119                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   120               [ CCOPT="$CFLAGS -fast"
   121                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
   122               [ CCOPT="$CFLAGS -O2" ])
   123 AC_CHECK_CFLAG([-msse2])
   124 AC_CHECK_CFLAG([-mfpmath=sse])
   126 if test "x$enable_optimized" = "xyes"; then
   127    CFLAGS="$CFLAGS $CCOPT"
   128    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
   129    if test "x$enable_profiled" != "xyes"; then
   130        dnl -fomit-frame-pointer can't be used with -pg
   131        CFLAGS="$CFLAGS -fomit-frame-pointer"
   132        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
   133    fi
   134 else
   135    CFLAGS="$CFLAGS -g3"
   136    OBJCFLAGS="$OBJCFLAGS -g3"
   137 fi
   139 if test "x$enable_profiled" = "xyes"; then
   140    CFLAGS="$CFLAGS -pg"
   141    LDFLAGS="$LDFLAGS -pg";
   142    OBJCFLAGS="$OBJCFLAGS -pg";
   143 fi
   145 if test "x$enable_strictwarn" = "xyes"; then
   146    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
   147    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
   148 fi
   150 if test "x$enable_shared" != "xno"; then
   151    if test "x$APPLE_BUILD" = "xyes"; then
   152       SOEXT="dylib"
   153       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
   154    else 
   155       SOEXT="so"
   156       PLUGINLDFLAGS="-shared"
   157    fi
   158    PLUGINCFLAGS="-fPIC"
   160 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
   161    AC_CHECK_HEADER( [dlfcn.h], [
   162       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
   163    if test "x$have_dlopen" != "xyes"; then
   164       if test "x$enable_shared" == "xyes"; then
   165          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
   166       else
   167          AC_MSG_WARN("Statically linking all plugins")
   168       fi
   169    fi
   171 dnl Check if linker accepts -rdynamic
   172    AC_MSG_CHECKING([if linker accepts -rdynamic])
   173    old_LDFLAGS="$LDFLAGS"
   174    LDFLAGS="$LDFLAGS -rdynamic"
   175    AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
   176      LXDREAMLDFLAGS="-rdynamic"
   177      AC_MSG_RESULT([yes]) 
   178    ], [
   179      LXDREAMLDFLAGS=""
   180      AC_MSG_RESULT([no]) ])
   181    LDFLAGS="$old_LDFLAGS"
   183    AC_SUBST(SOEXT)
   184    AC_SUBST(PLUGINCFLAGS)
   185    AC_SUBST(PLUGINLDFLAGS)
   186    AC_SUBST(LXDREAMLDFLAGS)
   187 fi
   188 if test "x$have_dlopen" = "xyes"; then
   189     AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])
   190 fi
   191 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes"])
   193 AC_CHECK_FASTCALL([
   194    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
   195 ])
   196 AC_CHECK_FORCEINLINE()
   197 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
   198 AC_CHECK_FRAME_ADDRESS( [
   199    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
   200 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
   202 AC_SUBST(LXDREAMCPPFLAGS)
   203 AC_SEARCH_LIBS(listen, [socket])
   204 AC_SEARCH_LIBS(inet_ntoa,[nsl])
   206 dnl ----------- Check for mandatory dependencies --------------
   207 dnl Check for libpng (required)
   208 PKG_CHECK_MODULES(LIBPNG, [libpng] )
   210 dnl Implied by libpng, but check explicitly just in case
   211 AC_CHECK_LIB(z, uncompress, [], [
   212     echo "Zlib (libz.so) could not be found, but is required."
   213     exit 1])
   215 if test "x$with_gtk" = "xno"; then
   216    dnl Check for GLIB only
   217    PKG_CHECK_MODULES(GLIB, glib-2.0)
   218 else
   219    dnl Check for GTK
   220    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
   221        HAVE_GTK='yes'
   222        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
   223    ])
   225    dnl Which GTK port do we have?
   226    LIBS="$LIBS $GTK_LIBS"
   227    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
   228       HAVE_GTK_X11='yes'
   229       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
   230       dnl Add -lX11 explicitly as some pkg-configs get it wrong
   231       GTK_LIBS="$GTK_LIBS -lX11"
   232       LIBS="$LIBS -lX11"
   233    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
   234       HAVE_GTK_OSX='yes'
   235       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   236    if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
   237       AC_MSG_FAILURE( [Unable to identify GTK platform] )
   238    fi
   239 fi
   241 AC_PUSH_CC_FOR_BUILD
   242 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)
   243 AC_POP_CC_FOR_BUILD
   245 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   247 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
   248 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
   249    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
   250       dnl LIBS="$LIBS -lisofs"
   251    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])], 
   252       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
   254 dnl ------------------ Video driver support -------------------
   255 AS_IF([test "x$with_osmesa" != xno], [ 
   257 dnl User requested OSMesa (ie pure software rendering)
   258   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   259     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   260   AC_CHECK_HEADER([GL/osmesa.h], [],
   261     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   262   HAVE_OSMESA='yes'
   263   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   264   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   266 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   267 dnl taken care of above).
   268    if test "x$APPLE_BUILD" != 'xyes'; then
   269       PKG_CHECK_MODULES(LIBGL, [gl] )
   270       dnl AC_CHECK_LIB(GL, glVertex3f, [], [
   271           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   272       dnl AC_CHECK_HEADER([GL/gl.h], [], [
   273           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   274       LIBS="$LIBS $LIBGL_LIBS";
   275       CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
   276    else
   277       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   278          HAVE_NSGL='yes'
   279          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   280          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   281    fi
   283 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   284    if test "x$HAVE_GTK_X11" = "xyes"; then
   285       if test "x$APPLE_BUILD" = "xyes"; then
   286          LIBS="$LIBS -L/usr/X11/lib -lGL"
   287       fi
   288       AC_CHECK_FUNC(glXQueryVersion, [
   289          HAVE_GLX='yes'
   290          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   291          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   292    fi
   294 ])
   298 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   299 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   300 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   302 dnl Check for optional (but highly desireable) OpenGL features
   303 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
   304 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
   305 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   306 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   307 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   308 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])
   309 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident function]) ], [])
   310 AC_CHECK_FUNC(glDrawBuffer, [ AC_DEFINE([HAVE_OPENGL_DRAW_BUFFER],1,[Have glDrawBuffer function])], [])
   311 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.
   315 dnl ------------------- SH4 translator target -------------------
   317 if test "x$enable_translator" != "xno"; then
   318     case $host_cpu in
   319         i386|i486|i586|i686|x86_64)
   320 	    SH4_TRANSLATOR="x86"
   321             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   322     esac
   323 fi
   324 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   326 dnl ------------------ Optional driver support -------------------
   327 dnl Check for Apple CoreAudio
   328 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   329      HAVE_CORE_AUDIO=yes
   330      LIBS="$LIBS -framework CoreAudio"
   331      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   332      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   333 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   335 dnl Check for SDL (only used for audio at the moment)
   336 if test "x$with_sdl" != "xno"; then
   337    PKG_CHECK_MODULES(SDL, [sdl], [
   338        HAVE_SDL='yes'
   339        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
   340        AC_DEFINE([HAVE_SDL],1,[Have SDL support])
   341    ], [
   342       if test "x$with_sdl" = "xyes"; then
   343          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
   344       fi
   345    ])
   346 fi
   347 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
   349 dnl Check for pulseaudio
   350 if test "x$with_pulse" != "xno"; then
   351    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   352        HAVE_PULSE='yes'
   353        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   354        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   355    ], [
   356        if test "x$with_pulse" = "xyes"; then
   357           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   358        fi
   359    ])
   360 fi
   361 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   363 dnl Check for esound
   364 if test "x$with_esd" != "xno"; then
   365    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   366        HAVE_ESOUND='yes'
   367        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   368        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   369    ], [
   370        if test "x$with_esd" = "xyes"; then
   371           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   372        fi
   373    ])
   374 fi
   375 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   377 dnl Check for alsa support
   378 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   379      HAVE_ALSA='yes'
   380      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   381      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   382 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   385 dnl Check for native cdrom support. There can be only one.
   386 AC_CHECK_HEADER([linux/cdrom.h], [
   387      CDROM_DRIVER=linux
   388      dnl Some kernel versions have non-c99 compliant headers - check here
   389      AC_MSG_CHECKING([C99 compliant kernel headers])
   390      old_CFLAGS="$CFLAGS"
   391      CFLAGS="$CFLAGS $STDCFLAG"
   392      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
   393         AC_MSG_RESULT([No])
   394         STDCFLAG="-std=gnu99"])
   395      CFLAGS="$old_CFLAGS"
   396 ], [true])
   397 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   398      CDROM_DRIVER=osx
   399      LIBS="$LIBS -framework IOKit"],[true])
   400 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   401 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   402 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   403 if test "x$CDROM_DRIVER" = "xlinux"; then
   404    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
   405 fi
   407 AC_CHECK_HEADER([linux/joystick.h], [
   408     HAVE_LINUX_JOYSTICK_H=yes
   409     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) 
   410     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ], 
   411   [ echo "Linux Joystick support not found, building without it."] )
   412 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   414 dnl Check for LIRC
   415 if test "x$with_lirc" != "xno"; then
   416     AC_CHECK_HEADER([lirc/lirc_client.h], [
   417         HAVE_LIRC_CLIENT_H=yes
   418         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) 
   419         INPUT_DRIVERS="$INPUT_DRIVERS lirc"
   420       ],
   421       [ echo "LIRC support not found, building without it." ] )
   422 fi
   423 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
   425 dnl Check for cross-compiler availability - needed for system tests
   426 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   427 AC_PATH_PROG(SHLD, [sh-elf-ld])
   428 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   429 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   430 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   431 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   433 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   434   BUILD_SH="no"
   435   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   436 else
   437   BUILD_SH="yes"
   438 fi
   439 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   440   BUILD_ARM="no"
   441   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   442 else
   443   BUILD_ARM="yes"
   444 fi
   445 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   446 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   448 CFLAGS="$CFLAGS $STDCFLAG"
   450 dnl ----------------------- All done, finish up -----------------------
   451 GETTEXT_PACKAGE=lxdream
   452 LXDREAM_LIBS="$LIBS"
   453 LIBS=""
   454 AC_SUBST(LXDREAM_LIBS)
   455 AC_SUBST(GETTEXT_PACKAGE)
   456 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   458 dnl Add the languages which your application supports here.
   459 ALL_LINGUAS="de es it nl pt_BR"
   460 AM_GLIB_GNU_GETTEXT
   462 AC_OUTPUT([
   463 Makefile
   464 src/Makefile
   465 src/tools/Makefile
   466 po/Makefile.in
   467 test/Makefile
   468 Info.plist
   469 ])
   470 AS_MKDIR_P(test/sh4)
   472 dnl ------------------------- Print out a summary ----------------------
   474 echo
   475 echo "Configuration complete"
   476 echo
   478 if test "x$HAVE_GTK" = x; then
   479   if test "x$HAVE_COCOA" = x; then
   480      echo "  User interface: none"
   481   else
   482      echo "  User interface: Cocoa"
   483   fi
   484 else
   485   echo "  User interface: GTK"
   486 fi
   488 if test "x$SH4_TRANSLATOR" = "x"; then
   489   echo "  SH4 translator: None (emulation core only)"
   490 else
   491   echo "  SH4 translator: $SH4_TRANSLATOR"
   492 fi
   494 if test "x$VIDEO_DRIVERS" = "x"; then
   495    echo "  Video drivers: none (no supported GL found)"
   496 else
   497    echo "  Video drivers: $VIDEO_DRIVERS"
   498 fi
   500 if test "x$AUDIO_DRIVERS" = "x"; then
   501    echo "  Audio drivers: none (no supported output devices found)"
   502 else
   503    echo "  Audio drivers: $AUDIO_DRIVERS"
   504 fi
   506 if test "x$INPUT_DRIVERS" = "x"; then
   507    echo "  Input drivers: none (no supported input devices found)"
   508 else
   509    echo "  Input drivers: $INPUT_DRIVERS"
   510 fi
   512 if test "x$CDROM_DRIVER" = "x"; then
   513    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   514 else
   515    echo "  CD-ROM driver:  $CDROM_DRIVER"
   516 fi
.