filename | configure.in |
changeset | 1226:227ceb186ba7 |
prev | 1225:73dd41cb37a8 |
next | 1228:8168aa94e6d7 |
author | nkeynes |
date | Thu Feb 23 14:59:58 2012 +1000 (12 years ago) |
permissions | -rw-r--r-- |
last change | mem_stream_class should be static (to avoid potential conflicts with the real one) |
view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_CANONICAL_BUILD
9 AC_CANONICAL_HOST
11 m4_include([m4/ccforbuild.m4])
13 AC_ISC_POSIX
14 AC_PROG_CC
15 AM_PROG_CC_STDC
16 AC_PROG_CC_FOR_BUILD
17 AC_PROG_OBJC
18 AC_PROG_SED
19 AM_PROG_AS
20 AC_PROG_RANLIB
21 AC_CHECK_SIZEOF([void *])
22 AC_HEADER_STDC
24 _AM_DEPENDENCIES([OBJC])
26 AC_PATH_PROG(POD2MAN, [pod2man])
27 AC_PATH_PROG(POD2HTML, [pod2html])
29 dnl ---------------- enable/with flags ------------------
31 AC_ARG_ENABLE( strict-warn,
32 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
33 [if test "$enableval" == "yes"; then
34 enable_strictwarn=yes
35 fi] )
36 AC_ARG_ENABLE( translator,
37 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
38 [true], [enable_translator=yes] )
39 AC_ARG_ENABLE( optimized,
40 AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
41 [true], [enable_optimized=yes] )
42 AC_ARG_ENABLE( shared,
43 AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
44 [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
45 AC_ARG_ENABLE( profiled,
46 AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
47 [if test "$enableval" == "yes"; then
48 enable_profiled=yes;
49 fi] )
50 AC_ARG_ENABLE( trace,
51 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
52 [if test "$enableval" == "yes"; then
53 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
54 fi] )
55 AC_ARG_ENABLE( watch,
56 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
57 [if test "$enableval" == "yes"; then
58 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
59 fi] )
60 AC_ARG_ENABLE( sh4stats,
61 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
62 [if test "$enableval" == "yes"; then
63 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
64 fi] )
65 AC_ARG_WITH( osmesa,
66 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
67 [], [with_osmesa=no])
68 AC_ARG_WITH( gtk,
69 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
70 AC_ARG_WITH( esd,
71 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
72 AC_ARG_WITH( pulse,
73 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
74 AC_ARG_WITH( sdl,
75 AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
78 dnl ------------ Check if we're building on Darwin --------------
80 dnl For starters, do we have a working objective-c compiler?
81 AC_HAVE_OBJC([
82 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
83 HAVE_COCOA='yes'
84 APPLE_BUILD='yes'
85 LIBS="$LIBS -framework AppKit -framework Carbon"
86 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
87 LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
88 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
89 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
90 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
91 if test "x$with_gtk" = "xx11"; then
92 with_gtk=no
93 fi
94 ], [], [AC_INCLUDES_DEFAULT])
96 AC_OBJC_VERSION([ OBJCOPT="-O2"
97 OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
98 [ OBJCOPT="-O2" ], [] )
99 AC_CHECK_OBJCFLAG([-msse2])
100 AC_CHECK_OBJCFLAG([-mfpmath=sse])
101 ])
103 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
104 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
105 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
106 fi
108 dnl ------------------ C Compiler flags -----------------------
109 CFLAGS_FOR_BUILD="-O2 -std=c99"
110 CFLAGS="-g -fexceptions"
111 OBJCFLAGS="-g -fexceptions"
112 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
114 STDCFLAG="-std=c99"
115 AC_CC_VERSION([ CCOPT="-O2"
116 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
117 [ CCOPT="$CFLAGS -fast"
118 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
119 [ CCOPT="$CFLAGS -O2" ])
120 AC_CHECK_CFLAG([-msse2])
121 AC_CHECK_CFLAG([-mfpmath=sse])
123 if test "x$enable_optimized" = "xyes"; then
124 CFLAGS="$CFLAGS $CCOPT"
125 OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
126 if test "x$enable_profiled" != "xyes"; then
127 dnl -fomit-frame-pointer can't be used with -pg
128 CFLAGS="$CFLAGS -fomit-frame-pointer"
129 OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
130 fi
131 else
132 CFLAGS="$CFLAGS -g3"
133 OBJCFLAGS="$OBJCFLAGS -g3"
134 fi
136 if test "x$enable_profiled" = "xyes"; then
137 CFLAGS="$CFLAGS -pg"
138 LDFLAGS="$LDFLAGS -pg";
139 OBJCFLAGS="$OBJCFLAGS -pg";
140 fi
142 if test "x$enable_strictwarn" = "xyes"; then
143 CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
144 OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
145 fi
147 if test "x$enable_shared" != "xno"; then
148 if test "x$APPLE_BUILD" = "xyes"; then
149 SOEXT="dylib"
150 PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
151 else
152 SOEXT="so"
153 PLUGINLDFLAGS="-shared"
154 fi
155 PLUGINCFLAGS="-fPIC"
157 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
158 AC_CHECK_HEADER( [dlfcn.h], [
159 AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
160 if test "x$have_dlopen" != "xyes"; then
161 if test "x$enable_shared" == "xyes"; then
162 AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
163 else
164 AC_MSG_WARN("Statically linking all plugins")
165 fi
166 fi
168 dnl Check if linker accepts -rdynamic
169 AC_MSG_CHECKING([if linker accepts -rdynamic])
170 old_LDFLAGS="$LDFLAGS"
171 LDFLAGS="$LDFLAGS -rdynamic"
172 AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
173 LXDREAMLDFLAGS="-rdynamic"
174 AC_MSG_RESULT([yes])
175 ], [
176 LXDREAMLDFLAGS=""
177 AC_MSG_RESULT([no]) ])
178 LDFLAGS="$old_LDFLAGS"
180 AC_SUBST(SOEXT)
181 AC_SUBST(PLUGINCFLAGS)
182 AC_SUBST(PLUGINLDFLAGS)
183 AC_SUBST(LXDREAMLDFLAGS)
184 fi
185 if test "x$have_dlopen" = "xyes"; then
186 AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])
187 fi
188 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes"])
190 AC_CHECK_FASTCALL([
191 AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
192 ])
193 AC_CHECK_FORCEINLINE()
194 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
195 AC_CHECK_FRAME_ADDRESS( [
196 AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
197 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
199 AC_SUBST(LXDREAMCPPFLAGS)
200 AC_SEARCH_LIBS(listen, [socket])
201 AC_SEARCH_LIBS(inet_ntoa,[nsl])
203 dnl ----------- Check for mandatory dependencies --------------
204 dnl Check for libpng (required)
205 PKG_CHECK_MODULES(LIBPNG, [libpng] )
207 dnl Implied by libpng, but check explicitly just in case
208 AC_CHECK_LIB(z, uncompress, [], [
209 echo "Zlib (libz.so) could not be found, but is required."
210 exit 1])
212 if test "x$with_gtk" = "xno"; then
213 dnl Check for GLIB only
214 PKG_CHECK_MODULES(GLIB, glib-2.0)
215 else
216 dnl Check for GTK
217 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
218 HAVE_GTK='yes'
219 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
220 ])
222 dnl Which GTK port do we have?
223 LIBS="$LIBS $GTK_LIBS"
224 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
225 HAVE_GTK_X11='yes'
226 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
227 dnl Add -lX11 explicitly as some pkg-configs get it wrong
228 GTK_LIBS="$GTK_LIBS -lX11"
229 LIBS="$LIBS -lX11"
230 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
231 HAVE_GTK_OSX='yes'
232 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
233 if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
234 AC_MSG_FAILURE( [Unable to identify GTK platform] )
235 fi
236 fi
238 AC_PUSH_CC_FOR_BUILD
239 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)
240 AC_POP_CC_FOR_BUILD
242 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
244 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
245 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
246 dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
247 dnl LIBS="$LIBS -lisofs"
248 dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])],
249 dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
251 dnl ------------------ Video driver support -------------------
252 AS_IF([test "x$with_osmesa" != xno], [
254 dnl User requested OSMesa (ie pure software rendering)
255 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
256 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
257 AC_CHECK_HEADER([GL/osmesa.h], [],
258 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
259 HAVE_OSMESA='yes'
260 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
261 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
263 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
264 dnl taken care of above).
265 if test "x$APPLE_BUILD" != 'xyes'; then
266 PKG_CHECK_MODULES(LIBGL, [gl] )
267 dnl AC_CHECK_LIB(GL, glVertex3f, [], [
268 dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
269 dnl AC_CHECK_HEADER([GL/gl.h], [], [
270 dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
271 LIBS="$LIBS $LIBGL_LIBS";
272 CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
273 else
274 AC_CHECK_FUNC(NSOpenGLGetVersion, [
275 HAVE_NSGL='yes'
276 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
277 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
278 fi
280 dnl Now work out how to get from the UI to GL - this is usually the painful part.
281 if test "x$HAVE_GTK_X11" = "xyes"; then
282 if test "x$APPLE_BUILD" = "xyes"; then
283 LIBS="$LIBS -L/usr/X11/lib -lGL"
284 fi
285 AC_CHECK_FUNC(glXQueryVersion, [
286 HAVE_GLX='yes'
287 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
288 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
289 fi
291 ])
295 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
296 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
297 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
299 dnl Check for optional (but highly desireable) OpenGL features
300 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
301 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
302 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
303 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
304 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
305 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])
306 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident]) ], [])
307 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.
312 dnl ------------------- SH4 translator target -------------------
314 if test "x$enable_translator" != "xno"; then
315 case $host_cpu in
316 i386|i486|i586|i686|x86_64)
317 SH4_TRANSLATOR="x86"
318 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
319 esac
320 fi
321 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
323 dnl ------------------ Optional driver support -------------------
324 dnl Check for Apple CoreAudio
325 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
326 HAVE_CORE_AUDIO=yes
327 LIBS="$LIBS -framework CoreAudio"
328 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
329 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
330 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
332 dnl Check for SDL (only used for audio at the moment)
333 if test "x$with_sdl" != "xno"; then
334 PKG_CHECK_MODULES(SDL, [sdl], [
335 HAVE_SDL='yes'
336 AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
337 AC_DEFINE([HAVE_SDL],1,[Have SDL support])
338 ], [
339 if test "x$with_sdl" = "xyes"; then
340 AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
341 fi
342 ])
343 fi
344 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
346 dnl Check for pulseaudio
347 if test "x$with_pulse" != "xno"; then
348 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
349 HAVE_PULSE='yes'
350 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
351 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
352 ], [
353 if test "x$with_pulse" = "xyes"; then
354 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
355 fi
356 ])
357 fi
358 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
360 dnl Check for esound
361 if test "x$with_esd" != "xno"; then
362 PKG_CHECK_MODULES(ESOUND, [esound], [
363 HAVE_ESOUND='yes'
364 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
365 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
366 ], [
367 if test "x$with_esd" = "xyes"; then
368 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
369 fi
370 ])
371 fi
372 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
374 dnl Check for alsa support
375 PKG_CHECK_MODULES(ALSA, [alsa], [
376 HAVE_ALSA='yes'
377 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
378 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
379 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
382 dnl Check for native cdrom support. There can be only one.
383 AC_CHECK_HEADER([linux/cdrom.h], [
384 CDROM_DRIVER=linux
385 dnl Some kernel versions have non-c99 compliant headers - check here
386 AC_MSG_CHECKING([C99 compliant kernel headers])
387 old_CFLAGS="$CFLAGS"
388 CFLAGS="$CFLAGS $STDCFLAG"
389 AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
390 AC_MSG_RESULT([No])
391 STDCFLAG="-std=gnu99"])
392 CFLAGS="$old_CFLAGS"
393 ], [true])
394 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
395 CDROM_DRIVER=osx
396 LIBS="$LIBS -framework IOKit"],[true])
397 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
398 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
399 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
400 if test "x$CDROM_DRIVER" = "xlinux"; then
401 AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
402 fi
404 AC_CHECK_HEADER([linux/joystick.h], [
405 HAVE_LINUX_JOYSTICK_H=yes
406 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support])
407 INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ],
408 [ echo "Linux Joystick support not found, building without it."] )
409 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
411 dnl Check for LIRC
412 if test "x$with_lirc" != "xno"; then
413 AC_CHECK_HEADER([lirc/lirc_client.h], [
414 HAVE_LIRC_CLIENT_H=yes
415 AC_DEFINE([HAVE_LIRC],1,[Have LIRC support])
416 INPUT_DRIVERS="$INPUT_DRIVERS lirc"
417 ],
418 [ echo "LIRC support not found, building without it." ] )
419 fi
420 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
422 dnl Check for cross-compiler availability - needed for system tests
423 AC_PATH_PROG(SHCC, [sh-elf-gcc])
424 AC_PATH_PROG(SHLD, [sh-elf-ld])
425 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
426 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
427 AC_PATH_PROG(ARMLD, [arm-elf-ld])
428 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
430 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
431 BUILD_SH="no"
432 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
433 else
434 BUILD_SH="yes"
435 fi
436 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
437 BUILD_ARM="no"
438 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
439 else
440 BUILD_ARM="yes"
441 fi
442 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
443 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
445 CFLAGS="$CFLAGS $STDCFLAG"
447 dnl ----------------------- All done, finish up -----------------------
448 GETTEXT_PACKAGE=lxdream
449 LXDREAM_LIBS="$LIBS"
450 LIBS=""
451 AC_SUBST(LXDREAM_LIBS)
452 AC_SUBST(GETTEXT_PACKAGE)
453 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
455 dnl Add the languages which your application supports here.
456 ALL_LINGUAS="de es it nl pt_BR"
457 AM_GLIB_GNU_GETTEXT
459 AC_OUTPUT([
460 Makefile
461 src/Makefile
462 src/tools/Makefile
463 po/Makefile.in
464 test/Makefile
465 Info.plist
466 ])
467 AS_MKDIR_P(test/sh4)
469 dnl ------------------------- Print out a summary ----------------------
471 echo
472 echo "Configuration complete"
473 echo
475 if test "x$HAVE_GTK" = x; then
476 if test "x$HAVE_COCOA" = x; then
477 echo " User interface: none"
478 else
479 echo " User interface: Cocoa"
480 fi
481 else
482 echo " User interface: GTK"
483 fi
485 if test "x$SH4_TRANSLATOR" = "x"; then
486 echo " SH4 translator: None (emulation core only)"
487 else
488 echo " SH4 translator: $SH4_TRANSLATOR"
489 fi
491 if test "x$VIDEO_DRIVERS" = "x"; then
492 echo " Video drivers: none (no supported GL found)"
493 else
494 echo " Video drivers: $VIDEO_DRIVERS"
495 fi
497 if test "x$AUDIO_DRIVERS" = "x"; then
498 echo " Audio drivers: none (no supported output devices found)"
499 else
500 echo " Audio drivers: $AUDIO_DRIVERS"
501 fi
503 if test "x$INPUT_DRIVERS" = "x"; then
504 echo " Input drivers: none (no supported input devices found)"
505 else
506 echo " Input drivers: $INPUT_DRIVERS"
507 fi
509 if test "x$CDROM_DRIVER" = "x"; then
510 echo " CD-ROM driver: none (no supported cd-rom devices found)"
511 else
512 echo " CD-ROM driver: $CDROM_DRIVER"
513 fi
.