filename | configure.in |
changeset | 1015:ad448bedc48a |
prev | 1002:8ad76ddbdc58 |
next | 1024:c67f2d61ab97 |
author | nkeynes |
date | Wed Jun 03 04:00:52 2009 +0000 (14 years ago) |
permissions | -rw-r--r-- |
last change | Replace dcemu.gif with the better-named lxdream.png Update gtkui to actually use the icon Add a GNOME desktop entry for menu goodness |
view | annotate | diff | log | raw |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(configure.in)
4 AM_INIT_AUTOMAKE(lxdream, 0.9)
5 AM_MAINTAINER_MODE
6 AM_CONFIG_HEADER(config.h)
8 AC_ISC_POSIX
9 AC_PROG_CC
10 AM_PROG_CC_STDC
11 AC_PROG_OBJC
12 AC_PROG_SED
13 AM_PROG_AS
14 AC_CHECK_SIZEOF([void *])
15 AC_HEADER_STDC
16 AC_CANONICAL_BUILD
17 AC_CANONICAL_HOST
19 _AM_DEPENDENCIES([OBJC])
21 AC_PATH_PROG(POD2MAN, [pod2man])
22 AC_PATH_PROG(POD2HTML, [pod2html])
24 dnl ---------------- enable/with flags ------------------
26 AC_ARG_ENABLE( strict-warn,
27 AS_HELP_STRING( [--enable-strict-warn], [Enable strict compilation warnings]),
28 [if test "$enableval" == "yes"; then
29 enable_strictwarn=yes
30 fi] )
31 AC_ARG_ENABLE( translator,
32 AS_HELP_STRING( [--disable-translator], [Disable the SH4 translator (Enabled by default)]),
33 [true], [enable_translator=yes] )
34 AC_ARG_ENABLE( optimized,
35 AS_HELP_STRING( [--disable-optimized], [Disable compile-time optimizations (Enabled by default)]),
36 [true], [enable_optimized=yes] )
37 AC_ARG_ENABLE( profiled,
38 AS_HELP_STRING( [--enable-profiled], [Enable profiling build]),
39 [if test "$enableval" == "yes"; then
40 enable_profiled=yes;
41 fi] )
42 AC_ARG_ENABLE( trace,
43 AS_HELP_STRING( [--enable-trace], [Enable generation of IO traces (warning: hurts performance)]),
44 [if test "$enableval" == "yes"; then
45 AC_DEFINE(ENABLE_TRACE_IO, 1, [Enable IO tracing])
46 fi] )
47 AC_ARG_ENABLE( watch,
48 AS_HELP_STRING( [--enable-watch], [Enable watchpoints in the debugger (warning: hurts performance)]),
49 [if test "$enableval" == "yes"; then
50 AC_DEFINE(ENABLE_WATCH, 1, [Enable watchpoints])
51 fi] )
52 AC_ARG_ENABLE( sh4stats,
53 AS_HELP_STRING( [--enable-sh4stats], [Enable statistics on executed sh4 instructions]),
54 [if test "$enableval" == "yes"; then
55 AC_DEFINE(ENABLE_SH4STATS, 1, [Enable SH4 statistics])
56 fi] )
57 AC_ARG_WITH( osmesa,
58 AS_HELP_STRING( [--with-osmesa], [Build with the osmesa GL library (software rendering)]),
59 [], [with_osmesa=no])
60 AC_ARG_WITH( gtk,
61 AS_HELP_STRING( [--with-gtk], [Build with the GTK UI. Default on X11 systems]), [with_gtk=yes], [with_gtk=x11] )
62 AC_ARG_WITH( esd,
63 AS_HELP_STRING( [--with-esd], [Build with support for the ESounD audio system]) )
64 AC_ARG_WITH( pulse,
65 AS_HELP_STRING( [--with-pulse], [Build with support for the PulseAudio audio system]) )
66 AC_ARG_WITH( sdl,
67 AS_HELP_STRING( [--with-sdl], [Build with support for SDL audio]) )
70 dnl ------------ Check if we're building on Darwin --------------
72 dnl For starters, do we have a working objective-c compiler?
73 AC_HAVE_OBJC([
74 AC_CHECK_HEADER([Cocoa/Cocoa.h], [
75 HAVE_COCOA='yes'
76 APPLE_BUILD='yes'
77 LIBS="$LIBS -framework AppKit"
78 LIBS="$LIBS -Wl,-dylib_file,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -framework OpenGL"
79 CPPFLAGS="$CPPFLAGS -DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_4 -mdynamic-no-pic"
80 LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"
81 AC_DEFINE(HAVE_COCOA,[1],[Have Cocoa framework])
82 AC_DEFINE(APPLE_BUILD,[1],[Building on an apple platform. Things are different...])
83 if test "x$with_gtk" = "xx11"; then
84 with_gtk=no
85 fi
86 ], [], [AC_INCLUDES_DEFAULT])
88 AC_OBJC_VERSION([ OBJCOPT="-O2 -msse2 -mfpmath=sse"
89 OBJCFLAGS="$OBJCFLAGS -fno-strict-aliasing" ],
90 [ OBJCOPT="-O2" ], [] )
91 ])
93 AM_CONDITIONAL(GUI_COCOA, [test "$HAVE_COCOA" = 'yes' -a "$with_gtk" = "no"])
94 if test "x$HAVE_COCOA" = 'xyes' -a "x$with_gtk" = "xno"; then
95 AC_DEFINE(OSX_BUNDLE, [1], [Generating a bundled application])
96 fi
98 dnl ------------------ C Compiler flags -----------------------
99 CFLAGS="-g -fexceptions"
100 OBJCFLAGS="-g -fexceptions"
101 AC_DEFINE(HAVE_EXCEPTIONS, [1], [Have exception stack-frame information])
103 STDCFLAG="-std=c99"
104 AC_CC_VERSION([ CCOPT="-O2 -msse2 -mfpmath=sse"
105 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
106 [ CCOPT="$CFLAGS -fast"
107 CFLAGS="$CFLAGS -fno-strict-aliasing" ],
108 [ CCOPT="$CFLAGS -O2" ])
110 if test "x$enable_optimized" = "xyes"; then
111 CFLAGS="$CFLAGS $CCOPT"
112 OBJCFLAGS="$OBJCFLAGS $OBJCOPT"
113 if test "x$enable_profiled" != "xyes"; then
114 dnl -fomit-frame-pointer can't be used with -pg
115 CFLAGS="$CFLAGS -fomit-frame-pointer"
116 OBJCFLAGS="$OBJCFLAGS -fomit-frame-pointer"
117 fi
118 else
119 CFLAGS="$CFLAGS -g3"
120 OBJCFLAGS="$OBJCFLAGS -g3"
121 fi
123 if test "x$enable_profiled" = "xyes"; then
124 CFLAGS="$CFLAGS -pg"
125 LDFLAGS="$LDFLAGS -pg";
126 OBJCFLAGS="$OBJCFLAGS -pg";
127 fi
129 if test "x$enable_strictwarn" = "xyes"; then
130 CFLAGS="$CFLAGS -Wall -Werror -Wno-unused"
131 OBJCFLAGS="$OBJCFLAGS -Wall -Werror -Wno-unused"
132 fi
134 AC_CHECK_FASTCALL([
135 AC_DEFINE(HAVE_FASTCALL, [1], [Use fast register-passing calling conventions])
136 ])
137 AC_CHECK_FRAME_ADDRESS( [
138 AC_DEFINE(HAVE_FRAME_ADDRESS, [1], [Define if we have a working builtin frame_address])
139 ], [ AC_MSG_WARN([Memory exceptions will be slow]) ])
141 AC_SEARCH_LIBS(listen, [socket])
142 AC_SEARCH_LIBS(inet_ntoa,[nsl])
144 dnl ----------- Check for mandatory dependencies --------------
145 dnl Check for libpng (required)
146 PKG_CHECK_MODULES(LIBPNG, [libpng] )
148 dnl Implied by libpng, but check explicitly just in case
149 AC_CHECK_LIB(z, uncompress, [], [
150 echo "Zlib (libz.so) could not be found, but is required."
151 exit 1])
153 if test "x$with_gtk" = "xno"; then
154 dnl Check for GLIB only
155 PKG_CHECK_MODULES(GLIB, glib-2.0)
156 else
157 dnl Check for GTK
158 PKG_CHECK_MODULES(GTK, gtk+-2.0, [
159 HAVE_GTK='yes'
160 AC_DEFINE([HAVE_GTK],1,[Have GTK libraries])
161 ])
163 dnl Which GTK port do we have?
164 LIBS="$LIBS $GTK_LIBS"
165 AC_CHECK_FUNC(gdk_x11_display_get_xdisplay, [
166 HAVE_GTK_X11='yes'
167 AC_DEFINE([HAVE_GTK_X11],1,[Building with GTK+X11]) ], [])
168 AC_CHECK_FUNC(gdk_quartz_window_get_nsview, [
169 HAVE_GTK_OSX='yes'
170 AC_DEFINE([HAVE_GTK_OSX],1,[Building with GTK+Cocoa]) ], [])
171 fi
173 AM_CONDITIONAL(GUI_GTK, [test "$HAVE_GTK" = 'yes'])
175 dnl ------------------ Video driver support -------------------
176 AS_IF([test "x$with_osmesa" != xno], [
178 dnl User requested OSMesa (ie pure software rendering)
179 AC_CHECK_LIB([OSMesa], [OSMesaCreateContext], [],
180 [AC_MSG_FAILURE( [--with-osmesa was given, but OSMesa library could not be found])])
181 AC_CHECK_HEADER([GL/osmesa.h], [],
182 [AC_MSG_FAILURE( [--with-osmesa was given, but osmesa.h could not be found])])
183 HAVE_OSMESA='yes'
184 VIDEO_DRIVERS="$VIDEO_DRIVERS osmesa"
185 AC_DEFINE([HAVE_OSMESA],1,[Building with the OSMesa video driver]) ], [
187 dnl Otherwise we want a real GL library (unless we're on darwin, in which case it's already
188 dnl taken care of above).
189 if test "x$APPLE_BUILD" != 'xyes'; then
190 AC_CHECK_LIB(GL, glVertex3f, [], [
191 AC_MSG_FAILURE( ["The OpenGL library (libGL.so) could not be found, but is required."])])
192 AC_CHECK_HEADER([GL/gl.h], [], [
193 AC_MSG_FAILURE( ["The OpenGL header files (eg GL/gl.h) could not be found, but are required."])])
194 else
195 AC_CHECK_FUNC(NSOpenGLGetVersion, [
196 HAVE_NSGL='yes'
197 VIDEO_DRIVERS="$VIDEO_DRIVERS nsgl"
198 AC_DEFINE([HAVE_NSGL],1, [Have NSOpenGL support]) ] )
199 fi
201 dnl Now work out how to get from the UI to GL - this is usually the painful part.
202 if test "x$HAVE_GTK_X11" = "xyes"; then
203 if test "x$APPLE_BUILD" = "xyes"; then
204 LIBS="$LIBS -L/usr/X11/lib -lGL"
205 fi
206 AC_CHECK_FUNC(glXQueryVersion, [
207 HAVE_GLX='yes'
208 VIDEO_DRIVERS="$VIDEO_DRIVERS glx"
209 AC_DEFINE([HAVE_GLX], 1, [Have GLX support]) ] )
210 fi
212 ])
216 AM_CONDITIONAL(VIDEO_OSMESA, [test "x$HAVE_OSMESA" = "xyes"])
217 AM_CONDITIONAL(VIDEO_GLX, [test "x$HAVE_GLX" = "xyes"])
218 AM_CONDITIONAL(VIDEO_NSGL, [test "x$HAVE_NSGL" = "xyes"])
220 dnl Check for optional (but highly desireable) OpenGL features
221 AC_CHECK_FUNC(glGenFramebuffersEXT, [ AC_DEFINE([HAVE_OPENGL_FBO],1,[Have EXT_framebuffer_object support]) ], [])
222 AC_CHECK_FUNC(glCreateShader, [ AC_DEFINE([HAVE_OPENGL_SHADER],1,[Have 2.0 shader support]) ], [])
223 AC_CHECK_FUNC(glCreateShaderObjectARB, [ AC_DEFINE([HAVE_OPENGL_SHADER_ARB],1,[Have ARB shader support]) ], [])
224 AC_CHECK_FUNC(glClampColorARB, [ AC_DEFINE([HAVE_OPENGL_CLAMP_COLOR],1,[Have Color Clamp]) ], [])
227 dnl ------------------- SH4 translator target -------------------
229 if test "x$enable_translator" != "xno"; then
230 case $host_cpu in
231 i386|i486|i586|i686|x86_64)
232 SH4_TRANSLATOR="x86"
233 AC_DEFINE_UNQUOTED(SH4_TRANSLATOR,[TARGET_X86], [SH4 Translator to use (if any)] );;
234 esac
235 fi
236 AM_CONDITIONAL(BUILD_SH4X86, [test "$SH4_TRANSLATOR" = "x86"])
238 dnl ------------------ Optional driver support -------------------
239 dnl Check for Apple CoreAudio
240 AC_CHECK_HEADER([CoreAudio/CoreAudio.h], [
241 HAVE_CORE_AUDIO=yes
242 LIBS="$LIBS -framework CoreAudio"
243 AUDIO_DRIVERS="$AUDIO_DRIVERS osx"
244 AC_DEFINE([HAVE_CORE_AUDIO], 1, [Have Apple CoreAudio support]) ],[true ])
245 AM_CONDITIONAL( AUDIO_OSX, [test "$HAVE_CORE_AUDIO" = 'yes'] )
247 dnl Check for SDL (only used for audio at the moment)
248 if test "x$with_sdl" != "xno"; then
249 PKG_CHECK_MODULES(SDL, [sdl], [
250 HAVE_SDL='yes'
251 AUDIO_DRIVERS="$AUDIO_DRIVERS sdl"
252 AC_DEFINE([HAVE_SDL],1,[Have SDL support])
253 ], [
254 if test "x$with_sdl" = "xyes"; then
255 AC_MSG_FAILURE( ["SDL libraries could not be found (but were required)] )
256 fi
257 ])
258 fi
259 AM_CONDITIONAL( AUDIO_SDL, [test "$HAVE_SDL" = 'yes'] )
261 dnl Check for pulseaudio
262 if test "x$with_pulse" != "xno"; then
263 PKG_CHECK_MODULES(PULSE, [libpulse-simple], [
264 HAVE_PULSE='yes'
265 AUDIO_DRIVERS="$AUDIO_DRIVERS pulse"
266 AC_DEFINE([HAVE_PULSE],1,[Have pulseaudio support])
267 ], [
268 if test "x$with_pulse" = "xyes"; then
269 AC_MSG_FAILURE( [PulseAudio audio package could not be found (but was required)] )
270 fi
271 ])
272 fi
273 AM_CONDITIONAL( AUDIO_PULSE, [test "$HAVE_PULSE" = 'yes'] )
275 dnl Check for esound
276 if test "x$with_esd" != "xno"; then
277 PKG_CHECK_MODULES(ESOUND, [esound], [
278 HAVE_ESOUND='yes'
279 AUDIO_DRIVERS="$AUDIO_DRIVERS esd"
280 AC_DEFINE([HAVE_ESOUND],1,[Have esound support])
281 ], [
282 if test "x$with_esd" = "xyes"; then
283 AC_MSG_FAILURE( [ESounD audio package could not be found (but was required)] )
284 fi
285 ])
286 fi
287 AM_CONDITIONAL( AUDIO_ESOUND, [test "$HAVE_ESOUND" = 'yes'] )
289 dnl Check for alsa support
290 PKG_CHECK_MODULES(ALSA, [alsa], [
291 HAVE_ALSA='yes'
292 AUDIO_DRIVERS="$AUDIO_DRIVERS alsa"
293 AC_DEFINE([HAVE_ALSA],1,[Have alsa support]) ], [true])
294 AM_CONDITIONAL( AUDIO_ALSA, [test "$HAVE_ALSA" = 'yes'] )
297 dnl Check for native cdrom support. There can be only one.
298 AC_CHECK_HEADER([linux/cdrom.h], [
299 CDROM_DRIVER=linux
300 dnl Some kernel versions have non-c99 compliant headers - check here
301 AC_MSG_CHECKING([C99 compliant kernel headers])
302 old_CFLAGS="$CFLAGS"
303 CFLAGS="$CFLAGS $STDCFLAG"
304 AC_TRY_COMPILE([#include <linux/cdrom.h>], [], [AC_MSG_RESULT([Yes])], [
305 AC_MSG_RESULT([No])
306 STDCFLAG="-std=gnu99"])
307 CFLAGS="$old_CFLAGS"
308 ], [true])
309 AC_CHECK_HEADER([IOKit/IOKitLib.h], [
310 CDROM_DRIVER=osx
311 LIBS="$LIBS -framework IOKit"],[true])
312 AM_CONDITIONAL(CDROM_LINUX, [test "x$CDROM_DRIVER" = "xlinux"])
313 AM_CONDITIONAL(CDROM_OSX, [test "x$CDROM_DRIVER" = "xosx"])
314 AM_CONDITIONAL(CDROM_NONE, [test "x$CDROM_DRIVER" = "x"])
316 AC_CHECK_HEADER([linux/joystick.h], [
317 HAVE_LINUX_JOYSTICK_H=yes
318 AC_DEFINE([HAVE_LINUX_JOYSTICK], 1, [Have linux joystick support]) ],
319 [ echo "Linux Joystick support not found, building without it."] )
320 AM_CONDITIONAL(JOY_LINUX, [test "$HAVE_LINUX_JOYSTICK_H" = "yes"])
322 dnl Check for LIRC
323 if test "x$with_lirc" != "xno"; then
324 AC_CHECK_HEADER([lirc/lirc_client.h], [
325 HAVE_LIRC_CLIENT_H=yes
326 AC_DEFINE([HAVE_LIRC],1,[Have LIRC support]) ],
327 [ echo "LIRC support not found, building without it." ] )
328 fi
329 AM_CONDITIONAL(INPUT_LIRC, [test "$HAVE_LIRC_CLIENT_H" = "yes"])
331 dnl Check for cross-compiler availability - needed for system tests
332 AC_PATH_PROG(SHCC, [sh-elf-gcc])
333 AC_PATH_PROG(SHLD, [sh-elf-ld])
334 AC_PATH_PROG(SHOBJCOPY, [sh-elf-objcopy])
335 AC_PATH_PROG(ARMCC, [arm-elf-gcc])
336 AC_PATH_PROG(ARMLD, [arm-elf-ld])
337 AC_PATH_PROG(ARMOBJCOPY, [arm-elf-objcopy])
339 if test "x$SHCC" = "x" -o "x$SHLD" = "x" -o "x$SHOBJCOPY" = "x"; then
340 BUILD_SH="no"
341 echo "Warning: SH4 cross-compiler not found, system tests will be disabled."
342 else
343 BUILD_SH="yes"
344 fi
345 if test "x$ARMCC" = "x" -o "x$ARMLD" = "x" -o "x$ARMOBJCOPY" = "x"; then
346 BUILD_ARM="no"
347 echo "Warning: ARM cross-compiler not found, AICA tests will be disabled."
348 else
349 BUILD_ARM="yes"
350 fi
351 AM_CONDITIONAL(BUILD_SYSTEST, [test "$BUILD_SH" = "yes"])
352 AM_CONDITIONAL(BUILD_ARMTEST, [test "$BUILD_ARM" = "yes"])
354 CFLAGS="$CFLAGS $STDCFLAG"
356 dnl ----------------------- All done, finish up -----------------------
357 GETTEXT_PACKAGE=lxdream
358 AC_SUBST(GETTEXT_PACKAGE)
359 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[translation domain])
361 dnl Add the languages which your application supports here.
362 ALL_LINGUAS="de es it pt_BR"
363 AM_GLIB_GNU_GETTEXT
365 AC_OUTPUT([
366 Makefile
367 src/Makefile
368 po/Makefile.in
369 test/Makefile
370 Info.plist
371 ])
372 AS_MKDIR_P(test/sh4)
374 dnl ------------------------- Print out a summary ----------------------
376 echo
377 echo "Configuration complete"
378 echo
380 if test "x$HAVE_GTK" = x; then
381 if test "x$HAVE_COCOA" = x; then
382 echo " User interface: none"
383 else
384 echo " User interface: Cocoa"
385 fi
386 else
387 echo " User interface: GTK"
388 fi
390 if test "x$SH4_TRANSLATOR" = "x"; then
391 echo " SH4 translator: None (emulation core only)"
392 else
393 echo " SH4 translator: $SH4_TRANSLATOR"
394 fi
396 if test "x$VIDEO_DRIVERS" = "x"; then
397 echo " Video drivers: none (no supported GL found)"
398 else
399 echo " Video drivers: $VIDEO_DRIVERS"
400 fi
402 if test "x$AUDIO_DRIVERS" = "x"; then
403 echo " Audio drivers: none (no supported output devices found)"
404 else
405 echo " Audio drivers: $AUDIO_DRIVERS"
406 fi
408 if test "x$CDROM_DRIVER" = "x"; then
409 echo " CD-ROM driver: none (no supported cd-rom devices found)"
410 else
411 echo " CD-ROM driver: $CDROM_DRIVER"
412 fi
414 if test "x$HAVE_LIRC_CLIENT_H" = "x"; then
415 echo " LIRC support: no"
416 else
417 echo " LIRC support: yes"
418 fi
.