lxdream.org :: lxdream/configure.in r1074:397d77b6e346

filename	configure.in
changeset	1074:397d77b6e346
prev	1066:ddffe9d2b332
next	1097:d4807997e450
author	nkeynes
date	Fri Dec 04 08:44:22 2009 +1000 (14 years ago)
permissions	-rw-r--r--
last change	Add convenience xlat_dump_block for debugger use

view

annotate

diff

log

raw

     1 dnl Process this file with autoconf to produce a configure script.

     3 AC_INIT(configure.in)

     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)

     5 AM_MAINTAINER_MODE

     6 AM_CONFIG_HEADER(config.h)

     8 AC_ISC_POSIX

     9 AC_PROG_CC

    10 AM_PROG_CC_STDC

    11 AC_PROG_OBJC

    12 AC_PROG_SED

    13 AM_PROG_AS

    14 AC_CHECK_SIZEOF([void *])

    15 AC_HEADER_STDC

    16 AC_CANONICAL_BUILD

    17 AC_CANONICAL_HOST

    19 _AM_DEPENDENCIES([OBJC])

    21 AC_PATH_PROG(POD2MAN, [pod2man])

    22 AC_PATH_PROG(POD2HTML, [pod2html])

    24 dnl ---------------- enable/with flags ------------------

    26 AC_ARG_ENABLE( strict-warn,

    27    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),

    28    [if test "$enableval" == "yes"; then

    29       enable_strictwarn=yes

    30     fi] )

    31 AC_ARG_ENABLE( translator,

    32    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),

    33    [true], [enable_translator=yes] )

    34 AC_ARG_ENABLE( optimized,

    35    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),

    36    [true], [enable_optimized=yes] )

    37 AC_ARG_ENABLE( shared,

    38    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),

    39    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )

    40 AC_ARG_ENABLE( profiled,

    41    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),

    42    [if test "$enableval" == "yes"; then

    43       enable_profiled=yes;

    44     fi] )

    45 AC_ARG_ENABLE( trace,

    46    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),

    47    [if test "$enableval" == "yes"; then

    48      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])

    49     fi] )

    50 AC_ARG_ENABLE( watch,

    51    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),

    52    [if test "$enableval" == "yes"; then

    53      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])

    54    fi] )

    55 AC_ARG_ENABLE( sh4stats,

    56    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),

    57    [if test "$enableval" == "yes"; then

    58      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])

    59     fi] )

    60 AC_ARG_WITH( osmesa,

    61    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),

    62    [], [with_osmesa=no])

    63 AC_ARG_WITH( gtk,

    64    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )

    65 AC_ARG_WITH( esd,

    66    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )

    67 AC_ARG_WITH( pulse,

    68    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )

    69 AC_ARG_WITH( sdl,

    70    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )

    73 dnl ------------ Check if we're building on Darwin --------------

    75 dnl For starters, do we have a working objective-c compiler?

    76 AC_HAVE_OBJC([

    77    AC_CHECK_HEADER([Cocoa/Cocoa.h], [

    78       HAVE_COCOA='yes'

    79       APPLE_BUILD='yes'

    80       LIBS="$LIBS -framework AppKit -framework Carbon"

    81       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"

    82       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"

    83       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"

    84       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])

    85       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])

    86       if test "x$with_gtk" = "xx11"; then

    87         with_gtk=no

    88       fi

    89    ], [], [AC_INCLUDES_DEFAULT])

    91    AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"

    92                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],

    93                    [ OBJCOPT="-O2" ], [] )

    94 ])

    96 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])

    97 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then

    98   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])

    99 fi

   101 dnl ------------------ C Compiler flags -----------------------

   102 CFLAGS="-g -fexceptions"

   103 OBJCFLAGS="-g -fexceptions"

   104 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])

   106 STDCFLAG="-std=c99"

   107 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse"

   108                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   109               [ CCOPT="$CFLAGS -fast"

   110                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   111               [ CCOPT="$CFLAGS -O2" ])

   113 if test "x$enable_optimized" = "xyes"; then

   114    CFLAGS="$CFLAGS $CCOPT"

   115    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"

   116    if test "x$enable_profiled" != "xyes"; then

   117        dnl -fomit-frame-pointer can't be used with -pg

   118        CFLAGS="$CFLAGS -fomit-frame-pointer"

   119        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"

   120    fi

   121 else

   122    CFLAGS="$CFLAGS -g3"

   123    OBJCFLAGS="$OBJCFLAGS -g3"

   124 fi

   126 if test "x$enable_profiled" = "xyes"; then

   127    CFLAGS="$CFLAGS -pg"

   128    LDFLAGS="$LDFLAGS -pg";

   129    OBJCFLAGS="$OBJCFLAGS -pg";

   130 fi

   132 if test "x$enable_strictwarn" = "xyes"; then

   133    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"

   134    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"

   135 fi

   137 if test "x$enable_shared" != "xno"; then

   138    AC_DEFINE(ENABLE_SHARED, [1], [Enable shared-library plugins])

   139    if test "x$APPLE_BUILD" = "xyes"; then

   140       SOEXT="dylib"

   141       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"

   142    else

   143       SOEXT="so"

   144       PLUGINLDFLAGS="-shared"

   145    fi

   146    PLUGINCFLAGS="-fPIC"

   148 dnl Check for dlfcn.h and dlopen() (in libdl or libc)

   149    AC_CHECK_HEADER( [dlfcn.h], [

   150       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])

   151    if test "x$have_dlopen" != "xyes"; then

   152       if test "x$enable_shared" == "xyes"; then

   153          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )

   154       else

   155          AC_MSG_WARN("Statically linking all plugins")

   156       fi

   157    fi

   159 dnl Check if linker accepts -rdynamic

   160    AC_MSG_CHECKING([if linker accepts -rdynamic])

   161    old_LDFLAGS="$LDFLAGS"

   162    LDFLAGS="$LDFLAGS -rdynamic"

   163    AC_LINK_IFELSE( [int main(){ return 0; }], [

   164      LXDREAMLDFLAGS="-rdynamic"

   165      AC_MSG_RESULT([yes])

   166    ], [

   167      LXDREAMLDFLAGS=""

   168      AC_MSG_RESULT([no]) ])

   169    LDFLAGS="$old_LDFLAGS"

   171    AC_SUBST(SOEXT)

   172    AC_SUBST(PLUGINCFLAGS)

   173    AC_SUBST(PLUGINLDFLAGS)

   174    AC_SUBST(LXDREAMLDFLAGS)

   175 fi

   176 AM_CONDITIONAL(BUILD_SHARED, [test "x$have_dlopen" = "xyes"])

   178 AC_CHECK_FASTCALL([

   179    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])

   180 ])

   181 AC_CHECK_FRAME_ADDRESS( [

   182    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])

   183 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])

   185 AC_SUBST(LXDREAMCPPFLAGS)

   186 AC_SEARCH_LIBS(listen, [socket])

   187 AC_SEARCH_LIBS(inet_ntoa,[nsl])

   189 dnl ----------- Check for mandatory dependencies --------------

   190 dnl Check for libpng (required)

   191 PKG_CHECK_MODULES(LIBPNG, [libpng] )

   193 dnl Implied by libpng, but check explicitly just in case

   194 AC_CHECK_LIB(z, uncompress, [], [

   195     echo "Zlib (libz.so) could not be found, but is required."

   196     exit 1])

   198 if test "x$with_gtk" = "xno"; then

   199    dnl Check for GLIB only

   200    PKG_CHECK_MODULES(GLIB, glib-2.0)

   201 else

   202    dnl Check for GTK

   203    PKG_CHECK_MODULES(GTK, gtk+-2.0, [

   204        HAVE_GTK='yes'

   205        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])

   206    ])

   208    dnl Which GTK port do we have?

   209    LIBS="$LIBS $GTK_LIBS"

   210    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [

   211       HAVE_GTK_X11='yes'

   212       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])

   213    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [

   214       HAVE_GTK_OSX='yes'

   215       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])

   216 fi

   218 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])

   220 dnl ------------------ Video driver support -------------------

   221 AS_IF([test "x$with_osmesa" != xno], [

   223 dnl User requested OSMesa (ie pure software rendering)

   224   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],

   225     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])

   226   AC_CHECK_HEADER([GL/osmesa.h], [],

   227     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])

   228   HAVE_OSMESA='yes'

   229   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"

   230   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [

   232 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already

   233 dnl taken care of above).

   234    if test "x$APPLE_BUILD" != 'xyes'; then

   235       AC_CHECK_LIB(GL, glVertex3f, [], [

   236           AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])

   237       AC_CHECK_HEADER([GL/gl.h], [], [

   238           AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])

   239    else

   240       AC_CHECK_FUNC(NSOpenGLGetVersion, [

   241          HAVE_NSGL='yes'

   242          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"

   243          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )

   244    fi

   246 dnl Now work out how to get from the UI to GL - this is usually the painful part.

   247    if test "x$HAVE_GTK_X11" = "xyes"; then

   248       if test "x$APPLE_BUILD" = "xyes"; then

   249          LIBS="$LIBS -L/usr/X11/lib -lGL"

   250       fi

   251       AC_CHECK_FUNC(glXQueryVersion, [

   252          HAVE_GLX='yes'

   253          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"

   254          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )

   255    fi

   257 ])

   261 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])

   262 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])

   263 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])

   265 dnl Check for optional (but highly desireable) OpenGL features

   266 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])

   267 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])

   268 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])

   269 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])

   272 dnl ------------------- SH4 translator target -------------------

   274 if test "x$enable_translator" != "xno"; then

   275     case $host_cpu in

   276         i386|i486|i586|i686|x86_64)

   277 	    SH4_TRANSLATOR="x86"

   278             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;

   279     esac

   280 fi

   281 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])

   283 dnl ------------------ Optional driver support -------------------

   284 dnl Check for Apple CoreAudio

   285 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [

   286      HAVE_CORE_AUDIO=yes

   287      LIBS="$LIBS -framework CoreAudio"

   288      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"

   289      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])

   290 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )

   292 dnl Check for SDL (only used for audio at the moment)

   293 if test "x$with_sdl" != "xno"; then

   294    PKG_CHECK_MODULES(SDL, [sdl], [

   295        HAVE_SDL='yes'

   296        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"

   297        AC_DEFINE([HAVE_SDL],1,[Have SDL support])

   298    ], [

   299       if test "x$with_sdl" = "xyes"; then

   300          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )

   301       fi

   302    ])

   303 fi

   304 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )

   306 dnl Check for pulseaudio

   307 if test "x$with_pulse" != "xno"; then

   308    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [

   309        HAVE_PULSE='yes'

   310        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"

   311        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])

   312    ], [

   313        if test "x$with_pulse" = "xyes"; then

   314           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )

   315        fi

   316    ])

   317 fi

   318 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )

   320 dnl Check for esound

   321 if test "x$with_esd" != "xno"; then

   322    PKG_CHECK_MODULES(ESOUND, [esound], [

   323        HAVE_ESOUND='yes'

   324        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"

   325        AC_DEFINE([HAVE_ESOUND],1,[Have esound support])

   326    ], [

   327        if test "x$with_esd" = "xyes"; then

   328           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )

   329        fi

   330    ])

   331 fi

   332 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )

   334 dnl Check for alsa support

   335 PKG_CHECK_MODULES(ALSA, [alsa], [

   336      HAVE_ALSA='yes'

   337      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"

   338      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])

   339 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )

   342 dnl Check for native cdrom support. There can be only one.

   343 AC_CHECK_HEADER([linux/cdrom.h], [

   344      CDROM_DRIVER=linux

   345      dnl Some kernel versions have non-c99 compliant headers - check here

   346      AC_MSG_CHECKING([C99 compliant kernel headers])

   347      old_CFLAGS="$CFLAGS"

   348      CFLAGS="$CFLAGS $STDCFLAG"

   349      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [

   350         AC_MSG_RESULT([No])

   351         STDCFLAG="-std=gnu99"])

   352      CFLAGS="$old_CFLAGS"

   353 ], [true])

   354 AC_CHECK_HEADER([IOKit/IOKitLib.h], [

   355      CDROM_DRIVER=osx

   356      LIBS="$LIBS -framework IOKit"],[true])

   357 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])

   358 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])

   359 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])

   361 AC_CHECK_HEADER([linux/joystick.h], [

   362     HAVE_LINUX_JOYSTICK_H=yes

   363     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support])

   364     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ],

   365   [ echo "Linux Joystick support not found, building without it."] )

   366 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])

   368 dnl Check for LIRC

   369 if test "x$with_lirc" != "xno"; then

   370     AC_CHECK_HEADER([lirc/lirc_client.h], [

   371         HAVE_LIRC_CLIENT_H=yes

   372         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support])

   373         INPUT_DRIVERS="$INPUT_DRIVERS lirc"

   374       ],

   375       [ echo "LIRC support not found, building without it." ] )

   376 fi

   377 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])

   379 dnl Check for cross-compiler availability - needed for system tests

   380 AC_PATH_PROG(SHCC, [sh-elf-gcc])

   381 AC_PATH_PROG(SHLD, [sh-elf-ld])

   382 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])

   383 AC_PATH_PROG(ARMCC, [arm-elf-gcc])

   384 AC_PATH_PROG(ARMLD, [arm-elf-ld])

   385 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])

   387 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then

   388   BUILD_SH="no"

   389   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."

   390 else

   391   BUILD_SH="yes"

   392 fi

   393 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then

   394   BUILD_ARM="no"

   395   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."

   396 else

   397   BUILD_ARM="yes"

   398 fi

   399 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])

   400 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])

   402 CFLAGS="$CFLAGS $STDCFLAG"

   404 dnl ----------------------- All done, finish up -----------------------

   405 GETTEXT_PACKAGE=lxdream

   406 LXDREAM_LIBS="$LIBS"

   407 LIBS=""

   408 AC_SUBST(LXDREAM_LIBS)

   409 AC_SUBST(GETTEXT_PACKAGE)

   410 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])

   412 dnl Add the languages which your application supports here.

   413 ALL_LINGUAS="de es it pt_BR"

   414 AM_GLIB_GNU_GETTEXT

   416 AC_OUTPUT([

   417 Makefile

   418 src/Makefile

   419 po/Makefile.in

   420 test/Makefile

   421 Info.plist

   422 ])

   423 AS_MKDIR_P(test/sh4)

   425 dnl ------------------------- Print out a summary ----------------------

   427 echo

   428 echo "Configuration complete"

   429 echo

   431 if test "x$HAVE_GTK" = x; then

   432   if test "x$HAVE_COCOA" = x; then

   433      echo "  User interface: none"

   434   else

   435      echo "  User interface: Cocoa"

   436   fi

   437 else

   438   echo "  User interface: GTK"

   439 fi

   441 if test "x$SH4_TRANSLATOR" = "x"; then

   442   echo "  SH4 translator: None (emulation core only)"

   443 else

   444   echo "  SH4 translator: $SH4_TRANSLATOR"

   445 fi

   447 if test "x$VIDEO_DRIVERS" = "x"; then

   448    echo "  Video drivers: none (no supported GL found)"

   449 else

   450    echo "  Video drivers: $VIDEO_DRIVERS"

   451 fi

   453 if test "x$AUDIO_DRIVERS" = "x"; then

   454    echo "  Audio drivers: none (no supported output devices found)"

   455 else

   456    echo "  Audio drivers: $AUDIO_DRIVERS"

   457 fi

   459 if test "x$INPUT_DRIVERS" = "x"; then

   460    echo "  Input drivers: none (no supported input devices found)"

   461 else

   462    echo "  Input drivers: $INPUT_DRIVERS"

   463 fi

   465 if test "x$CDROM_DRIVER" = "x"; then

   466    echo "  CD-ROM driver: none (no supported cd-rom devices found)"

   467 else

   468    echo "  CD-ROM driver:  $CDROM_DRIVER"

   469 fi