Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 769:f7f62bea4cad
prev756:38385124df7a
next778:a34b180d92f7
author nkeynes
date Mon Jul 28 04:51:04 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Fix build of testsh4x86
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.3)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( translator, 
    23    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enable by default)]),
    24    [true], [enable_translator=yes] )
    25 AC_ARG_ENABLE( trace, 
    26    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    27    [if test "$enableval" == "yes"; then
    28      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    29     fi] )
    30 AC_ARG_ENABLE( watch,
    31    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    32    [if test "$enableval" == "yes"; then
    33      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    34    fi] )
    35 AC_ARG_ENABLE( sh4stats,
    36    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    37    [if test "$enableval" == "yes"; then
    38      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    39     fi] )
    40 AC_ARG_WITH( osmesa,
    41    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    42    [], [with_osmesa=no])
    43 AC_ARG_WITH( gtk,
    44    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    45 AC_ARG_WITH( esd,
    46    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    47 AC_ARG_WITH( pulse,
    48    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    50 dnl ------------ Check if we're building on Darwin --------------
    52 dnl For starters, do we have a working objective-c compiler?
    53 lxdream_save_cppflags="$CPPFLAGS"
    54 CPPFLAGS="$CPPFLAGS -x objective-c"
    55 AC_TRY_COMPILE([@interface Foo @end],, [
    57    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    58       HAVE_COCOA='yes'
    59       APPLE_BUILD='yes'
    60       LIBS="$LIBS -framework AppKit"
    61       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    62       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
    63       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    64       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    65       if test "x$with_gtk" = "xx11"; then
    66         with_gtk=no
    67       fi
    68    ])
    70 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    71 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    73 dnl ----------- Check for mandatory dependencies --------------
    74 dnl Check for libpng (required)
    75 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    77 dnl Implied by libpng, but check explicitly just in case
    78 AC_CHECK_LIB(z, uncompress, [], [
    79     echo "Zlib (libz.so) could not be found, but is required."
    80     exit 1])
    82 if test "x$with_gtk" = "xno"; then
    83    dnl Check for GLIB only
    84    PKG_CHECK_MODULES(GLIB, glib-2.0)
    85 else
    86    dnl Check for GTK
    87    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    88        HAVE_GTK='yes'
    89        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    90    ])
    92    dnl Which GTK port do we have?
    93    LIBS="$LIBS $GTK_LIBS"
    94    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    95       HAVE_GTK_X11='yes'
    96       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    97    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    98       HAVE_GTK_OSX='yes'
    99       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
   100 fi
   102 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   104 dnl ------------------ Video driver support -------------------
   105 AS_IF([test "x$with_osmesa" != xno], [ 
   107 dnl User requested OSMesa (ie pure software rendering)
   108   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   109     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   110   AC_CHECK_HEADER([GL/osmesa.h], [],
   111     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   112   HAVE_OSMESA='yes'
   113   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   114   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   116 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   117 dnl taken care of above).
   118    if test "x$APPLE_BUILD" != 'xyes'; then
   119       AC_CHECK_LIB(GL, glVertex3f, [], [
   120           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   121       AC_CHECK_HEADER([GL/gl.h], [], [
   122           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   123    else
   124       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   125          HAVE_NSGL='yes'
   126          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   127          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   128    fi
   130 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   131    if test "x$HAVE_GTK_X11" = "xyes"; then
   132       if test "x$APPLE_BUILD" = "xyes"; then
   133          LIBS="$LIBS -L/usr/X11/lib -lGL"
   134       fi
   135       AC_CHECK_FUNC(glXQueryVersion, [
   136          HAVE_GLX='yes'
   137          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   138          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   139    fi
   141 ])
   145 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   146 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   147 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   149 dnl Check for optional (but highly desireable) OpenGL features
   150 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   151 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   152 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   153 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   156 dnl ------------------- SH4 translator target -------------------
   158 if test "x$enable_translator" != "xno"; then
   159     case $host_cpu in
   160         i386|i486|i586|i686|x86_64)
   161 	    SH4_TRANSLATOR="x86"
   162             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   163     esac
   164 fi
   165 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
   167 dnl ------------------ Optional driver support -------------------
   168 dnl Check for Apple CoreAudio
   169 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   170      HAVE_CORE_AUDIO=yes
   171      LIBS="$LIBS -framework CoreAudio"
   172      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   173      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   174 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   176 dnl Check for pulseaudio
   177 if test "x$with_pulse" != "xno"; then
   178    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   179        HAVE_PULSE='yes'
   180        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   181        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   182    ], [
   183        if test "x$with_pulse" = "xyes"; then
   184           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   185        fi
   186    ])
   187 fi
   188 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   190 dnl Check for esound
   191 if test "x$with_esd" != "xno"; then
   192    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   193        HAVE_ESOUND='yes'
   194        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   195        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   196    ], [
   197        if test "x$with_esd" = "xyes"; then
   198           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   199        fi
   200    ])
   201 fi
   202 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   204 dnl Check for alsa support
   205 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   206      HAVE_ALSA='yes'
   207      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   208      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   209 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   212 dnl Check for native cdrom support. There can be only one.
   213 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   214 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   215      CDROM_DRIVER=osx
   216      LIBS="$LIBS -framework IOKit"],[true])
   217 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   218 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   219 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   221 AC_CHECK_HEADER([linux/joystick.h], [
   222     HAVE_LINUX_JOYSTICK_H=yes
   223     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   224   [ echo "Linux Joystick support not found, building without it."] )
   225 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   227 dnl Check for cross-compiler availability - needed for system tests
   228 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   229 AC_PATH_PROG(SHLD, [sh-elf-ld])
   230 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   231 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   232 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   233 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   235 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   236   BUILD_SH="no"
   237   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   238 else
   239   BUILD_SH="yes"
   240 fi
   241 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   242   BUILD_ARM="no"
   243   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   244 else
   245   BUILD_ARM="yes"
   246 fi
   247 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   248 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   251 dnl ----------------------- All done, finish up -----------------------
   252 GETTEXT_PACKAGE=lxdream
   253 AC_SUBST(GETTEXT_PACKAGE)
   254 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   256 dnl Add the languages which your application supports here.
   257 ALL_LINGUAS="de es it pt_BR"
   258 AM_GLIB_GNU_GETTEXT
   260 AC_OUTPUT([
   261 Makefile
   262 src/Makefile
   263 po/Makefile.in
   264 test/Makefile
   265 ])
   266 AS_MKDIR_P(test/sh4)
   268 dnl ------------------------- Print out a summary ----------------------
   270 echo
   271 echo "Configuration complete"
   272 echo
   274 if test "x$HAVE_GTK" = x; then
   275   if test "x$HAVE_COCOA" = x; then
   276      echo "  User interface: none"
   277   else
   278      echo "  User interface: Cocoa"
   279   fi
   280 else
   281   echo "  User interface: GTK"
   282 fi
   284 if test "x$SH4_TRANSLATOR" = "x"; then
   285   echo "  SH4 translator: None (emulation core only)"
   286 else
   287   echo "  SH4 translator: $SH4_TRANSLATOR"
   288 fi
   290 if test "x$VIDEO_DRIVERS" = "x"; then
   291    echo "  Video drivers: none (no supported GL found)"
   292 else
   293    echo "  Video drivers: $VIDEO_DRIVERS"
   294 fi
   296 if test "x$AUDIO_DRIVERS" = "x"; then
   297    echo "  Audio drivers: none (no supported output devices found)"
   298 else
   299    echo "  Audio drivers: $AUDIO_DRIVERS"
   300 fi
   302 if test "x$CDROM_DRIVER" = "x"; then
   303    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   304 else
   305    echo "  CD-ROM driver: $CDROM_DRIVER"
   306 fi
.