lxdream.org :: lxdream/configure.in r1110:eb1c005ba3cb

filename	configure.in
changeset	1110:eb1c005ba3cb
prev	1107:7b279d10f46f
next	1113:174fa8e137b6
author	nkeynes
date	Mon Jul 12 22:41:38 2010 +1000 (13 years ago)
permissions	-rw-r--r--
last change	Change GL + libisofs checks to use pkg-config (Patch by ElBarto!)

view

annotate

diff

log

raw

     1 dnl Process this file with autoconf to produce a configure script.

     3 AC_INIT(configure.in)

     4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)

     5 AM_MAINTAINER_MODE

     6 AM_CONFIG_HEADER(config.h)

     8 AC_ISC_POSIX

     9 AC_PROG_CC

    10 AM_PROG_CC_STDC

    11 AC_PROG_OBJC

    12 AC_PROG_SED

    13 AM_PROG_AS

    14 AC_CHECK_SIZEOF([void *])

    15 AC_HEADER_STDC

    16 AC_CANONICAL_BUILD

    17 AC_CANONICAL_HOST

    19 _AM_DEPENDENCIES([OBJC])

    21 AC_PATH_PROG(POD2MAN, [pod2man])

    22 AC_PATH_PROG(POD2HTML, [pod2html])

    24 dnl ---------------- enable/with flags ------------------

    26 AC_ARG_ENABLE( strict-warn,

    27    AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),

    28    [if test "$enableval" == "yes"; then

    29       enable_strictwarn=yes

    30     fi] )

    31 AC_ARG_ENABLE( translator,

    32    AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),

    33    [true], [enable_translator=yes] )

    34 AC_ARG_ENABLE( optimized,

    35    AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),

    36    [true], [enable_optimized=yes] )

    37 AC_ARG_ENABLE( shared,

    38    AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),

    39    [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )

    40 AC_ARG_ENABLE( profiled,

    41    AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),

    42    [if test "$enableval" == "yes"; then

    43       enable_profiled=yes;

    44     fi] )

    45 AC_ARG_ENABLE( trace,

    46    AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),

    47    [if test "$enableval" == "yes"; then

    48      AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])

    49     fi] )

    50 AC_ARG_ENABLE( watch,

    51    AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),

    52    [if test "$enableval" == "yes"; then

    53      AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])

    54    fi] )

    55 AC_ARG_ENABLE( sh4stats,

    56    AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),

    57    [if test "$enableval" == "yes"; then

    58      AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])

    59     fi] )

    60 AC_ARG_WITH( osmesa,

    61    AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),

    62    [], [with_osmesa=no])

    63 AC_ARG_WITH( gtk,

    64    AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )

    65 AC_ARG_WITH( esd,

    66    AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )

    67 AC_ARG_WITH( pulse,

    68    AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )

    69 AC_ARG_WITH( sdl,

    70    AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )

    73 dnl ------------ Check if we're building on Darwin --------------

    75 dnl For starters, do we have a working objective-c compiler?

    76 AC_HAVE_OBJC([

    77    AC_CHECK_HEADER([Cocoa/Cocoa.h], [

    78       HAVE_COCOA='yes'

    79       APPLE_BUILD='yes'

    80       LIBS="$LIBS -framework AppKit -framework Carbon"

    81       LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"

    82       LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"

    83       LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"

    84       AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])

    85       AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])

    86       if test "x$with_gtk" = "xx11"; then

    87         with_gtk=no

    88       fi

    89    ], [], [AC_INCLUDES_DEFAULT])

    91    AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"

    92                      OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],

    93                    [ OBJCOPT="-O2" ], [] )

    94 ])

    96 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])

    97 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then

    98   AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])

    99 fi

   101 dnl ------------------ C Compiler flags -----------------------

   102 CFLAGS="-g -fexceptions"

   103 OBJCFLAGS="-g -fexceptions"

   104 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])

   106 STDCFLAG="-std=c99"

   107 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse"

   108                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   109               [ CCOPT="$CFLAGS -fast"

   110                 CFLAGS="$CFLAGS -fno-strict-aliasing" ],

   111               [ CCOPT="$CFLAGS -O2" ])

   113 if test "x$enable_optimized" = "xyes"; then

   114    CFLAGS="$CFLAGS $CCOPT"

   115    OBJCFLAGS="$OBJCFLAGS $OBJCOPT"

   116    if test "x$enable_profiled" != "xyes"; then

   117        dnl -fomit-frame-pointer can't be used with -pg

   118        CFLAGS="$CFLAGS -fomit-frame-pointer"

   119        OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"

   120    fi

   121 else

   122    CFLAGS="$CFLAGS -g3"

   123    OBJCFLAGS="$OBJCFLAGS -g3"

   124 fi

   126 if test "x$enable_profiled" = "xyes"; then

   127    CFLAGS="$CFLAGS -pg"

   128    LDFLAGS="$LDFLAGS -pg";

   129    OBJCFLAGS="$OBJCFLAGS -pg";

   130 fi

   132 if test "x$enable_strictwarn" = "xyes"; then

   133    CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"

   134    OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"

   135 fi

   137 if test "x$enable_shared" != "xno"; then

   138    AC_DEFINE(ENABLE_SHARED, [1], [Enable shared-library plugins])

   139    if test "x$APPLE_BUILD" = "xyes"; then

   140       SOEXT="dylib"

   141       PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"

   142    else

   143       SOEXT="so"

   144       PLUGINLDFLAGS="-shared"

   145    fi

   146    PLUGINCFLAGS="-fPIC"

   148 dnl Check for dlfcn.h and dlopen() (in libdl or libc)

   149    AC_CHECK_HEADER( [dlfcn.h], [

   150       AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])

   151    if test "x$have_dlopen" != "xyes"; then

   152       if test "x$enable_shared" == "xyes"; then

   153          AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )

   154       else

   155          AC_MSG_WARN("Statically linking all plugins")

   156       fi

   157    fi

   159 dnl Check if linker accepts -rdynamic

   160    AC_MSG_CHECKING([if linker accepts -rdynamic])

   161    old_LDFLAGS="$LDFLAGS"

   162    LDFLAGS="$LDFLAGS -rdynamic"

   163    AC_LINK_IFELSE( [int main(){ return 0; }], [

   164      LXDREAMLDFLAGS="-rdynamic"

   165      AC_MSG_RESULT([yes])

   166    ], [

   167      LXDREAMLDFLAGS=""

   168      AC_MSG_RESULT([no]) ])

   169    LDFLAGS="$old_LDFLAGS"

   171    AC_SUBST(SOEXT)

   172    AC_SUBST(PLUGINCFLAGS)

   173    AC_SUBST(PLUGINLDFLAGS)

   174    AC_SUBST(LXDREAMLDFLAGS)

   175 fi

   176 AM_CONDITIONAL(BUILD_SHARED, [test "x$have_dlopen" = "xyes"])

   178 AC_CHECK_FASTCALL([

   179    AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])

   180 ])

   181 AC_CHECK_FRAME_ADDRESS( [

   182    AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])

   183 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])

   185 AC_SUBST(LXDREAMCPPFLAGS)

   186 AC_SEARCH_LIBS(listen, [socket])

   187 AC_SEARCH_LIBS(inet_ntoa,[nsl])

   189 dnl ----------- Check for mandatory dependencies --------------

   190 dnl Check for libpng (required)

   191 PKG_CHECK_MODULES(LIBPNG, [libpng] )

   193 dnl Implied by libpng, but check explicitly just in case

   194 AC_CHECK_LIB(z, uncompress, [], [

   195     echo "Zlib (libz.so) could not be found, but is required."

   196     exit 1])

   198 if test "x$with_gtk" = "xno"; then

   199    dnl Check for GLIB only

   200    PKG_CHECK_MODULES(GLIB, glib-2.0)

   201 else

   202    dnl Check for GTK

   203    PKG_CHECK_MODULES(GTK, gtk+-2.0, [

   204        HAVE_GTK='yes'

   205        AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])

   206    ])

   208    dnl Which GTK port do we have?

   209    LIBS="$LIBS $GTK_LIBS"

   210    AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [

   211       HAVE_GTK_X11='yes'

   212       AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])

   213    AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [

   214       HAVE_GTK_OSX='yes'

   215       AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])

   216 fi

   218 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])

   220 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )

   221 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [

   222    dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [

   223       dnl LIBS="$LIBS -lisofs"

   224    dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])],

   225       dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])

   227 dnl ------------------ Video driver support -------------------

   228 AS_IF([test "x$with_osmesa" != xno], [

   230 dnl User requested OSMesa (ie pure software rendering)

   231   AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],

   232     [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])

   233   AC_CHECK_HEADER([GL/osmesa.h], [],

   234     [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])

   235   HAVE_OSMESA='yes'

   236   VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"

   237   AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [

   239 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already

   240 dnl taken care of above).

   241    if test "x$APPLE_BUILD" != 'xyes'; then

   242       PKG_CHECK_MODULES(LIBGL, [gl] )

   243       dnl AC_CHECK_LIB(GL, glVertex3f, [], [

   244           dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])

   245       dnl AC_CHECK_HEADER([GL/gl.h], [], [

   246           dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])

   247    else

   248       AC_CHECK_FUNC(NSOpenGLGetVersion, [

   249          HAVE_NSGL='yes'

   250          VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"

   251          AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )

   252    fi

   254 dnl Now work out how to get from the UI to GL - this is usually the painful part.

   255    if test "x$HAVE_GTK_X11" = "xyes"; then

   256       if test "x$APPLE_BUILD" = "xyes"; then

   257          LIBS="$LIBS -L/usr/X11/lib -lGL"

   258       fi

   259       AC_CHECK_FUNC(glXQueryVersion, [

   260          HAVE_GLX='yes'

   261          VIDEO_DRIVERS="$VIDEO_DRIVERS glx"

   262          AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )

   263    fi

   265 ])

   269 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])

   270 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])

   271 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])

   273 dnl Check for optional (but highly desireable) OpenGL features

   274 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])

   275 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])

   276 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])

   277 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])

   280 dnl ------------------- SH4 translator target -------------------

   282 if test "x$enable_translator" != "xno"; then

   283     case $host_cpu in

   284         i386|i486|i586|i686|x86_64)

   285 	    SH4_TRANSLATOR="x86"

   286             AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;

   287     esac

   288 fi

   289 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])

   291 dnl ------------------ Optional driver support -------------------

   292 dnl Check for Apple CoreAudio

   293 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [

   294      HAVE_CORE_AUDIO=yes

   295      LIBS="$LIBS -framework CoreAudio"

   296      AUDIO_DRIVERS="$AUDIO_DRIVERS osx"

   297      AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])

   298 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )

   300 dnl Check for SDL (only used for audio at the moment)

   301 if test "x$with_sdl" != "xno"; then

   302    PKG_CHECK_MODULES(SDL, [sdl], [

   303        HAVE_SDL='yes'

   304        AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"

   305        AC_DEFINE([HAVE_SDL],1,[Have SDL support])

   306    ], [

   307       if test "x$with_sdl" = "xyes"; then

   308          AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )

   309       fi

   310    ])

   311 fi

   312 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )

   314 dnl Check for pulseaudio

   315 if test "x$with_pulse" != "xno"; then

   316    PKG_CHECK_MODULES(PULSE, [libpulse-simple], [

   317        HAVE_PULSE='yes'

   318        AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"

   319        AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])

   320    ], [

   321        if test "x$with_pulse" = "xyes"; then

   322           AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )

   323        fi

   324    ])

   325 fi

   326 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )

   328 dnl Check for esound

   329 if test "x$with_esd" != "xno"; then

   330    PKG_CHECK_MODULES(ESOUND, [esound], [

   331        HAVE_ESOUND='yes'

   332        AUDIO_DRIVERS="$AUDIO_DRIVERS esd"

   333        AC_DEFINE([HAVE_ESOUND],1,[Have esound support])

   334    ], [

   335        if test "x$with_esd" = "xyes"; then

   336           AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )

   337        fi

   338    ])

   339 fi

   340 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )

   342 dnl Check for alsa support

   343 PKG_CHECK_MODULES(ALSA, [alsa], [

   344      HAVE_ALSA='yes'

   345      AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"

   346      AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])

   347 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )

   350 dnl Check for native cdrom support. There can be only one.

   351 AC_CHECK_HEADER([linux/cdrom.h], [

   352      CDROM_DRIVER=linux

   353      dnl Some kernel versions have non-c99 compliant headers - check here

   354      AC_MSG_CHECKING([C99 compliant kernel headers])

   355      old_CFLAGS="$CFLAGS"

   356      CFLAGS="$CFLAGS $STDCFLAG"

   357      AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [

   358         AC_MSG_RESULT([No])

   359         STDCFLAG="-std=gnu99"])

   360      CFLAGS="$old_CFLAGS"

   361 ], [true])

   362 AC_CHECK_HEADER([IOKit/IOKitLib.h], [

   363      CDROM_DRIVER=osx

   364      LIBS="$LIBS -framework IOKit"],[true])

   365 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])

   366 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])

   367 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])

   368 if test "x$CDROM_DRIVER" = "xlinux"; then

   369    AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])

   370 fi

   372 AC_CHECK_HEADER([linux/joystick.h], [

   373     HAVE_LINUX_JOYSTICK_H=yes

   374     AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support])

   375     INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ],

   376   [ echo "Linux Joystick support not found, building without it."] )

   377 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])

   379 dnl Check for LIRC

   380 if test "x$with_lirc" != "xno"; then

   381     AC_CHECK_HEADER([lirc/lirc_client.h], [

   382         HAVE_LIRC_CLIENT_H=yes

   383         AC_DEFINE([HAVE_LIRC],1,[Have LIRC support])

   384         INPUT_DRIVERS="$INPUT_DRIVERS lirc"

   385       ],

   386       [ echo "LIRC support not found, building without it." ] )

   387 fi

   388 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])

   390 dnl Check for cross-compiler availability - needed for system tests

   391 AC_PATH_PROG(SHCC, [sh-elf-gcc])

   392 AC_PATH_PROG(SHLD, [sh-elf-ld])

   393 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])

   394 AC_PATH_PROG(ARMCC, [arm-elf-gcc])

   395 AC_PATH_PROG(ARMLD, [arm-elf-ld])

   396 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])

   398 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then

   399   BUILD_SH="no"

   400   echo "Warning: SH4 cross-compiler not found, system tests will be disabled."

   401 else

   402   BUILD_SH="yes"

   403 fi

   404 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then

   405   BUILD_ARM="no"

   406   echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."

   407 else

   408   BUILD_ARM="yes"

   409 fi

   410 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])

   411 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])

   413 CFLAGS="$CFLAGS $STDCFLAG"

   415 dnl ----------------------- All done, finish up -----------------------

   416 GETTEXT_PACKAGE=lxdream

   417 LXDREAM_LIBS="$LIBS"

   418 LIBS=""

   419 AC_SUBST(LXDREAM_LIBS)

   420 AC_SUBST(GETTEXT_PACKAGE)

   421 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])

   423 dnl Add the languages which your application supports here.

   424 ALL_LINGUAS="de es it pt_BR"

   425 AM_GLIB_GNU_GETTEXT

   427 AC_OUTPUT([

   428 Makefile

   429 src/Makefile

   430 po/Makefile.in

   431 test/Makefile

   432 Info.plist

   433 ])

   434 AS_MKDIR_P(test/sh4)

   436 dnl ------------------------- Print out a summary ----------------------

   438 echo

   439 echo "Configuration complete"

   440 echo

   442 if test "x$HAVE_GTK" = x; then

   443   if test "x$HAVE_COCOA" = x; then

   444      echo "  User interface: none"

   445   else

   446      echo "  User interface: Cocoa"

   447   fi

   448 else

   449   echo "  User interface: GTK"

   450 fi

   452 if test "x$SH4_TRANSLATOR" = "x"; then

   453   echo "  SH4 translator: None (emulation core only)"

   454 else

   455   echo "  SH4 translator: $SH4_TRANSLATOR"

   456 fi

   458 if test "x$VIDEO_DRIVERS" = "x"; then

   459    echo "  Video drivers: none (no supported GL found)"

   460 else

   461    echo "  Video drivers: $VIDEO_DRIVERS"

   462 fi

   464 if test "x$AUDIO_DRIVERS" = "x"; then

   465    echo "  Audio drivers: none (no supported output devices found)"

   466 else

   467    echo "  Audio drivers: $AUDIO_DRIVERS"

   468 fi

   470 if test "x$INPUT_DRIVERS" = "x"; then

   471    echo "  Input drivers: none (no supported input devices found)"

   472 else

   473    echo "  Input drivers: $INPUT_DRIVERS"

   474 fi

   476 if test "x$CDROM_DRIVER" = "x"; then

   477    echo "  CD-ROM driver: none (no supported cd-rom devices found)"

   478 else

   479    echo "  CD-ROM driver:  $CDROM_DRIVER"

   480 fi