Search
lxdream.org :: lxdream/configure.in
lxdream 0.9.1
released Jun 29
Download Now
filename configure.in
changeset 702:d39fc81e9630
prev700:4650d0c7f6f9
next704:2c1d6f8e69e7
author nkeynes
date Sun Jun 22 08:59:39 2008 +0000 (11 years ago)
permissions -rw-r--r--
last change Add a tidy summary at the end of the configure script
view annotate diff log raw
     1 dnl Process this file with autoconf to produce a configure script.
     3 AC_INIT(configure.in)
     4 AM_INIT_AUTOMAKE(lxdream, 0.8.1)
     5 AM_MAINTAINER_MODE
     6 AM_CONFIG_HEADER(config.h)
     8 AC_ISC_POSIX
     9 AC_PROG_CC
    10 AM_PROG_CC_STDC
    11 AM_PROG_AS
    12 AC_CHECK_SIZEOF([void *])
    13 AC_HEADER_STDC
    14 AC_CANONICAL_BUILD
    15 AC_CANONICAL_HOST
    17 AC_PATH_PROG(POD2MAN, [pod2man])
    18 AC_PATH_PROG(POD2HTML, [pod2html])
    20 dnl ---------------- enable/with flags ------------------
    22 AC_ARG_ENABLE( trace, 
    23    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
    24    [if test "$enableval" == "yes"; then
    25      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
    26     fi] )
    27 AC_ARG_ENABLE( watch,
    28    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
    29    [if test "$enableval" == "yes"; then
    30      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
    31    fi] )
    32 AC_ARG_ENABLE( sh4stats,
    33    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
    34    [if test "$enableval" == "yes"; then
    35      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
    36     fi] )
    37 AC_ARG_WITH( osmesa,
    38    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
    39    [], [with_osmesa=no])
    40 AC_ARG_WITH( gtk,
    41    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
    43 dnl ------------ Check if we're building on Darwin --------------
    45 dnl For starters, do we have a working objective-c compiler?
    46 lxdream_save_cppflags="$CPPFLAGS"
    47 CPPFLAGS="$CPPFLAGS -x objective-c"
    48 AC_TRY_COMPILE([@interface Foo @end],, [
    50    AC_CHECK_HEADER([Cocoa/Cocoa.h], [
    51       HAVE_COCOA='yes'
    52       APPLE_BUILD='yes'
    53       LIBS="$LIBS -framework AppKit"
    54       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
    55       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
    56       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
    57    ])
    59    if test "x$with_gtk" = "xx11"; then
    60       with_gtk=no
    61    fi
    63 ], [CPPFLAGS="$lxdream_save_cppflags"] )
    64 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
    66 dnl ----------- Check for mandatory dependencies --------------
    67 dnl Check for libpng (required)
    68 PKG_CHECK_MODULES(LIBPNG, [libpng] )
    70 dnl Implied by libpng, but check explicitly just in case
    71 AC_CHECK_LIB(z, uncompress, [], [
    72     echo "Zlib (libz.so) could not be found, but is required."
    73     exit 1])
    75 if test "x$with_gtk" = "xno"; then
    76    dnl Check for GLIB only
    77    PKG_CHECK_MODULES(GLIB, glib-2.0)
    78 else
    79    dnl Check for GTK
    80    PKG_CHECK_MODULES(GTK, gtk+-2.0, [
    81        HAVE_GTK='yes'
    82        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
    83    ])
    85    dnl Which GTK port do we have?
    86    LIBS="$LIBS $GTK_LIBS"
    87    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [ 
    88       HAVE_GTK_X11='yes'
    89       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
    90    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [ 
    91       HAVE_GTK_OSX='yes'
    92       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
    93 fi
    95 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
    97 dnl ------------------ Video driver support -------------------
    98 AS_IF([test "x$with_osmesa" != xno], [ 
   100 dnl User requested OSMesa (ie pure software rendering)
   101   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
   102     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
   103   AC_CHECK_HEADER([GL/osmesa.h], [],
   104     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
   105   HAVE_OSMESA='yes'
   106   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
   107   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
   109 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
   110 dnl taken care of above).
   111    if test "x$APPLE_BUILD" != 'xyes'; then
   112       AC_CHECK_LIB(GL, glVertex3f, [], [
   113           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
   114       AC_CHECK_HEADER([GL/gl.h], [], [
   115           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
   116    else
   117       AC_CHECK_FUNC(NSOpenGLGetVersion, [
   118          HAVE_NSGL='yes'
   119          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
   120          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
   121    fi
   123 dnl Now work out how to get from the UI to GL - this is usually the painful part.
   124    if test "x$HAVE_GTK_X11" = "xyes"; then
   125       if test "x$APPLE_BUILD" = "xyes"; then
   126          LIBS="$LIBS -L/usr/X11/lib -lGL"
   127       fi
   128       AC_CHECK_FUNC(glXQueryVersion, [
   129          HAVE_GLX='yes'
   130          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
   131          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
   132    fi
   134 ])
   138 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
   139 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
   140 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
   142 dnl Check for optional (but highly desireable) OpenGL features
   143 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
   144 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
   145 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
   146 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
   149 dnl Check for a supported cpu target for translation purposes
   150 case $host_cpu in
   151     i386|i486|i586|i686|x86_64)
   152 	SH4_TRANSLATOR="x86"
   153         AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
   154 esac
   155 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86" -o "$SH4_TRANSLATOR" = "x86_64"])
   156 AM_CONDITIONAL(BUILD_X86_64, [test "$SH4_TRANSLATOR" = "x86_64"])
   158 dnl ------------------ Optional driver support -------------------
   159 dnl Check for Apple CoreAudio
   160 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
   161      HAVE_CORE_AUDIO=yes
   162      LIBS="$LIBS -framework CoreAudio"
   163      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
   164      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
   165 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
   167 dnl Check for pulseaudio
   168 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
   169      HAVE_PULSE='yes'
   170      AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
   171      AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support]) ], [true])
   172 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
   174 dnl Check for esound
   175 PKG_CHECK_MODULES(ESOUND, [esound], [ 
   176      HAVE_ESOUND='yes'
   177      AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
   178      AC_DEFINE([HAVE_ESOUND],1,[Have esound support]) ], [true])
   179 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
   181 dnl Check for alsa support
   182 PKG_CHECK_MODULES(ALSA, [alsa], [ 
   183      HAVE_ALSA='yes'
   184      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
   185      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
   186 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
   189 dnl Check for linux cdrom device support
   190 AC_CHECK_HEADER([linux/cdrom.h], [HAVE_LINUX_CDROM_H=yes], [
   191     echo "Linux CDROM support not found, building without it."]  )
   192 AM_CONDITIONAL(CDROM_LINUX, [test "$HAVE_LINUX_CDROM_H" = "yes"])
   194 AC_CHECK_HEADER([linux/joystick.h], [
   195     HAVE_LINUX_JOYSTICK_H=yes
   196     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ], 
   197   [ echo "Linux Joystick support not found, building without it."] )
   198 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
   200 dnl Check for cross-compiler availability - needed for system tests
   201 AC_PATH_PROG(SHCC, [sh-elf-gcc])
   202 AC_PATH_PROG(SHLD, [sh-elf-ld])
   203 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
   204 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
   205 AC_PATH_PROG(ARMLD, [arm-elf-ld])
   206 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
   208 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
   209   BUILD_SH="no"
   210   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
   211 else
   212   BUILD_SH="yes"
   213 fi
   214 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
   215   BUILD_ARM="no"
   216   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
   217 else
   218   BUILD_ARM="yes"
   219 fi
   220 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
   221 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
   224 dnl ----------------------- All done, finish up -----------------------
   225 GETTEXT_PACKAGE=lxdream
   226 AC_SUBST(GETTEXT_PACKAGE)
   227 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
   229 dnl Add the languages which your application supports here.
   230 ALL_LINGUAS="de es it pt_BR"
   231 AM_GLIB_GNU_GETTEXT
   233 AC_OUTPUT([
   234 Makefile
   235 src/Makefile
   236 po/Makefile.in
   237 test/Makefile
   238 ])
   240 dnl ------------------------- Print out a summary ----------------------
   242 echo
   243 echo "Configuration complete"
   244 echo
   246 if test "x$HAVE_GTK" = x; then
   247   if test "x$HAVE_COCOA" = x; then
   248      echo "  User interface: none"
   249   else
   250      echo "  User interface: Cocoa"
   251   fi
   252 else
   253   echo "  User interface: GTK"
   254 fi
   256 if test "x$SH4_TRANSLATOR" = "x"; then
   257   echo "  SH4 translator: None (emulation core only)"
   258 else
   259   echo "  SH4 translator: $SH4_TRANSLATOR"
   260 fi
   262 if test "x$VIDEO_DRIVERS" = "x"; then
   263    echo "  Video drivers: none (no supported GL found)"
   264 else
   265    echo "  Video drivers: $VIDEO_DRIVERS"
   266 fi
   268 if test "x$AUDIO_DRIVERS" = "x"; then
   269    echo "  Audio drivers: none (no supported output devices found)"
   270 else
   271    echo "  Audio drivers: $AUDIO_DRIVERS"
   272 fi
.