filename | configure.in |
changeset | 866:86cd01c2b2d3 |
prev | 804:567a684e1e7a |
next | 882:ada7d14a8ad9 |
author | nkeynes |
date | Tue Oct 14 08:43:01 2008 +0000 (15 years ago) |
permissions | -rw-r--r-- |
last change | Save the main window in a global rather than using [NSApp mainWindow]. This has the advantage of working properly when the window isn't actually main at the time |
view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.8.4)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_ISC_POSIX
9 AC_PROG_CC
10 AM_PROG_CC_STDC
11 AM_PROG_AS
12 AC_CHECK_SIZEOF([void *])
13 AC_HEADER_STDC
14 AC_CANONICAL_BUILD
15 AC_CANONICAL_HOST
17 AC_PATH_PROG(POD2MAN, [pod2man])
18 AC_PATH_PROG(POD2HTML, [pod2html])
20 dnl ---------------- enable/with flags ------------------
22 AC_ARG_ENABLE( strict-warn,
23 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
24 [CFLAGS="$CFLAGS -Werror -Wall -Wno-unused"], [])
25 AC_ARG_ENABLE( translator,
26 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enable by default)]),
27 [true], [enable_translator=yes] )
28 AC_ARG_ENABLE( trace,
29 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
30 [if test "$enableval" == "yes"; then
31 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
32 fi] )
33 AC_ARG_ENABLE( watch,
34 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
35 [if test "$enableval" == "yes"; then
36 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
37 fi] )
38 AC_ARG_ENABLE( sh4stats,
39 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
40 [if test "$enableval" == "yes"; then
41 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
42 fi] )
43 AC_ARG_WITH( osmesa,
44 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
45 [], [with_osmesa=no])
46 AC_ARG_WITH( gtk,
47 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
48 AC_ARG_WITH( esd,
49 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
50 AC_ARG_WITH( pulse,
51 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
53 dnl ------------
55 if test "x$GCC" = "xyes"; then
56 CFLAGS="$CFLAGS -fno-strict-aliasing"
57 fi
59 dnl ------------ Check if we're building on Darwin --------------
61 dnl For starters, do we have a working objective-c compiler?
62 lxdream_save_cppflags="$CPPFLAGS"
63 CPPFLAGS="$CPPFLAGS -x objective-c"
64 AC_TRY_COMPILE([@interface Foo @end],, [
66 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
67 HAVE_COCOA='yes'
68 APPLE_BUILD='yes'
69 LIBS="$LIBS -framework AppKit"
70 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
71 CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4"
72 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
73 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
74 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
75 if test "x$with_gtk" = "xx11"; then
76 with_gtk=no
77 fi
78 ])
80 ], [CPPFLAGS="$lxdream_save_cppflags"] )
81 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
82 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
83 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
84 fi
86 dnl ----------- Check for mandatory dependencies --------------
87 dnl Check for libpng (required)
88 PKG_CHECK_MODULES(LIBPNG, [libpng] )
90 dnl Implied by libpng, but check explicitly just in case
91 AC_CHECK_LIB(z, uncompress, [], [
92 echo "Zlib (libz.so) could not be found, but is required."
93 exit 1])
95 if test "x$with_gtk" = "xno"; then
96 dnl Check for GLIB only
97 PKG_CHECK_MODULES(GLIB, glib-2.0)
98 else
99 dnl Check for GTK
100 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
101 HAVE_GTK='yes'
102 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
103 ])
105 dnl Which GTK port do we have?
106 LIBS="$LIBS $GTK_LIBS"
107 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
108 HAVE_GTK_X11='yes'
109 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
110 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
111 HAVE_GTK_OSX='yes'
112 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
113 fi
115 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
117 dnl ------------------ Video driver support -------------------
118 AS_IF([test "x$with_osmesa" != xno], [
120 dnl User requested OSMesa (ie pure software rendering)
121 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
122 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
123 AC_CHECK_HEADER([GL/osmesa.h], [],
124 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
125 HAVE_OSMESA='yes'
126 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
127 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
129 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
130 dnl taken care of above).
131 if test "x$APPLE_BUILD" != 'xyes'; then
132 AC_CHECK_LIB(GL, glVertex3f, [], [
133 AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
134 AC_CHECK_HEADER([GL/gl.h], [], [
135 AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
136 else
137 AC_CHECK_FUNC(NSOpenGLGetVersion, [
138 HAVE_NSGL='yes'
139 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
140 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
141 fi
143 dnl Now work out how to get from the UI to GL - this is usually the painful part.
144 if test "x$HAVE_GTK_X11" = "xyes"; then
145 if test "x$APPLE_BUILD" = "xyes"; then
146 LIBS="$LIBS -L/usr/X11/lib -lGL"
147 fi
148 AC_CHECK_FUNC(glXQueryVersion, [
149 HAVE_GLX='yes'
150 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
151 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
152 fi
154 ])
158 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
159 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
160 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
162 dnl Check for optional (but highly desireable) OpenGL features
163 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
164 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
165 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
166 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
169 dnl ------------------- SH4 translator target -------------------
171 if test "x$enable_translator" != "xno"; then
172 case $host_cpu in
173 i386|i486|i586|i686|x86_64)
174 SH4_TRANSLATOR="x86"
175 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
176 esac
177 fi
178 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
180 dnl ------------------ Optional driver support -------------------
181 dnl Check for Apple CoreAudio
182 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
183 HAVE_CORE_AUDIO=yes
184 LIBS="$LIBS -framework CoreAudio"
185 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
186 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
187 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
189 dnl Check for pulseaudio
190 if test "x$with_pulse" != "xno"; then
191 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
192 HAVE_PULSE='yes'
193 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
194 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
195 ], [
196 if test "x$with_pulse" = "xyes"; then
197 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
198 fi
199 ])
200 fi
201 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
203 dnl Check for esound
204 if test "x$with_esd" != "xno"; then
205 PKG_CHECK_MODULES(ESOUND, [esound], [
206 HAVE_ESOUND='yes'
207 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
208 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
209 ], [
210 if test "x$with_esd" = "xyes"; then
211 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
212 fi
213 ])
214 fi
215 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
217 dnl Check for alsa support
218 PKG_CHECK_MODULES(ALSA, [alsa], [
219 HAVE_ALSA='yes'
220 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
221 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
222 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
225 dnl Check for native cdrom support. There can be only one.
226 AC_CHECK_HEADER([linux/cdrom.h], [CDROM_DRIVER=linux], [true])
227 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
228 CDROM_DRIVER=osx
229 LIBS="$LIBS -framework IOKit"],[true])
230 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
231 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
232 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
234 AC_CHECK_HEADER([linux/joystick.h], [
235 HAVE_LINUX_JOYSTICK_H=yes
236 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ],
237 [ echo "Linux Joystick support not found, building without it."] )
238 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
240 dnl Check for cross-compiler availability - needed for system tests
241 AC_PATH_PROG(SHCC, [sh-elf-gcc])
242 AC_PATH_PROG(SHLD, [sh-elf-ld])
243 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
244 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
245 AC_PATH_PROG(ARMLD, [arm-elf-ld])
246 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
248 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
249 BUILD_SH="no"
250 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
251 else
252 BUILD_SH="yes"
253 fi
254 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
255 BUILD_ARM="no"
256 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
257 else
258 BUILD_ARM="yes"
259 fi
260 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
261 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
264 dnl ----------------------- All done, finish up -----------------------
265 GETTEXT_PACKAGE=lxdream
266 AC_SUBST(GETTEXT_PACKAGE)
267 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
269 dnl Add the languages which your application supports here.
270 ALL_LINGUAS="de es it pt_BR"
271 AM_GLIB_GNU_GETTEXT
273 AC_OUTPUT([
274 Makefile
275 src/Makefile
276 po/Makefile.in
277 test/Makefile
278 Info.plist
279 ])
280 AS_MKDIR_P(test/sh4)
282 dnl ------------------------- Print out a summary ----------------------
284 echo
285 echo "Configuration complete"
286 echo
288 if test "x$HAVE_GTK" = x; then
289 if test "x$HAVE_COCOA" = x; then
290 echo " User interface: none"
291 else
292 echo " User interface: Cocoa"
293 fi
294 else
295 echo " User interface: GTK"
296 fi
298 if test "x$SH4_TRANSLATOR" = "x"; then
299 echo " SH4 translator: None (emulation core only)"
300 else
301 echo " SH4 translator: $SH4_TRANSLATOR"
302 fi
304 if test "x$VIDEO_DRIVERS" = "x"; then
305 echo " Video drivers: none (no supported GL found)"
306 else
307 echo " Video drivers: $VIDEO_DRIVERS"
308 fi
310 if test "x$AUDIO_DRIVERS" = "x"; then
311 echo " Audio drivers: none (no supported output devices found)"
312 else
313 echo " Audio drivers: $AUDIO_DRIVERS"
314 fi
316 if test "x$CDROM_DRIVER" = "x"; then
317 echo " CD-ROM driver: none (no supported cd-rom devices found)"
318 else
319 echo " CD-ROM driver: $CDROM_DRIVER"
320 fi
.