Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 657:c4143facbfcb
prev656:031d23fa6d0b
next658:f5926310bfbe
author nkeynes
date Wed Apr 16 10:12:12 2008 +0000 (12 years ago)
permissions -rw-r--r--
last change Add support for the pulseaudio sound system
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_HEADER_STDC
    13 AC_CANONICAL_BUILD
    14 AC_CANONICAL_HOST
    15 AC_ARG_ENABLE( trace, 
    16    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    17    [if test "$enableval" == "yes"; then
    18      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    19     fi] )
    20 AC_ARG_ENABLE( watch,
    21    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    22    [if test "$enableval" == "yes"; then
    23      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    24    fi] )
    25 AC_ARG_WITH( osmesa,
    26    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    27    [], [with_osmesa=no])
    29 AS_IF([test "x$with_osmesa" != xno], [ 
    30   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
    31     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
    32   AC_CHECK_HEADER([GL/osmesa.h], [],
    33     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
    34   ])
    35 AM_CONDITIONAL(OSMESA_DRIVER, [test "x$with_osmesa" != xno])
    37 dnl ----------- Check for mandatory dependencies --------------
    38 dnl Building on MAC?
    39 AC_CHECK_HEADER([Carbon/Carbon.h], [
    40    HAVE_CARBON='yes'
    41    APPLE_BUILD='yes'
    42    LIBS="$LIBS -framework OpenGL -framework AGL -framework Carbon -L/usr/X11R6/lib -lGL"
    43    AC_DEFINE(HAVE_CARBON,[1],[Have Carbon framework])
    44    AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    45 ])
    47 dnl Check for libpng (required)
    48 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    50 dnl Implied by libpng, but check explicitly just in case
    51 AC_CHECK_LIB(z, uncompress, [], [
    52     echo "Zlib (libz.so) could not be found, but is required."
    53     exit 1])
    55 if test "$APPLE_BUILD" != 'yes'; then
    56 if test "x$with_osmesa" == "xno"; then
    57 AC_CHECK_LIB(GL, glXQueryVersion, [], [
    58     echo "The OpenGL library (libGL.so) could not be found, but is required."
    59     exit 1])
    60 AC_CHECK_HEADER([GL/gl.h], [], [
    61     echo "The OpenGL header files (eg GL/gl.h) could not be found, but are required."
    62     exit 1])
    63 fi
    64 fi
    66 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
    67 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
    68 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
    70 dnl Check for GTK (required for unix systems)
    71 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    72     HAVE_GTK='yes'
    73     AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    74 ])
    76 AM_CONDITIONAL(GUI_CARBON, [test "$HAVE_CARBON" = 'yes'])
    77 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    79 dnl Check for a supported cpu target for translation purposes
    80 case $host_cpu in
    81     i386|i486|i586|i686)
    82 	SH4_TRANSLATOR="x86"
    83         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
    84     x86_64)
    85 	SH4_TRANSLATOR="x86_64"
    86         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86_64], [SH4 Translator to use (if any)] );;
    87     *)
    88 	echo "Warning: No translator available for $host. Building emulation core only";;
    89 esac
    90 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
    91 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
    93 dnl ------------------ Optional driver support -------------------
    94 dnl Check for pulseaudio
    95 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
    96      HAVE_PULSE='yes'
    97      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
    98 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   100 dnl Check for esound
   101 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   102      HAVE_ESOUND='yes'
   103      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   104 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   106 dnl Check for alsa support
   107 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   108      HAVE_ALSA='yes'
   109      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   110 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   112 if test "x$HAVE_ESOUND" = "x" -a "x$HAVE_ALSA" = "x" -a "x$HAVE_PULSE" = "x"; then
   113    echo "Warning: Building without audio support"
   114 fi
   116 dnl Check for linux cdrom device support
   117 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   118     echo "Linux CDROM support not found, building without it."]  )
   119 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   122 AC_CHECK_HEADER([linux/joystick.h], [
   123     HAVE_LINUX_JOYSTICK_H=yes
   124     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   125   [ echo "Linux Joystick support not found, building without it."] )
   126 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   128 dnl Check for cross-compiler availability - needed for system tests
   129 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   130 AC_PATH_PROG(SHLD, [sh-elf-ld])
   131 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   132 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   133 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   134 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   136 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   137   BUILD_SH="no"
   138   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   139 else
   140   BUILD_SH="yes"
   141 fi
   142 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   143   BUILD_ARM="no"
   144   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   145 else
   146   BUILD_ARM="yes"
   147 fi
   148 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   149 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   152 dnl ----------------------- All done, finish up -----------------------
   153 GETTEXT_PACKAGE=lxdream
   154 AC_SUBST(GETTEXT_PACKAGE)
   155 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   157 dnl Add the languages which your application supports here.
   158 ALL_LINGUAS="de pt_BR"
   159 AM_GLIB_GNU_GETTEXT
   161 AC_OUTPUT([
   162 Makefile
   163 src/Makefile
   164 po/Makefile.in
   165 test/Makefile
   166 ])
.