lxdream 0.9.1| filename | configure.in |
| changeset | 1266:e6079b9c69ba |
| prev | 1245:01e0020adf88 |
| next | 1284:0db0a5e72698 |
| author | nkeynes |
| date | Wed Mar 21 09:01:41 2012 +1000 (12 years ago) |
| permissions | -rw-r--r-- |
| last change | Surface management is actually already being taken care of - don't try to duplicate in onPause/onResume |
| view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.9.1)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_CANONICAL_BUILD
9 AC_CANONICAL_HOST
11 m4_include([m4/ccforbuild.m4])
12 m4_include([m4/android.m4])
13 LX_ANDROID_BUILD
15 AC_ISC_POSIX
16 AC_PROG_CC
17 AM_PROG_CC_STDC
18 AC_PROG_CC_FOR_BUILD
19 AC_PROG_OBJC
20 AC_PROG_SED
21 AM_PROG_AS
22 AC_PROG_RANLIB
23 AC_CHECK_SIZEOF([void *])
24 AC_HEADER_STDC
26 _AM_DEPENDENCIES([OBJC])
28 AC_PATH_PROG(POD2MAN, [pod2man])
29 AC_PATH_PROG(POD2HTML, [pod2html])
31 AC_DEFINE_UNQUOTED(BUILD_SED_PROG, ["${SED}"], [Sed to use for build tools])
32 AC_DEFINE_UNQUOTED(BUILD_CPP_PROG, ["${CPP}"], [CPP to use for build tools])
34 dnl ---------------- enable/with flags ------------------
36 AC_ARG_ENABLE( strict-warn,
37 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
38 [if test "$enableval" == "yes"; then
39 enable_strictwarn=yes
40 fi] )
41 AC_ARG_ENABLE( translator,
42 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
43 [true], [enable_translator=yes] )
44 AC_ARG_ENABLE( optimized,
45 AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
46 [true], [enable_optimized=yes] )
47 AC_ARG_ENABLE( shared,
48 AS_HELP_STRING( [--enable-shared], [Build drivers as shared libraries (Enabled if available)]),
49 [if test "$enableval" == "yes"; then enable_shared=yes; else enable_shared=no; fi], [enable_shared=cond] )
50 AC_ARG_ENABLE( profiled,
51 AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
52 [if test "$enableval" == "yes"; then
53 enable_profiled=yes;
54 fi] )
55 AC_ARG_ENABLE( trace,
56 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
57 [if test "$enableval" == "yes"; then
58 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
59 fi] )
60 AC_ARG_ENABLE( watch,
61 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
62 [if test "$enableval" == "yes"; then
63 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
64 fi] )
65 AC_ARG_ENABLE( sh4stats,
66 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
67 [if test "$enableval" == "yes"; then
68 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
69 fi] )
70 AC_ARG_WITH( osmesa,
71 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
72 [], [with_osmesa=no])
73 AC_ARG_WITH( gtk,
74 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
75 AC_ARG_WITH( esd,
76 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
77 AC_ARG_WITH( pulse,
78 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
79 AC_ARG_WITH( sdl,
80 AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
82 dnl ------------ Check if we're building on Darwin or Android --------------
84 dnl For starters, do we have a working objective-c compiler?
85 if test "$ANDROID_BUILD" = "yes"; then
86 with_gtk=no;
87 EXTRA_OUTPUT_FILES="src/android/build.properties"
88 LIBS="-lEGL -lGLESv2 $LIBS"
89 AC_DEFINE(HAVE_GLES2, 1, [Using GLESv2])
90 UI_DRIVER="Android"
91 VIDEO_DRIVERS="egl"
92 with_sdl=no
93 else
94 AC_HAVE_OBJC([
95 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
96 HAVE_COCOA='yes'
97 APPLE_BUILD='yes'
98 LIBS="$LIBS -framework AppKit -framework Carbon"
99 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
100 LXDREAMCPPFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
101 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
102 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
103 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
104 UI_DRIVER="Cocoa"
105 if test "x$with_gtk" = "xx11"; then
106 with_gtk=no
107 fi
108 ], [], [AC_INCLUDES_DEFAULT])
110 AC_OBJC_VERSION([ OBJCOPT="-O2"
111 OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
112 [ OBJCOPT="-O2" ], [] )
113 AC_CHECK_OBJCFLAG([-msse2])
114 AC_CHECK_OBJCFLAG([-mfpmath=sse])
115 ])
116 fi
118 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
119 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
120 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
121 fi
123 dnl ------------------ C Compiler flags -----------------------
124 CFLAGS_FOR_BUILD="-O2 -std=c99"
125 CFLAGS="-g -fexceptions"
126 OBJCFLAGS="-g -fexceptions"
127 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
129 STDCFLAG="-std=c99"
130 AC_CC_VERSION([ CCOPT="-O2"
131 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
132 [ CCOPT="$CFLAGS -fast"
133 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
134 [ CCOPT="$CFLAGS -O2" ])
135 AC_CHECK_CFLAG([-msse2])
136 AC_CHECK_CFLAG([-mfpmath=sse])
138 if test "x$enable_optimized" = "xyes"; then
139 CFLAGS="$CFLAGS $CCOPT"
140 OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
141 if test "x$enable_profiled" != "xyes"; then
142 dnl -fomit-frame-pointer can't be used with -pg
143 CFLAGS="$CFLAGS -fomit-frame-pointer"
144 OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
145 fi
146 else
147 CFLAGS="$CFLAGS -g3"
148 OBJCFLAGS="$OBJCFLAGS -g3"
149 fi
151 if test "x$enable_profiled" = "xyes"; then
152 CFLAGS="$CFLAGS -pg"
153 LDFLAGS="$LDFLAGS -pg";
154 OBJCFLAGS="$OBJCFLAGS -pg";
155 fi
157 if test "x$enable_strictwarn" = "xyes"; then
158 CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
159 OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
160 fi
162 if test "x$enable_shared" != "xno"; then
163 if test "x$APPLE_BUILD" = "xyes"; then
164 SOEXT="dylib"
165 PLUGINLDFLAGS="-dynamiclib -undefined dynamic_lookup"
166 else
167 SOEXT="so"
168 PLUGINLDFLAGS="-shared"
169 fi
170 PLUGINCFLAGS="-fPIC"
172 dnl Check for dlfcn.h and dlopen() (in libdl or libc)
173 AC_CHECK_HEADER( [dlfcn.h], [
174 AC_SEARCH_LIBS( [dlopen], [dl], [have_dlopen=yes]) ])
175 if test "x$have_dlopen" != "xyes"; then
176 if test "x$enable_shared" == "xyes"; then
177 AC_MSG_ERROR( "--enable-shared not supported on your system - can't find a working dlopen" )
178 else
179 AC_MSG_WARN("Statically linking all plugins")
180 fi
181 fi
183 dnl Check if linker accepts -rdynamic
184 AC_MSG_CHECKING([if linker accepts -rdynamic])
185 old_LDFLAGS="$LDFLAGS"
186 LDFLAGS="$LDFLAGS -rdynamic"
187 AC_LINK_IFELSE( [AC_LANG_SOURCE([int main() { return 0; }])], [
188 LXDREAMLDFLAGS="-rdynamic"
189 AC_MSG_RESULT([yes])
190 ], [
191 LXDREAMLDFLAGS=""
192 AC_MSG_RESULT([no]) ])
193 LDFLAGS="$old_LDFLAGS"
195 AC_SUBST(SOEXT)
196 AC_SUBST(PLUGINCFLAGS)
197 AC_SUBST(PLUGINLDFLAGS)
198 AC_SUBST(LXDREAMLDFLAGS)
199 fi
200 if test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"; then
201 AC_DEFINE(BUILD_PLUGINS, [1], [Enable dynamic plugin support])
202 fi
203 AM_CONDITIONAL(BUILD_PLUGINS, [test "x$have_dlopen" = "xyes" -a "x$ANDROID_BUILD" != "xyes"])
205 AC_CHECK_FASTCALL([
206 AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
207 ])
208 AC_CHECK_FORCEINLINE()
209 AC_DEFINE_UNQUOTED(FORCEINLINE, [$FORCEINLINE], [Forcibly inline code])
210 AC_CHECK_FRAME_ADDRESS( [
211 AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
212 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
214 AC_SUBST(LXDREAMCPPFLAGS)
215 AC_SEARCH_LIBS(listen, [socket])
216 AC_SEARCH_LIBS(inet_ntoa,[nsl])
218 dnl ----------- Check for mandatory dependencies --------------
219 dnl Check for libpng (required)
220 PKG_CHECK_MODULES(LIBPNG, [libpng] )
222 dnl Implied by libpng, but check explicitly just in case
223 AC_CHECK_LIB(z, uncompress, [], [
224 echo "Zlib (libz.so) could not be found, but is required."
225 exit 1])
227 if test "x$with_gtk" = "xno"; then
228 dnl Check for GLIB only
229 PKG_CHECK_MODULES(GLIB, glib-2.0)
230 else
231 dnl Check for GTK
232 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
233 HAVE_GTK='yes'
234 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
235 UI_DRIVER="GTK"
236 ])
238 dnl Which GTK port do we have?
239 LIBS="$LIBS $GTK_LIBS"
240 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
241 HAVE_GTK_X11='yes'
242 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
243 dnl Add -lX11 explicitly as some pkg-configs get it wrong
244 GTK_LIBS="$GTK_LIBS -lX11"
245 LIBS="$LIBS -lX11"
246 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
247 HAVE_GTK_OSX='yes'
248 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
249 if test "x$HAVE_GTK_X11$HAVE_GTK_OSX" = "x"; then
250 AC_MSG_FAILURE( [Unable to identify GTK platform] )
251 fi
252 fi
254 AC_PUSH_CC_FOR_BUILD
255 PKG_CHECK_MODULES(GLIB_FOR_BUILD, glib-2.0)
256 AC_POP_CC_FOR_BUILD
258 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
260 PKG_CHECK_MODULES(LIBISOFS, [libisofs-1] )
261 dnl AC_CHECK_HEADER([libisofs/libisofs.h], [
262 dnl AC_CHECK_LIB(isofs, [iso_data_source_new_from_file], [
263 dnl LIBS="-lisofs $LIBS"
264 dnl ], [ AC_MSG_FAILURE( ["Libisofs library not found, but is required"]) ])],
265 dnl [ AC_MSG_FAILURE( ["Libisofs headers not found, but is required"]) ])
267 dnl ------------------ Video driver support -------------------
268 AS_IF([test "x$with_osmesa" != xno], [
270 dnl User requested OSMesa (ie pure software rendering)
271 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
272 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
273 AC_CHECK_HEADER([GL/osmesa.h], [],
274 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
275 HAVE_OSMESA='yes'
276 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
277 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
279 dnl Otherwise we want a real GL library (unless we're on darwin or android, in which case it's already
280 dnl taken care of above).
281 if test "x$APPLE_BUILD" != 'xyes' -a "x$ANDROID_BUILD" != 'xyes'; then
282 PKG_CHECK_MODULES(LIBGL, [gl] )
283 dnl AC_CHECK_LIB(GL, glVertex3f, [], [
284 dnl AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
285 dnl AC_CHECK_HEADER([GL/gl.h], [], [
286 dnl AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
287 LIBS="$LIBS $LIBGL_LIBS";
288 CPPFLAGS="$CPPFLAGS $LIBGL_CFLAGS";
289 else
290 AC_CHECK_FUNC(NSOpenGLGetVersion, [
291 HAVE_NSGL='yes'
292 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
293 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
294 fi
296 dnl Now work out how to get from the UI to GL - this is usually the painful part.
297 if test "x$HAVE_GTK_X11" = "xyes"; then
298 if test "x$APPLE_BUILD" = "xyes"; then
299 LIBS="$LIBS -L/usr/X11/lib -lGL"
300 fi
301 AC_CHECK_FUNC(glXQueryVersion, [
302 HAVE_GLX='yes'
303 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
304 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
305 fi
307 ])
311 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
312 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
313 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
315 dnl Check for optional (but highly desireable) OpenGL features
316 AC_CHECK_FUNC(glGenFramebuffers, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have 2.0 framebuffer_object support]) ], [])
317 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO_EXT],1,[Have EXT_framebuffer_object support]) ], [])
318 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
319 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
320 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
321 AC_CHECK_FUNC(glClearDepthf, [ AC_DEFINE([HAVE_OPENGL_CLEAR_DEPTHF],1,[Have glClearDepthf function]) ], [])
322 AC_CHECK_FUNC(glAreTexturesResident, [ AC_DEFINE([HAVE_OPENGL_TEX_RESIDENT],1,[Have glAreTexturesResident function]) ], [])
323 AC_CHECK_FUNC(glDrawBuffer, [ AC_DEFINE([HAVE_OPENGL_DRAW_BUFFER],1,[Have glDrawBuffer function])], [])
324 AC_CHECK_FUNC(glTexEnvi, [ AC_DEFINE([HAVE_OPENGL_FIXEDFUNC],1,[Have OpenGL fixed-functionality]) ], [])dnl glTexEnvi is a pretty fair proxy for this.
326 dnl ------------------- SH4 translator target -------------------
328 if test "x$enable_translator" != "xno"; then
329 case $host_cpu in
330 i386|i486|i586|i686|x86_64)
331 SH4_TRANSLATOR="x86"
332 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
333 esac
334 fi
335 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
337 dnl ------------------ Optional driver support -------------------
338 dnl Check for Apple CoreAudio
339 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
340 HAVE_CORE_AUDIO=yes
341 LIBS="$LIBS -framework CoreAudio"
342 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
343 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
344 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
346 dnl Check for SDL (only used for audio at the moment)
347 if test "x$with_sdl" != "xno"; then
348 PKG_CHECK_MODULES(SDL, [sdl], [
349 HAVE_SDL='yes'
350 AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
351 AC_DEFINE([HAVE_SDL],1,[Have SDL support])
352 ], [
353 if test "x$with_sdl" = "xyes"; then
354 AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
355 fi
356 ])
357 fi
358 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
360 dnl Check for pulseaudio
361 if test "x$with_pulse" != "xno"; then
362 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
363 HAVE_PULSE='yes'
364 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
365 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
366 ], [
367 if test "x$with_pulse" = "xyes"; then
368 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
369 fi
370 ])
371 fi
372 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
374 dnl Check for esound
375 if test "x$with_esd" != "xno"; then
376 PKG_CHECK_MODULES(ESOUND, [esound], [
377 HAVE_ESOUND='yes'
378 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
379 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
380 ], [
381 if test "x$with_esd" = "xyes"; then
382 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
383 fi
384 ])
385 fi
386 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
388 dnl Check for alsa support
389 PKG_CHECK_MODULES(ALSA, [alsa], [
390 HAVE_ALSA='yes'
391 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
392 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
393 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
396 dnl Check for native cdrom support. There can be only one.
397 if test "$ANDROID_BUILD" != "yes"; then
398 AC_CHECK_HEADER([linux/cdrom.h], [
399 CDROM_DRIVER=linux
400 dnl Some kernel versions have non-c99 compliant headers - check here
401 AC_MSG_CHECKING([C99 compliant kernel headers])
402 old_CFLAGS="$CFLAGS"
403 CFLAGS="$CFLAGS $STDCFLAG"
404 AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
405 AC_MSG_RESULT([No])
406 STDCFLAG="-std=gnu99"])
407 CFLAGS="$old_CFLAGS"
408 ], [true])
409 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
410 CDROM_DRIVER=osx
411 LIBS="$LIBS -framework IOKit"],[true])
412 fi
413 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
414 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
415 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
416 if test "x$CDROM_DRIVER" = "xlinux"; then
417 AC_DEFINE([HAVE_LINUX_CDROM],1,[Using the linux native CDROM driver])
418 fi
420 AC_CHECK_HEADER([linux/joystick.h], [
421 HAVE_LINUX_JOYSTICK_H=yes
422 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support])
423 INPUT_DRIVERS="$INPUT_DRIVERS joy_linux" ],
424 [ echo "Linux Joystick support not found, building without it."] )
425 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
427 dnl Check for LIRC
428 if test "x$with_lirc" != "xno"; then
429 AC_CHECK_HEADER([lirc/lirc_client.h], [
430 HAVE_LIRC_CLIENT_H=yes
431 AC_DEFINE([HAVE_LIRC],1,[Have LIRC support])
432 INPUT_DRIVERS="$INPUT_DRIVERS lirc"
433 ],
434 [ echo "LIRC support not found, building without it." ] )
435 fi
436 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
438 dnl Check for cross-compiler availability - needed for system tests
439 AC_PATH_PROG(SHCC, [sh-elf-gcc])
440 AC_PATH_PROG(SHLD, [sh-elf-ld])
441 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
442 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
443 AC_PATH_PROG(ARMLD, [arm-elf-ld])
444 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
446 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
447 BUILD_SH="no"
448 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
449 else
450 BUILD_SH="yes"
451 fi
452 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
453 BUILD_ARM="no"
454 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
455 else
456 BUILD_ARM="yes"
457 fi
458 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
459 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
461 CFLAGS="$CFLAGS $STDCFLAG"
463 dnl ----------------------- All done, finish up -----------------------
464 GETTEXT_PACKAGE=lxdream
465 LXDREAM_LIBS="$LIBS"
466 LIBS=""
467 AC_SUBST(LXDREAM_LIBS)
468 AC_SUBST(GETTEXT_PACKAGE)
469 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
471 dnl Add the languages which your application supports here.
472 ALL_LINGUAS="de es it nl pt_BR"
473 AM_GLIB_GNU_GETTEXT
475 AC_OUTPUT([
476 Makefile
477 src/Makefile
478 src/tools/Makefile
479 po/Makefile.in
480 test/Makefile
481 Info.plist
482 ])
483 AS_MKDIR_P(test/sh4)
485 dnl ------------------------- Print out a summary ----------------------
487 echo
488 echo "Configuration complete"
489 echo
491 if test "x$UI_DRIVER" = x; then
492 echo " User interface: none"
493 else
494 echo " User interface: $UI_DRIVER"
495 fi
497 if test "x$SH4_TRANSLATOR" = "x"; then
498 echo " SH4 translator: none (emulation core only)"
499 else
500 echo " SH4 translator: $SH4_TRANSLATOR"
501 fi
503 if test "x$VIDEO_DRIVERS" = "x"; then
504 echo " Video drivers: none (no supported GL found)"
505 else
506 echo " Video drivers: $VIDEO_DRIVERS"
507 fi
509 if test "x$AUDIO_DRIVERS" = "x"; then
510 echo " Audio drivers: none (no supported output devices found)"
511 else
512 echo " Audio drivers: $AUDIO_DRIVERS"
513 fi
515 if test "x$INPUT_DRIVERS" = "x"; then
516 echo " Input drivers: none (no supported input devices found)"
517 else
518 echo " Input drivers: $INPUT_DRIVERS"
519 fi
521 if test "x$CDROM_DRIVER" = "x"; then
522 echo " CD-ROM driver: none (no supported cd-rom devices found)"
523 else
524 echo " CD-ROM driver: $CDROM_DRIVER"
525 fi
.