Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 671:a530ea88eebd
prev664:728508bb08df
next675:b97020f9af1c
author nkeynes
date Thu May 15 10:22:39 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Permanently add SH4 instruction statistics tracking (enabled with --enable-sh4stats)
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_HEADER_STDC
    13 AC_CANONICAL_BUILD
    14 AC_CANONICAL_HOST
    15 AC_ARG_ENABLE( trace, 
    16    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    17    [if test "$enableval" == "yes"; then
    18      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    19     fi] )
    20 AC_ARG_ENABLE( watch,
    21    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    22    [if test "$enableval" == "yes"; then
    23      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    24    fi] )
    25 AC_ARG_ENABLE( sh4stats,
    26    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    27    [if test "$enableval" == "yes"; then
    28      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    29     fi] )
    30 AC_ARG_WITH( osmesa,
    31    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    32    [], [with_osmesa=no])
    35 dnl ------------ Check if we're building on Darwn --------------
    37 dnl For starters, do we have a working objective-c compiler?
    38 lxdream_save_cppflags="$CPPFLAGS"
    39 CPPFLAGS="$CPPFLAGS -x objective-c"
    40 AC_TRY_COMPILE([@interface Foo @end],, [
    42    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    43       HAVE_COCOA='yes'
    44       APPLE_BUILD='yes'
    45       LIBS="$LIBS -framework AppKit"
    46       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    47       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    48       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    49    ])
    51 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    52 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes'])
    54 dnl ----------- Check for mandatory dependencies --------------
    55 dnl Check for libpng (required)
    56 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    58 dnl Implied by libpng, but check explicitly just in case
    59 AC_CHECK_LIB(z, uncompress, [], [
    60     echo "Zlib (libz.so) could not be found, but is required."
    61     exit 1])
    64 dnl Check for GTK (currently compulsory)
    65 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    66     HAVE_GTK='yes'
    67     AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    68 ])
    69 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    71 dnl Which GTK port do we have?
    72 LIBS="$LIBS $GTK_LIBS"
    73 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    74    HAVE_GTK_X11='yes'
    75    AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    76 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    77    HAVE_GTK_OSX='yes'
    78    AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    80 dnl ------------------ Video driver support -------------------
    81 AS_IF([test "x$with_osmesa" != xno], [ 
    83 dnl User requested OSMesa (ie pure software rendering)
    84   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
    85     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
    86   AC_CHECK_HEADER([GL/osmesa.h], [],
    87     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
    88   HAVE_OSMESA='yes'
    89   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
    91 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
    92 dnl taken care of above).
    93    if test "x$APPLE_BUILD" != 'xyes'; then
    94       AC_CHECK_LIB(GL, glVertex3f, [], [
    95           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
    96       AC_CHECK_HEADER([GL/gl.h], [], [
    97           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
    98    fi
   100 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   101    if test "x$HAVE_GTK_X11" = "xyes"; then
   102       if test "x$APPLE_BUILD" = "xyes"; then
   103          LIBS="$LIBS -L/usr/X11/lib -lGL"
   104       fi
   105       AC_CHECK_FUNC(glXQueryVersion, [
   106          HAVE_GLX='yes'
   107          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   108    elif test "x$HAVE_GTK_OSX" = "xyes"; then
   109       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   110          HAVE_NSGL='yes'
   111          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   112    fi
   114 ])
   117 dnl OK, now decide which video driver(s) we can build
   118 if test "x$HAVE_OSMESA" = "x" -a "x$HAVE_GLX" = "x" -a "x$HAVE_NSGL" = "x"; then
   119    echo "Warning: Building with no video support"
   120 fi
   122 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   123 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   124 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   126 dnl Check for optional (but highly desireable) OpenGL features
   127 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   128 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   129 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   132 dnl Check for a supported cpu target for translation purposes
   133 case $host_cpu in
   134     i386|i486|i586|i686)
   135 	SH4_TRANSLATOR="x86"
   136         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   137     x86_64)
   138 	SH4_TRANSLATOR="x86_64"
   139         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86_64], [SH4 Translator to use (if any)] );;
   140     *)
   141 	echo "Warning: No translator available for $host. Building emulation core only";;
   142 esac
   143 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   144 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   146 dnl ------------------ Optional driver support -------------------
   147 dnl Check for pulseaudio
   148 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   149      HAVE_PULSE='yes'
   150      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
   151 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   153 dnl Check for esound
   154 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   155      HAVE_ESOUND='yes'
   156      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   157 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   159 dnl Check for alsa support
   160 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   161      HAVE_ALSA='yes'
   162      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   163 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   165 if test "x$HAVE_ESOUND" = "x" -a "x$HAVE_ALSA" = "x" -a "x$HAVE_PULSE" = "x"; then
   166    echo "Warning: Building without audio support"
   167 fi
   169 dnl Check for linux cdrom device support
   170 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   171     echo "Linux CDROM support not found, building without it."]  )
   172 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   174 AC_CHECK_HEADER([linux/joystick.h], [
   175     HAVE_LINUX_JOYSTICK_H=yes
   176     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   177   [ echo "Linux Joystick support not found, building without it."] )
   178 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   180 dnl Check for cross-compiler availability - needed for system tests
   181 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   182 AC_PATH_PROG(SHLD, [sh-elf-ld])
   183 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   184 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   185 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   186 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   188 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   189   BUILD_SH="no"
   190   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   191 else
   192   BUILD_SH="yes"
   193 fi
   194 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   195   BUILD_ARM="no"
   196   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   197 else
   198   BUILD_ARM="yes"
   199 fi
   200 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   201 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   204 dnl ----------------------- All done, finish up -----------------------
   205 GETTEXT_PACKAGE=lxdream
   206 AC_SUBST(GETTEXT_PACKAGE)
   207 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   209 dnl Add the languages which your application supports here.
   210 ALL_LINGUAS="de es it pt_BR"
   211 AM_GLIB_GNU_GETTEXT
   213 AC_OUTPUT([
   214 Makefile
   215 src/Makefile
   216 po/Makefile.in
   217 test/Makefile
   218 ])
.