Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 720:b5594d1ac80a
prev714:009591ac251e
next734:f8fcc8322b45
author nkeynes
date Sat Jul 05 11:57:36 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Get OS X cdrom driver to the 'sort of working' stage. Hide most of the IOKit
fun in a separate osx_iokit module.
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( trace, 
    23    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    24    [if test "$enableval" == "yes"; then
    25      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    26     fi] )
    27 AC_ARG_ENABLE( watch,
    28    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    29    [if test "$enableval" == "yes"; then
    30      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    31    fi] )
    32 AC_ARG_ENABLE( sh4stats,
    33    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    34    [if test "$enableval" == "yes"; then
    35      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    36     fi] )
    37 AC_ARG_WITH( osmesa,
    38    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    39    [], [with_osmesa=no])
    40 AC_ARG_WITH( gtk,
    41    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    42 AC_ARG_WITH( esd,
    43    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
    44 AC_ARG_WITH( pulse,
    45    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
    47 dnl ------------ Check if we're building on Darwin --------------
    49 dnl For starters, do we have a working objective-c compiler?
    50 lxdream_save_cppflags="$CPPFLAGS"
    51 CPPFLAGS="$CPPFLAGS -x objective-c"
    52 AC_TRY_COMPILE([@interface Foo @end],, [
    54    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    55       HAVE_COCOA='yes'
    56       APPLE_BUILD='yes'
    57       LIBS="$LIBS -framework AppKit"
    58       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    59       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    60       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    61       if test "x$with_gtk" = "xx11"; then
    62         with_gtk=no
    63       fi
    64    ])
    66 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    67 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    69 dnl ----------- Check for mandatory dependencies --------------
    70 dnl Check for libpng (required)
    71 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    73 dnl Implied by libpng, but check explicitly just in case
    74 AC_CHECK_LIB(z, uncompress, [], [
    75     echo "Zlib (libz.so) could not be found, but is required."
    76     exit 1])
    78 if test "x$with_gtk" = "xno"; then
    79    dnl Check for GLIB only
    80    PKG_CHECK_MODULES(GLIB, glib-2.0)
    81 else
    82    dnl Check for GTK
    83    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    84        HAVE_GTK='yes'
    85        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    86    ])
    88    dnl Which GTK port do we have?
    89    LIBS="$LIBS $GTK_LIBS"
    90    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    91       HAVE_GTK_X11='yes'
    92       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    93    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    94       HAVE_GTK_OSX='yes'
    95       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    96 fi
    98 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
   100 dnl ------------------ Video driver support -------------------
   101 AS_IF([test "x$with_osmesa" != xno], [ 
   103 dnl User requested OSMesa (ie pure software rendering)
   104   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   105     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   106   AC_CHECK_HEADER([GL/osmesa.h], [],
   107     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   108   HAVE_OSMESA='yes'
   109   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   110   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   112 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   113 dnl taken care of above).
   114    if test "x$APPLE_BUILD" != 'xyes'; then
   115       AC_CHECK_LIB(GL, glVertex3f, [], [
   116           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   117       AC_CHECK_HEADER([GL/gl.h], [], [
   118           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   119    else
   120       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   121          HAVE_NSGL='yes'
   122          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   123          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   124    fi
   126 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   127    if test "x$HAVE_GTK_X11" = "xyes"; then
   128       if test "x$APPLE_BUILD" = "xyes"; then
   129          LIBS="$LIBS -L/usr/X11/lib -lGL"
   130       fi
   131       AC_CHECK_FUNC(glXQueryVersion, [
   132          HAVE_GLX='yes'
   133          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   134          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   135    fi
   137 ])
   141 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   142 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   143 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   145 dnl Check for optional (but highly desireable) OpenGL features
   146 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   147 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   148 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   149 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   152 dnl Check for a supported cpu target for translation purposes
   153 case $host_cpu in
   154     i386|i486|i586|i686|x86_64)
   155 	SH4_TRANSLATOR="x86"
   156         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   157 esac
   158 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   159 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   161 dnl ------------------ Optional driver support -------------------
   162 dnl Check for Apple CoreAudio
   163 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   164      HAVE_CORE_AUDIO=yes
   165      LIBS="$LIBS -framework CoreAudio"
   166      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   167      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   168 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   170 dnl Check for pulseaudio
   171 if test "x$with_pulse" != "xno"; then
   172    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   173        HAVE_PULSE='yes'
   174        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   175        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) 
   176    ], [
   177        if test "x$with_pulse" = "xyes"; then
   178           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
   179        fi
   180    ])
   181 fi
   182 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   184 dnl Check for esound
   185 if test "x$with_esd" != "xno"; then
   186    PKG_CHECK_MODULES(ESOUND, [esound], [ 
   187        HAVE_ESOUND='yes'
   188        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   189        AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) 
   190    ], [
   191        if test "x$with_esd" = "xyes"; then
   192           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
   193        fi
   194    ])
   195 fi
   196 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   198 dnl Check for alsa support
   199 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   200      HAVE_ALSA='yes'
   201      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   202      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   203 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   206 dnl Check for native cdrom support. There can be only one.
   207 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
   208 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
   209      CDROM_DRIVER=osx
   210      LIBS="$LIBS -framework IOKit"],[true])
   211 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
   212 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
   213 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
   215 AC_CHECK_HEADER([linux/joystick.h], [
   216     HAVE_LINUX_JOYSTICK_H=yes
   217     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   218   [ echo "Linux Joystick support not found, building without it."] )
   219 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   221 dnl Check for cross-compiler availability - needed for system tests
   222 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   223 AC_PATH_PROG(SHLD, [sh-elf-ld])
   224 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   225 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   226 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   227 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   229 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   230   BUILD_SH="no"
   231   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   232 else
   233   BUILD_SH="yes"
   234 fi
   235 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   236   BUILD_ARM="no"
   237   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   238 else
   239   BUILD_ARM="yes"
   240 fi
   241 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   242 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   245 dnl ----------------------- All done, finish up -----------------------
   246 GETTEXT_PACKAGE=lxdream
   247 AC_SUBST(GETTEXT_PACKAGE)
   248 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   250 dnl Add the languages which your application supports here.
   251 ALL_LINGUAS="de es it pt_BR"
   252 AM_GLIB_GNU_GETTEXT
   254 AC_OUTPUT([
   255 Makefile
   256 src/Makefile
   257 po/Makefile.in
   258 test/Makefile
   259 ])
   261 dnl ------------------------- Print out a summary ----------------------
   263 echo
   264 echo "Configuration complete"
   265 echo
   267 if test "x$HAVE_GTK" = x; then
   268   if test "x$HAVE_COCOA" = x; then
   269      echo "  User interface: none"
   270   else
   271      echo "  User interface: Cocoa"
   272   fi
   273 else
   274   echo "  User interface: GTK"
   275 fi
   277 if test "x$SH4_TRANSLATOR" = "x"; then
   278   echo "  SH4 translator: None (emulation core only)"
   279 else
   280   echo "  SH4 translator: $SH4_TRANSLATOR"
   281 fi
   283 if test "x$VIDEO_DRIVERS" = "x"; then
   284    echo "  Video drivers: none (no supported GL found)"
   285 else
   286    echo "  Video drivers: $VIDEO_DRIVERS"
   287 fi
   289 if test "x$AUDIO_DRIVERS" = "x"; then
   290    echo "  Audio drivers: none (no supported output devices found)"
   291 else
   292    echo "  Audio drivers: $AUDIO_DRIVERS"
   293 fi
   295 if test "x$CDROM_DRIVER" = "x"; then
   296    echo "  CD-ROM driver: none (no supported cd-rom devices found)"
   297 else
   298    echo "  CD-ROM driver: $CDROM_DRIVER"
   299 fi
.