Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 675:b97020f9af1c
prev671:a530ea88eebd
next681:1755a126b109
author nkeynes
date Mon May 26 11:01:42 2008 +0000 (12 years ago)
permissions -rw-r--r--
last change hange 64-bit configuration to use sizeof(void *) rather than the system id
returned by config.guess - config.guess gets it wrong in some situations.
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    16 AC_ARG_ENABLE( trace, 
    17    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    18    [if test "$enableval" == "yes"; then
    19      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    20     fi] )
    21 AC_ARG_ENABLE( watch,
    22    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    23    [if test "$enableval" == "yes"; then
    24      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    25    fi] )
    26 AC_ARG_ENABLE( sh4stats,
    27    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    28    [if test "$enableval" == "yes"; then
    29      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    30     fi] )
    31 AC_ARG_WITH( osmesa,
    32    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    33    [], [with_osmesa=no])
    36 dnl ------------ Check if we're building on Darwn --------------
    38 dnl For starters, do we have a working objective-c compiler?
    39 lxdream_save_cppflags="$CPPFLAGS"
    40 CPPFLAGS="$CPPFLAGS -x objective-c"
    41 AC_TRY_COMPILE([@interface Foo @end],, [
    43    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    44       HAVE_COCOA='yes'
    45       APPLE_BUILD='yes'
    46       LIBS="$LIBS -framework AppKit"
    47       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    48       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    49       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    50    ])
    52 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    53 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes'])
    55 dnl ----------- Check for mandatory dependencies --------------
    56 dnl Check for libpng (required)
    57 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    59 dnl Implied by libpng, but check explicitly just in case
    60 AC_CHECK_LIB(z, uncompress, [], [
    61     echo "Zlib (libz.so) could not be found, but is required."
    62     exit 1])
    65 dnl Check for GTK (currently compulsory)
    66 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    67     HAVE_GTK='yes'
    68     AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    69 ])
    70 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    72 dnl Which GTK port do we have?
    73 LIBS="$LIBS $GTK_LIBS"
    74 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    75    HAVE_GTK_X11='yes'
    76    AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    77 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    78    HAVE_GTK_OSX='yes'
    79    AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    81 dnl ------------------ Video driver support -------------------
    82 AS_IF([test "x$with_osmesa" != xno], [ 
    84 dnl User requested OSMesa (ie pure software rendering)
    85   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
    86     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
    87   AC_CHECK_HEADER([GL/osmesa.h], [],
    88     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
    89   HAVE_OSMESA='yes'
    90   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
    92 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
    93 dnl taken care of above).
    94    if test "x$APPLE_BUILD" != 'xyes'; then
    95       AC_CHECK_LIB(GL, glVertex3f, [], [
    96           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
    97       AC_CHECK_HEADER([GL/gl.h], [], [
    98           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
    99    fi
   101 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   102    if test "x$HAVE_GTK_X11" = "xyes"; then
   103       if test "x$APPLE_BUILD" = "xyes"; then
   104          LIBS="$LIBS -L/usr/X11/lib -lGL"
   105       fi
   106       AC_CHECK_FUNC(glXQueryVersion, [
   107          HAVE_GLX='yes'
   108          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   109    elif test "x$HAVE_GTK_OSX" = "xyes"; then
   110       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   111          HAVE_NSGL='yes'
   112          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   113    fi
   115 ])
   118 dnl OK, now decide which video driver(s) we can build
   119 if test "x$HAVE_OSMESA" = "x" -a "x$HAVE_GLX" = "x" -a "x$HAVE_NSGL" = "x"; then
   120    echo "Warning: Building with no video support"
   121 fi
   123 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   124 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   125 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   127 dnl Check for optional (but highly desireable) OpenGL features
   128 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   129 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   130 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   133 dnl Check for a supported cpu target for translation purposes
   134 case $host_cpu in
   135     i386|i486|i586|i686|x86_64)
   136 	SH4_TRANSLATOR="x86"
   137         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   138     *)
   139 	echo "Warning: No translator available for $host. Building emulation core only";;
   140 esac
   141 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   142 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   144 dnl ------------------ Optional driver support -------------------
   145 dnl Check for pulseaudio
   146 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   147      HAVE_PULSE='yes'
   148      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
   149 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   151 dnl Check for esound
   152 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   153      HAVE_ESOUND='yes'
   154      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   155 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   157 dnl Check for alsa support
   158 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   159      HAVE_ALSA='yes'
   160      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   161 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   163 if test "x$HAVE_ESOUND" = "x" -a "x$HAVE_ALSA" = "x" -a "x$HAVE_PULSE" = "x"; then
   164    echo "Warning: Building without audio support"
   165 fi
   167 dnl Check for linux cdrom device support
   168 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   169     echo "Linux CDROM support not found, building without it."]  )
   170 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   172 AC_CHECK_HEADER([linux/joystick.h], [
   173     HAVE_LINUX_JOYSTICK_H=yes
   174     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   175   [ echo "Linux Joystick support not found, building without it."] )
   176 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   178 dnl Check for cross-compiler availability - needed for system tests
   179 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   180 AC_PATH_PROG(SHLD, [sh-elf-ld])
   181 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   182 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   183 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   184 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   186 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   187   BUILD_SH="no"
   188   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   189 else
   190   BUILD_SH="yes"
   191 fi
   192 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   193   BUILD_ARM="no"
   194   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   195 else
   196   BUILD_ARM="yes"
   197 fi
   198 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   199 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   202 dnl ----------------------- All done, finish up -----------------------
   203 GETTEXT_PACKAGE=lxdream
   204 AC_SUBST(GETTEXT_PACKAGE)
   205 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   207 dnl Add the languages which your application supports here.
   208 ALL_LINGUAS="de es it pt_BR"
   209 AM_GLIB_GNU_GETTEXT
   211 AC_OUTPUT([
   212 Makefile
   213 src/Makefile
   214 po/Makefile.in
   215 test/Makefile
   216 ])
.