Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 756:38385124df7a
prev746:3a574a68e793
next769:f7f62bea4cad
author nkeynes
date Thu Jul 24 07:27:48 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Halt emulation after reporting an error
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.3)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( translator, 
    23    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enable by default)]),
    24    [true], [enable_translator=yes] )
    25 AC_ARG_ENABLE( trace, 
    26    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    27    [if test "$enableval" == "yes"; then
    28      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    29     fi] )
    30 AC_ARG_ENABLE( watch,
    31    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    32    [if test "$enableval" == "yes"; then
    33      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    34    fi] )
    35 AC_ARG_ENABLE( sh4stats,
    36    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    37    [if test "$enableval" == "yes"; then
    38      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    39     fi] )
    40 AC_ARG_WITH( osmesa,
    41    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    42    [], [with_osmesa=no])
    43 AC_ARG_WITH( gtk,
    44    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    45 AC_ARG_WITH( esd,
    46    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    47 AC_ARG_WITH( pulse,
    48    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    50 dnl ------------ Check if we're building on Darwin --------------
    52 dnl For starters, do we have a working objective-c compiler?
    53 lxdream_save_cppflags="$CPPFLAGS"
    54 CPPFLAGS="$CPPFLAGS -x objective-c"
    55 AC_TRY_COMPILE([@interface Foo @end],, [
    57    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    58       HAVE_COCOA='yes'
    59       APPLE_BUILD='yes'
    60       LIBS="$LIBS -framework AppKit"
    61       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    62       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    63       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    64       if test "x$with_gtk" = "xx11"; then
    65         with_gtk=no
    66       fi
    67    ])
    69 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    70 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    72 dnl ----------- Check for mandatory dependencies --------------
    73 dnl Check for libpng (required)
    74 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    76 dnl Implied by libpng, but check explicitly just in case
    77 AC_CHECK_LIB(z, uncompress, [], [
    78     echo "Zlib (libz.so) could not be found, but is required."
    79     exit 1])
    81 if test "x$with_gtk" = "xno"; then
    82    dnl Check for GLIB only
    83    PKG_CHECK_MODULES(GLIB, glib-2.0)
    84 else
    85    dnl Check for GTK
    86    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    87        HAVE_GTK='yes'
    88        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    89    ])
    91    dnl Which GTK port do we have?
    92    LIBS="$LIBS $GTK_LIBS"
    93    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    94       HAVE_GTK_X11='yes'
    95       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    96    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    97       HAVE_GTK_OSX='yes'
    98       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    99 fi
   101 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   103 dnl ------------------ Video driver support -------------------
   104 AS_IF([test "x$with_osmesa" != xno], [ 
   106 dnl User requested OSMesa (ie pure software rendering)
   107   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   108     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   109   AC_CHECK_HEADER([GL/osmesa.h], [],
   110     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   111   HAVE_OSMESA='yes'
   112   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   113   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   115 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   116 dnl taken care of above).
   117    if test "x$APPLE_BUILD" != 'xyes'; then
   118       AC_CHECK_LIB(GL, glVertex3f, [], [
   119           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   120       AC_CHECK_HEADER([GL/gl.h], [], [
   121           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   122    else
   123       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   124          HAVE_NSGL='yes'
   125          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   126          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   127    fi
   129 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   130    if test "x$HAVE_GTK_X11" = "xyes"; then
   131       if test "x$APPLE_BUILD" = "xyes"; then
   132          LIBS="$LIBS -L/usr/X11/lib -lGL"
   133       fi
   134       AC_CHECK_FUNC(glXQueryVersion, [
   135          HAVE_GLX='yes'
   136          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   137          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   138    fi
   140 ])
   144 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   145 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   146 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   148 dnl Check for optional (but highly desireable) OpenGL features
   149 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   150 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   151 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   152 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   155 dnl ------------------- SH4 translator target -------------------
   157 if test "x$enable_translator" != "xno"; then
   158     case $host_cpu in
   159         i386|i486|i586|i686|x86_64)
   160 	    SH4_TRANSLATOR="x86"
   161             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   162     esac
   163 fi
   164 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   166 dnl ------------------ Optional driver support -------------------
   167 dnl Check for Apple CoreAudio
   168 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   169      HAVE_CORE_AUDIO=yes
   170      LIBS="$LIBS -framework CoreAudio"
   171      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   172      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   173 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   175 dnl Check for pulseaudio
   176 if test "x$with_pulse" != "xno"; then
   177    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   178        HAVE_PULSE='yes'
   179        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   180        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   181    ], [
   182        if test "x$with_pulse" = "xyes"; then
   183           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   184        fi
   185    ])
   186 fi
   187 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   189 dnl Check for esound
   190 if test "x$with_esd" != "xno"; then
   191    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   192        HAVE_ESOUND='yes'
   193        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   194        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   195    ], [
   196        if test "x$with_esd" = "xyes"; then
   197           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   198        fi
   199    ])
   200 fi
   201 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   203 dnl Check for alsa support
   204 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   205      HAVE_ALSA='yes'
   206      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   207      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   208 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   211 dnl Check for native cdrom support. There can be only one.
   212 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   213 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   214      CDROM_DRIVER=osx
   215      LIBS="$LIBS -framework IOKit"],[true])
   216 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   217 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   218 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   220 AC_CHECK_HEADER([linux/joystick.h], [
   221     HAVE_LINUX_JOYSTICK_H=yes
   222     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   223   [ echo "Linux Joystick support not found, building without it."] )
   224 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   226 dnl Check for cross-compiler availability - needed for system tests
   227 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   228 AC_PATH_PROG(SHLD, [sh-elf-ld])
   229 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   230 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   231 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   232 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   234 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   235   BUILD_SH="no"
   236   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   237 else
   238   BUILD_SH="yes"
   239 fi
   240 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   241   BUILD_ARM="no"
   242   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   243 else
   244   BUILD_ARM="yes"
   245 fi
   246 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   247 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   250 dnl ----------------------- All done, finish up -----------------------
   251 GETTEXT_PACKAGE=lxdream
   252 AC_SUBST(GETTEXT_PACKAGE)
   253 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   255 dnl Add the languages which your application supports here.
   256 ALL_LINGUAS="de es it pt_BR"
   257 AM_GLIB_GNU_GETTEXT
   259 AC_OUTPUT([
   260 Makefile
   261 src/Makefile
   262 po/Makefile.in
   263 test/Makefile
   264 ])
   265 AS_MKDIR_P(test/sh4)
   267 dnl ------------------------- Print out a summary ----------------------
   269 echo
   270 echo "Configuration complete"
   271 echo
   273 if test "x$HAVE_GTK" = x; then
   274   if test "x$HAVE_COCOA" = x; then
   275      echo "  User interface: none"
   276   else
   277      echo "  User interface: Cocoa"
   278   fi
   279 else
   280   echo "  User interface: GTK"
   281 fi
   283 if test "x$SH4_TRANSLATOR" = "x"; then
   284   echo "  SH4 translator: None (emulation core only)"
   285 else
   286   echo "  SH4 translator: $SH4_TRANSLATOR"
   287 fi
   289 if test "x$VIDEO_DRIVERS" = "x"; then
   290    echo "  Video drivers: none (no supported GL found)"
   291 else
   292    echo "  Video drivers: $VIDEO_DRIVERS"
   293 fi
   295 if test "x$AUDIO_DRIVERS" = "x"; then
   296    echo "  Audio drivers: none (no supported output devices found)"
   297 else
   298    echo "  Audio drivers: $AUDIO_DRIVERS"
   299 fi
   301 if test "x$CDROM_DRIVER" = "x"; then
   302    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   303 else
   304    echo "  CD-ROM driver: $CDROM_DRIVER"
   305 fi
.